form1.vb

Microsoft Mobile Development Handbook的代码,有C#,VB,C++的

Imports System.Data
Imports System.Data.SqlServerCe

Public Class Form1

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        If ProductsDataSetUtil.DesignerUtil.IsRunTime Then
            'TODO: Delete this line of code to remove the default AutoFill for 'ProductsDataSet.Product'.
            Me.ProductTableAdapter.Fill(Me.ProductsDataSet.Product)
        End If

    End Sub

    Private Sub NewMenuItemMenuItem_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles NewMenuItemMenuItem.Click
        ' Don't allow new Product creation if there are no Product Categories
        If GetProductCategoriesCount() = 0 Then
            MessageBox.Show("You must create some Product Categories first")
        Else
            ' Set some default column values
            Me.ProductsDataSet.Product.ProductCategoryIDColumn.DefaultValue = 1
            Me.ProductsDataSet.Product.SizeColumn.DefaultValue = "M"

            ProductBindingSource.AddNew()

            Dim productEditViewDialog As ProductEditViewDialog = productEditViewDialog.Instance(Me.ProductBindingSource)
            productEditViewDialog.ShowDialog()
        End If
    End Sub

    Private Sub ProductDataGrid_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ProductDataGrid.Click
        Dim productSummaryViewDialog As SQLCEDataSourceQuickUI.ProductSummaryViewDialog = SQLCEDataSourceQuickUI.ProductSummaryViewDialog.Instance(Me.ProductBindingSource)
        productSummaryViewDialog.ShowDialog()

    End Sub

    Private Sub ProductBindingSource_AddingNew(ByVal sender As System.Object, ByVal e As System.ComponentModel.AddingNewEventArgs) Handles ProductBindingSource.AddingNew
        MessageBox.Show("AddingNew event fired")
        ' Create a DataRowView
        Dim datarowview As DataRowView = (CType(ProductBindingSource.List, DataView)).AddNew()

        ' You can set fields in the new row like this:
        datarowview("ProductCategoryID") = 1
        ' Or by getting the underlying DataRow in the data source
        Dim productRow As ProductsDataSet.ProductRow = CType(datarowview.Row, ProductsDataSet.ProductRow)
        productRow.ProductCategoryID = 1
        productRow.ListPrice = 0.0

        ' Tell it that this is the new row
        e.NewObject = datarowview

        ' Set the position of the BindingSource
        ProductBindingSource.Position = ProductBindingSource.Count - 1
    End Sub

    Private Function GetProductCategoriesCount() As Integer
        Dim count As Integer = -1
        Using cmd As SqlCeCommand = New SqlCeCommand("SELECT COUNT(*) FROM ProductCategory", Me.ProductTableAdapter.Connection)
            Try
                Me.ProductTableAdapter.Connection.Open()
                count = CType(cmd.ExecuteScalar(), Integer)
            Finally
                Me.ProductTableAdapter.Connection.Close()
            End Try
        End Using

        Return count
    End Function

    Private Sub MenuItem1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MenuItem1.Click
        Dim frm As ProductCategoriesForm = New ProductCategoriesForm()
        frm.ShowDialog()

        ' When we are finished maintaining Product Categories, fill the ProductCategory table in the DataSet
        FillProductCategories()

    End Sub

    Private Sub FillProductCategories()
        Dim prodCatTA As ProductsDataSetTableAdapters.ProductCategoryTableAdapter _
         = New ProductsDataSetTableAdapters.ProductCategoryTableAdapter()
        prodCatTA.Fill(Me.productsDataSet.ProductCategory)
    End Sub

End Class