message.asp

一个ＡＳＰ网站博克程序

<%

	Class Message
	
		'签写留言界面
		Public Sub SignMessage()
			%><table width="580" cellpadding="0" cellspacing="0" border="0"><%
			%><caption><li type="square">签写留言</li></caption><%
			%><form name="message" action="Message.asp" method="post" onsubmit="return (message.label.value!=''&&message.username.value!='');"><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider">留言内容（必填）：</td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider"><textarea name="label" rows="15" cols="45"></textarea></td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider">留言者姓名（必填）：</td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider"><input type="text" name="username" size="35" maxlength="50"></td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider">留言者电子邮件：</td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider"><input type="text" name="email" size="35" maxlength="50"></td><%
			%></tr><%
			%><tr align="left" valign="middle"><%
			%><td width="100%" class="guider"><input type="submit" value="签写留言" class="button"></td><%
			%></tr><%
			%></form><%
			%></table><%
		End Sub
		
		'留言簿显示列表
		Public Sub MessageList(strSQL, intPage)
			Dim objDBMS
			Dim intCount
			Set objDBMS = New LarrixDBMS
			objDBMS.Open strSQL, 1
			If objDBMS.objRSET.BOF And objDBMS.objRSET.EOF Then
				%><table width="580" cellpadding="0" cellspacing="0" border="0"><%
				%><tr align="left" valign="middle"><%
				%><td width="100%" class="ground">当前还没有任何留言！</td><%
				%></tr><%
				%></table><%
				%><br>&nbsp;<br><%
			Else
				objDBMS.objRSET.PageSize = 25
				If Trim(Request.QueryString("page")) = "" Or IsNumeric(Trim(Request.QueryString("page"))) = False Then
					intPage = 1
				Else
					intPage = CInt(Trim(Request.QueryString("page")))
					If intPage < 1 Then
						intPage = 1
					End If
					If intPage > objDBMS.objRSET.PageCount Then
						intPage = objDBMS.objRSET.PageCount
					End If
				End If
				objDBMS.objRSET.AbsolutePage = intPage
				For intCount = 1 To objDBMS.objRSET.PageSize
					If objDBMS.objRSET.EOF Then
						Exit For
					End If
					%><table width="580" cellpadding="0" cellspacing="0" border="0"><%
					%><tr align="left" valign="middle"><%
					%><td width="100%" class="weblog"><% = objDBMS.objRSET("MessageDTM") %>：<% = Server.HTMLEncode(objDBMS.objRSET("MessageUSR")) %> &nbsp;|&nbsp; 电子邮件：<% = Server.HTMLEncode(objDBMS.objRSET("MessageEML")) %></td><%
					%></tr><%
					%><tr align="left" valign="middle"><%
					%><td width="100%" class="ground">留言内容：<br><% = Server.HTMLEncode(objDBMS.objRSET("MessageLAB")) %></td><%
					%></tr><%
					If objDBMS.objRSET("MessageVAL") <> "" Then
						%><tr align="left" valign="middle"><%
						%><td width="100%" class="ground">管理回复：<br><% = objDBMS.objRSET("MessageVAL") %></td><%
						%></tr><%
					End If
					%></table><%
					%><br>&nbsp;<br><%
					objDBMS.objRSET.MoveNext
				Next
				If intPage > 1 Then
					%><a href="GuestBook.asp?page=1">首页</a>&nbsp; <a href="GuestBook.asp?page=<% = intPage - 1 %>">上一页</a>&nbsp; <%
				Else
					%>首页&nbsp; 上一页&nbsp; <%
				End If
				If intPage > 6 Then
					%>...&nbsp; <%
				End If
				For intCount = intPage - 5 To intPage + 5
					If intCount >= 1 And intCount <= objDBMS.objRSET.PageCount Then
						%><a href="GuestBook.asp?page=<% = intCount %>"><% = intCount %></a>&nbsp; <%
					End If
				Next 
				If intPage < objDBMS.objRSET.PageCount - 5 Then
					%>...&nbsp; <%
				End If
				If intPage < objDBMS.objRSET.PageCount Then
					%><a href="GuestBook.asp?page=<% = intPage + 1 %>">下一页</a>&nbsp; <a href="GuestBook.asp?page=<% = objDBMS.objRSET.PageCount %>">尾页</a><%
				Else
					%>下一页&nbsp; 尾页<%
				End If
			End If
			objDBMS.Close
			Set objDBMS = Nothing
		End Sub
		
	End Class

%>