window.dsp

ADSP-21xx Applications Handbook File Area

.MODULE         windowing;

{       Calling Parameters
                I0 = ---> 1st element of input data buffer to be windowed
                I4 = ---> 1st element of window coefficients
                M0,M4 = 1;
                L0,L1,L4 = 0;
                (constant) N = 1024 for 1024-pt FFT input values

                for complex values, call this routine twice, once for
                the real values, and once for the imaginary values, each 
                time setting I0 and I4 to the proper addresses

        Return Values
                Data windowed in same buffer as original

        Altered Registers
                I0,I1,I4,M0,M4,MX0,MY0,MR,CNTR
}

.CONST          N = 1024;

.VAR/PM         window_coeffs[N];
.INIT           window_coeffs: <window.dat>;

.ENTRY          window;

window:         I1=I0;
                CNTR=N-1;
                MX0=DM(I0,M0),MY0=PM(I4,M4);
                DO windowloop UNTIL CE;
                    MR=MX0*MY0(RND),MX0=DM(I0,M0),MY0=PM(I4,M4);
windowloop:         DM(I1,M0)=MR1;
                MR=MX0*MY0(RND);
                DM(I1,M0)=MR1;
                RTS;
.ENDMOD;