category.asp

一个ＡＳＰ网站博克程序

<%

	Class Category
	
		'日志分类列表
		Public Sub CategoryList()
			Dim objDBMS
			Set objDBMS = New LarrixDBMS
			objDBMS.Open "SELECT * FROM [Categories] ORDER BY [CategoryLAB]", 1
			%><table width="190" cellpadding="0" cellspacing="0" border="0"><%
			%><caption class="guider"><li type="square">日志分类</li></caption><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider">&nbsp;-&nbsp; <a href="Default.asp" title="合并分类日志">合并分类日志</a></td><%
			%></tr><%
			If Not (objDBMS.objRSET.BOF And objDBMS.objRSET.EOF) Then
				While Not objDBMS.objRSET.EOF
					%><tr align="left" valign="middle"><%
					%><td width="100%" class="guider">&nbsp;-&nbsp; <a href="Category.asp?id=<% = objDBMS.objRSET("CategoryID") %>" title="<% = objDBMS.objRSET("CategoryVAL") %>"><% = objDBMS.objRSET("CategoryLAB") %></a></td><%
					%></tr><%
					objDBMS.objRSET.MoveNext
				Wend
			End If
			%></table><%
			objDBMS.Close
			Set objDBMS = Nothing
		End Sub
		
		'分类下拉菜单
		Public Sub CategorySelect(intCategory)
			Dim objDBMS
			Set objDBMS = New LarrixDBMS
			%><select name="category" size="1"><%
			If intCategory = 0 Then
				%><option value="0" selected>分类列表</option><%
			Else
				%><option value="0">分类列表</option><%
			End If
			objDBMS.Open "SELECT * FROM [Categories] ORDER BY [CategoryLAB]" , 1
			If Not (objDBMS.objRSET.BOF And objDBMS.objRSET.EOF) Then
				While Not objDBMS.objRSET.EOF
					If objDBMS.objRSET("CategoryID") = intCategory Then
						%><option value="<% = objDBMS.objRSET("CategoryID") %>" selected><% = objDBMS.objRSET("CategoryLAB") %></option><%
					Else
						%><option value="<% = objDBMS.objRSET("CategoryID") %>"><% = objDBMS.objRSET("CategoryLAB") %></option><%
					End If
					objDBMS.objRSET.MoveNext
				Wend
			End If
			objDBMS.Close
			%></select><%
			Set objDBMS = Nothing
		End Sub

	End Class

%>