setmenu.bak

来自「吐血贡献纺织上的进销存原码,功能齐全,给大家吧.」· BAK 代码 · 共 59 行

Set Sysmenu To Default
Set Sysmenu To
Set Sysmenu Automatic
Set NullDisplay To ' '
SELECT * FROM MENUTABLE ORDER BY MENUID INTO CURSOR APPMENU
SELECT APPMENU
GO TOP
SCAN FOR LEN(ALLTRIM(MENUID))=3
   DEFMENU='DEFINE PAD '+Alltrim(MENUID)+' OF _MSYSMENU PROMPT "'+Alltrim(MCAPTION)+'" COLOR SCHEME 3 KEY '+Alltrim(MENUKEY)+',"'+Alltrim(MENUKEY)+'"'
   &DEFMENU.
   DEFMENU='ON PAD '+Alltrim(MENUID)+' OF _MSYSMENU ACTIVATE POPUP '+Alltrim(MENUID)
   &DEFMENU
   DEFMENU='DEFINE POPUP '+Alltrim(MENUID)+' MARGIN RELATIVE SHADOW COLOR SCHEME 4 '
   &DEFMENU
Endscan

Go Top
Scan For Len(Alltrim(MENUID))=6
   DEFMENU='DEFINE BAR '+Substr(MENUID,5,2)+' OF  ' +Left(Alltrim(MENUID),3)+' PROMPT "'+Alltrim(MCAPTION)+'"'
   If !Empty(ALLTRIM(MENUKEY))
      DEFMENU=DEFMENU+' KEY '+Alltrim(MENUKEY)+',"'+Alltrim(MENUKEY)+'"'
   Endif
   If !Empty(Alltrim(MPICTURE))
      DEFMENU=DEFMENU+' PICTURE "'+Alltrim(MPICTURE)+'"'
   Endif
   If !Empty(Alltrim(MMESSAGE))
      DEFMENU=DEFMENU+' MESSAGE "'+Alltrim(MMESSAGE)+'"'
   Endif
   &DEFMENU.
   Do Case
      Case Upper(MENUTYPE)='C'
         DEFMENU='ON SELECTION BAR '+Substr(MENUID,5,2)+' OF '+Left(Alltrim(MENUID),3)+' '+Iif(Isnull(MCOMMAND),'',Alltrim(MCOMMAND))
         &DEFMENU
      Case Upper(MENUTYPE)='S'
         DEFMENU='ON BAR '+Substr(MENUID,5,2)+' OF '+Left(Alltrim(MENUID),3)+' ACTIVATE POPUP '+Alltrim(MENUID)
         &DEFMENU
         DEFMENU='DEFINE POPUP '+Alltrim(MENUID)+' MARGIN RELATIVE SHADOW COLOR SCHEME 4'
         &DEFMENU
   Endcase
Endscan

Go Top
Scan For Len(Alltrim(MENUID))=9
   DEFMENU='DEFINE BAR '+Substr(MENUID,8,2)+' OF  ' +Left(Alltrim(MENUID),6)+' PROMPT "'+Alltrim(MCAPTION)+'"'
   If !Empty(Alltrim(MENUKEY))
      DEFMENU=DEFMENU+' KEY '+Alltrim(MENUKEY)+',"'+Alltrim(MENUKEY)+'"'
   Endif
   If !Empty(Alltrim(MPICTURE))
      DEFMENU=DEFMENU+' PICTURE "'+Alltrim(MPICTURE)+'"'
   Endif
   If !Empty(Alltrim(MMESSAGE))
      DEFMENU=DEFMENU+' MESSAGE "'+Alltrim(MMESSAGE)+'"'
   Endif
   &DEFMENU
   DEFMENU='ON SELECTION BAR '+Substr(MENUID,8,2)+' OF '+Left(Alltrim(MENUID),6)+' '+Alltrim(MCOMMAND)
   &DEFMENU
Endscan