e9.07.txt

185个ANSYS工程结构数值分析非常实用的命令流

!EX9.7 悬臂三角板的谐响应分析-缩减法
finish
/clear
/filname,ex97
/prep7
!定义单元类型与材料性质
et,1,shell63
mp,ex,1,2.1e11
mp,nuxy,1,0.3
mp,dens,1,7800
r,1,0.02
!创建几何和有限元模型
k,1
k,2,3
k,3,3,0.5
a,1,2,3,3
arsym,y,1
nummrg,kp
lesize,2,,,1
lesize,5,,,1
esize,,6
amesh,all
lsel,s,loc,x,3
dl,all,,all
!模态分析-缩减法(也可不进行)
/solu
antype,modal
modopt,reduc,2,,,2
mxpand,2
outres,all,all
nsel,s,loc,y,0
m,all,uz
nsel,all
solve
finish
!谐响应分析
/solu
antype,harmic
hropt,reduce
hrout,on
nsel,s,loc,y,0
m,all,uz
nsel,all
total,9
f,1,fz,1000
harfrq,0,20
dmprat,0.05
nsubst,20
kbc,1
solve
finish
!观察缩减解
/post26
file,ex97,rfrq
nsol,2,1,u,z
plcplx,0
plvar,2
plcplx,1
plvar,2
finish
!扩展解(单点)
/solu
expass,on
expsol,,,3.8
hrexp,all
outres,all,all
solve
finish
!观察扩展解(单点)
/post1
set,list
set,1,1
pldisp,1
set,1,1,,1
pldisp,1
LCDEF,1,1,1,0
LCDEF,2,1,1,1
LCZERO$LCASE,1
LCOPER,SRSS,2
PLDISP,1
plnsol,s,x
!扩展解(多点)
/solu
expass,on
numexp,10,3.0,4.0
hrexp,all
outres,all,all
solve
finish
!观察扩展解(多点)
/post1
set,list
set,1,1
pldisp,1
set,1,1,,1
pldisp,1
LCDEF,1,1,1,0
LCDEF,2,1,1,1
LCZERO$LCASE,1
LCOPER,SRSS,2
PLDISP,1
plnsol,s,x

!--------------------------------
!悬臂三角板的谐响应分析-完全法
!--------------------------------
finish
/clear
/filname,ex97
/prep7
et,1,shell63
mp,ex,1,2.1e11
mp,nuxy,1,0.3
mp,dens,1,7800
r,1,0.02
k,1
k,2,3
k,3,3,0.5
a,1,2,3,3
arsym,y,1
nummrg,kp
lesize,2,,,1
lesize,5,,,1
esize,,6
amesh,all
lsel,s,loc,x,3
dl,all,,all

/solu
antype,harmic
hrout,on
f,1,fz,1000
harfrq,0,20
dmprat,0.05
nsubst,100
kbc,1
solve
finish
/post26
nsol,2,1,u,z
plcplx,0
plvar,2
plcplx,1
plvar,2
finish
/post1
set,list
set,1,19
pldisp,1
set,1,19,,1
pldisp,1

LCDEF,1,1,19,0
LCDEF,2,1,19,1
LCZERO$LCASE,1
LCOPER,SRSS,2
PLDISP,1