comment.asp

一个ＡＳＰ网站博克程序

<%

	Class Comment
		
		'评论管理列表
		Public Sub CommentExplor(intItem)
			%><table width="580" cellpadding="0" cellspacing="0" border="0"><%
			%><caption><li type="square">评论列表</li></caption><%
			%><tr align="left"><%
			%><td width="580" class="ground"><%
			Set objDBMS = New LarrixDBMS
			objDBMS.Open "SELECT * FROM [Comments] WHERE [ItemID]=" & intItem & " ORDER BY [CommentID] DESC" , 1
			If objDBMS.objRSET.BOF And objDBMS.objRSET.EOF Then
				%>当前还没有任何评论！<%
			Else
				While Not objDBMS.objRSET.EOF
					%><table width="100%" cellpadding="0" cellspacing="0" border="0" class="comment"><%
					%><tr align="left" valign="middle"><%
					%><td width="100%" class="ground"><%
					%><a href="mailto:<% = Server.HTMLEncode(objDBMS.objRSET("CommentEML")) %>" title="发送电子邮件到 <% = Server.HTMLEncode(objDBMS.objRSET("CommentLAB")) %> 的信箱"><% = Server.HTMLEncode(objDBMS.objRSET("CommentLAB")) %></a> 评论说：<br><% = Server.HTMLEncode(objDBMS.objRSET("CommentVAL")) %><br>评论日期时间：<% = objDBMS.objRSET("CommentDTM") %> &nbsp;|&nbsp; IP地址：<% = objDBMS.objRSET("CommentURL") %> &nbsp;|&nbsp; <a href="CommentDelete.asp?id=<% = objDBMS.objRSET("CommentID") %>">删除该评论</a><%
					%></td><%
					%></tr><%
					%></table><%
					objDBMS.objRSET.MoveNext
				Wend
			End If
			objDBMS.Close
			Set objDBMS = Nothing
			%></td><%
			%></tr><%
			%></table><%
		End Sub
		
		'评论统计
		Public Function CommentCount(intItem)
			Dim objDBMS
			Set objDBMS = New LarrixDBMS
			objDBMS.Open "SELECT * FROM [Comments] WHERE [ItemID]=" & intItem, 1
			If objDBMS.objRSET.BOF And objDBMS.objRSET.EOF Then
				CommentCount = 0
			Else
				CommentCount = objDBMS.objRSET.RecordCount
			End If
			objDBMS.Close
			Set objDBMS = Nothing
		End Function
		
		'因删除日志导致的批量删除评论
		Public Sub ItemDelete(intItem)
			Dim objDBMS
			Set objDBMS = New LarrixDBMS
			objDBMS.Open "SELECT * FROM [Comments] WHERE [ItemID]=" & intItem, 2
			If Not (objDBMS.objRSET.BOF And objDBMS.objRSET.EOF) Then
				While Not objDBMS.objRSET.EOF
					objDBMS.objRSET.Delete
					objDBMS.objRSET.MoveNext
				Wend
				objDBMS.objRSET.UpdateBatch
			End If
			objDBMS.Close
			Set objDBMS = Nothing
		End Sub
		
	End Class

%>