ex1.4.txt

通过实例详细介绍Ansys在实际工程中的应用

!1.4  平行杆件与刚性梁连接的热应力问题
! 本程序来源于邢静忠等编著的《ANSYS分析实例与工程应用》，机械工业出版社（2004年）
FINISH
/CLEAR,START
! (1) 定义分析类型,单元类型,截面面积和材料的力学,热学参数
/FILNAME,EX1.4
/PREP7
/TITLE, EX1.4, THERMALLY LOADED SUPPORT STRUCTURE
ANTYPE,STATIC
ET,1,LINK1
R,1,65e-6
MP,EX,1,100E9
MP,ALPX,1,1.6E-5
MP,EX,2,210E9
MP,ALPX,2,1.3E-5
TREF,70
! (2) 定义节点位置信息
N,1,-1
N,3,1
FILL
N,4,-1,-1
N,6,1,-1
FILL
! (3) 定义单元信息
E,1,4
E,3,6
MAT,2
E,2,5
CP,1,UY,5,4,6
! (4) 定义位移约束和荷载（外力和温度荷载）
D,1,ALL,,,3
F,5,FY,-4000
BFUNIF,TEMP,80
FINISH
! (5) 在求解模块,定义求解选项,并开始求解
/SOLU
OUTPR,BASIC,1
OUTPR,NLOAD,1
NSUBST,1
SOLVE
FINISH
! (6) 在一般后处理模块中,寻找特定位置的节点和单元,并提取它们的内力
/POST1
STEEL_N  = NODE (,,,)
COPPER_N = NODE (1,0,0)
STEEL_E = ENEARN (STEEL_N)
COPPER_E = ENEARN (COPPER_N)
ETABLE,STRS_ST,LS,1
ETABLE,STRS_CO,LS,1
*GET,STRSS_ST,ELEM,STEEL_E,ETAB,STRS_ST
*GET,STRSS_CO,ELEM,COPPER_E,ETAB,STRS_CO
! (7) 将计算结果及其与理论解的比较情况输出到文件vm3.txt
*DIM,LABEL,CHAR,2,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'STRSS_ST','STRSS_CO'
LABEL(1,2) = ' (MPa) ',' (MPa) '
*VFILL,VALUE(1,1),DATA,34.59,13.47
*VFILL,VALUE(1,2),DATA,STRSS_ST/1e6,STRSS_CO/1e6
*VFILL,VALUE(1,3),DATA,ABS(STRSS_ST/34.59e6 ) ,ABS( STRSS_CO/13.47e6 )
/COM
/OUT,EX1_4,out
/COM,------------------- EX1.4 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,EX1_4,out