configure.in

A GTK sound font editor. Sound font files are used to synthesize instruments from audio samples for

dnl --------------------------------------------------
dnl configure.in for Smurf Sound Font Editor
dnl --------------------------------------------------

AC_INIT(src/uiface.c)
AM_INIT_AUTOMAKE(smurf, 0.52.6)
AM_CONFIG_HEADER(src/config.h)

CFLAGS="$CFLAGS -Wall"

dnl - Program checks
AC_PROG_CC

dnl International language support
ALL_LINGUAS="de"
AM_GNU_GETTEXT

AC_PROG_INSTALL
AC_PROG_MAKE_SET
AC_PROG_RANLIB

AC_HEADER_STDC

dnl Compile options string used in about dialog for debugging purposes
COMPOPSTR=""

dnl - Check for debugging or profiling configure flags
AC_DEBUGGING
AC_PROFILING

dnl - Sound support check (ALSA/OSS/AWE)
AC_SOUND

dnl - Allow ignoring of AWE driver sample caching support (for building RPMs)
AC_ARG_ENABLE(splash,
  [  --disable-awe-caching   Ignore AWE support for sample caching],
  AC_DEFINE(AWE_NO_CACHE_SUPPORT, 1,
  [Define to ignore AWE support for sample caching]))

AC_ARG_WITH(audiofile,
	[  --with-audiofile        Force use of audiofile library],
	with_audiofile="yes", with_audiofile="")

AC_ARG_WITH(libsndfile,
        [  --with-sndfile          Force use of libsndfile library],
        with_sndfile="yes", with_sndfile="")

AC_SNDFILE_CHECK(SNDFILE_SUPPORT=1, SNDFILE_SUPPORT=0)

dnl Do audiofile check
AUDIOFILE_SUPPORT=0
AM_PATH_AUDIOFILE(0.1.5, AUDIOFILE_SUPPORT=1)

USE_AUDIOFILE=0
NICE_AUDIOFILE=0
if test $AUDIOFILE_SUPPORT -eq 1 ; then
  AC_MSG_CHECKING(for AUDIOFILE - version >= 0.2.0)
  if test "$audiofile_major_version" -gt 0 \
   -o "$audiofile_minor_version" -ge 2 ; then
    NICE_AUDIOFILE=1
    AC_MSG_RESULT(yes)
  else
    AC_MSG_RESULT(no)
  fi
fi

dnl --with-audiofile switch supplied?
if test "$with_audiofile" = "yes" ; then
  if test $AUDIOFILE_SUPPORT -eq 0 ; then
    AC_MSG_ERROR([
--- The --with-audiofile switch was supplied but no audiofile support
--- was found. Make sure you have audiofile or libsndfile installed.
    ])
  fi
 USE_AUDIOFILE=1

dnl --with-sndfile switch supplied?
elif test "$with_sndfile" = "yes" ; then
  if test $SNDFILE_SUPPORT -eq 0 ; then
    AC_MSG_ERROR([
--- The --with-sndfile switch was supplied but no libsndfile support
--- was found. Make sure you have libsndfile or audiofile installed.
    ])
  fi

dnl If no --with switches defined, use AUDIOFILE if nice
elif test $NICE_AUDIOFILE -eq 1 ; then
  USE_AUDIOFILE=1

dnl Use not nice audiofile only if no libsndfile support
elif test $SNDFILE_SUPPORT -eq 0 -a $AUDIOFILE_SUPPORT -eq 1 ; then
  USE_AUDIOFILE=1
fi

if test $USE_AUDIOFILE -eq 1 ; then
  if test $NICE_AUDIOFILE -eq 0 ; then
    AC_MSG_WARN([Using audiofile < v0.2.0, upgrade recommended, see INSTALL])
  fi

  AC_DEFINE(WITH_AUDIOFILE, 1,[Define to use AUDIOFILE instead of libsndfile])

  CFLAGS="${AUDIOFILE_CFLAGS} ${CFLAGS}"
  LIBS="${AUDIOFILE_LIBS} ${LIBS}"
  COMPOPSTR="audiofile ${COMPOPSTR}"
elif test $SNDFILE_SUPPORT -eq 1 ; then
  CFLAGS="${SNDFILE_CFLAGS} ${CFLAGS}"
  LIBS="${SNDFILE_LIBS} ${LIBS}"
  COMPOPSTR="libsndfile ${COMPOPSTR}"
else
  AC_MSG_ERROR([
--- Failed to find libsndfile or audiofile. Install one of
--- these, delete config.cache and re-run ./configure.
--- Check config.log for details.
  ])
fi

AC_PATH_GTK(1.2.0, , AC_MSG_ERROR([Failed to find sufficient GTK library]))
CFLAGS="${GTK_CFLAGS} ${CFLAGS}"
LIBS="${GTK_LIBS} ${LIBS}"

dnl Smurf intro splash image conditional compile stuff

CDUMP=""
AC_SUBST(CDUMP)

AC_CHECK_HEADER(png.h, png_h=yes, png_h="")
AC_CHECK_LIB(png, png_read_image, libpng=yes, libpng="")

AC_ARG_ENABLE(splash,
  [  --disable-splash        Don't compile Smurfy splash intro image],
  disable_splash="yes")

if test "${disable_splash}" != "yes" -a "${png_h}" = "yes" \
  -a "${libpng}" = "yes" ; then
    AC_DEFINE(SPLASH, 1, [Define to compile splash intro image functions])
    CDUMP="cdump"
    LIBS="${LIBS} -lpng"
    COMPOPSTR="splash ${COMPOPSTR}"
fi

echo "*** Compile options: ${COMPOPSTR}"

AC_DEFINE_UNQUOTED(COMPILE_OPTIONS, "${COMPOPSTR}", [This is an autoconf generated list of compile options, informational only])

AC_OUTPUT([Makefile smurf.spec tools/Makefile src/Makefile src/drivers/Makefile
  src/widgets/Makefile intl/Makefile po/Makefile.in pixmaps/Makefile
  package/Makefile])