e8.22.txt

185个ANSYS工程结构数值分析非常实用的命令流

!EX8.22 菱形索网找形与分析
finish
/clear
/filname,ex822
/prep7
netnum=4
netsiz=9.15
f=3.66
a=0.001468
t0=8e5
deadld=1e3
istran=0.999
et,1,link10
r,1,a,istran
mp,ex,1,t0/(istran*a)
mp,prxy,1,0.3
k,1
k,2,0,netnum*netsiz
k,3,netnum*netsiz
l,1,2
l,1,3
l,2,3
ldiv,all,,,netnum
*do,i,1,netnum-1
xi=i*netsiz
yi=(netnum-i)*netsiz
l,kp(xi,0,0),kp(xi,yi,0)
l,kp(0,xi,0),kp(yi,xi,0)
*enddo
lsel,u,tan1,x
lsel,u,tan1,y
ldele,all
lsel,all
lovlap,all
lsymm,x,all
lsymm,y,all
nummrg,all
*do,i,1,netnum+1
xi=(i-1)*netsiz
yi=(netnum+1-i)*netsiz
dfv=f-(netnum+1-i)*2*f/netnum
dk,kp(xi,yi,0),ux,,,,uy
dk,kp(xi,yi,0),uz,dfv

dk,kp(xi,-yi,0),ux,,,,uy
dk,kp(xi,-yi,0),uz,dfv

dk,kp(-xi,yi,0),ux,,,,uy
dk,kp(-xi,yi,0),uz,dfv

dk,kp(-xi,-yi,0),ux,,,,uy
dk,kp(-xi,-yi,0),uz,dfv
*enddo
lesize,all,,,1
lmesh,all
/solu
antype,0
nlgeom,on
nsubst,10
solve
finish
/prep7
upgeom,1,last,last,ex822,rst
*do,i,1,netnum+1
xi=(i-1)*netsiz
yi=(netnum+1-i)*netsiz
dk,kp(xi,yi,0),uz
dk,kp(xi,-yi,0),uz
dk,kp(-xi,yi,0),uz
dk,kp(-xi,-yi,0),uz
*enddo
*do,i,1,5
finish
/solu
solve
finish
/prep7
upgeom,1,last,last,ex822,rst
*enddo

mp,ex,1,2.0e11
r,1,a,t0/(a*2.0e11)
/solu
time,1
solve
time,2
f,all,fz,-deadld*netsiz*netsiz
solve