e7.02.txt

185个ANSYS工程结构数值分析非常实用的命令流

!EX7.2A 集中荷载作用下圆弧无铰拱的屈曲特征值
!beam189单元
finish
/clear
/prep7
r=8
l=10
b=7
h=0.5
p=1e8
et,1,beam189,1,1
mp,ex,1,3.3e10
mp,prxy,1,0.3
sectype,1,beam,rect
secdata,b,h
*afun,deg
cita=asin(0.5*l/r)
csys,1
k,1,r,90+cita
k,2,r,90
k,3,r,90-cita
k,10,2*r,90
l,1,2
l,2,3
csys,0
dk,1,all
dk,3,all
latt,1,,1,,10,,1
lesize,all,,,10
lmesh,all
fk,2,fy,-p
finish
/solu
pstres,on
solve
finish
/solu
antype,1
bucopt,lanb,2
mxpand,2
outres,all,all
solve
finish
/post1
set,list

!EX7.2B 集中荷载作用下圆弧无铰拱的屈曲特征值
!-----------------------
!BEAM4单元
finish
/clear
/prep7
r=8
l=10
b=7
h=0.5
p=1e8
et,1,beam4
mp,ex,1,3.3e10
mp,prxy,1,0.3
r,1,b*h,b*h**3/12,h*b**3/12,b,h
rmore,,b*h**3/3
*afun,deg
cita=asin(0.5*l/r)
csys,1
k,1,r,90+cita
k,2,r,90
k,3,r,90-cita
k,10,2*r,90
l,1,2
l,2,3
csys,0
dk,1,all
dk,3,all
latt,1,1,1
lesize,all,,,10
lmesh,all
fk,2,fy,-p
finish
/solu
pstres,on
solve
finish
/solu
antype,1
bucopt,lanb,2
mxpand,2
outres,all,all
solve
finish
/post1
set,list
!EX7.2C 集中荷载作用下圆弧无铰拱的屈曲特征值
!-----------------------
!shell93单元
finish
/clear
/prep7
r=8
l=10
b=7
h=0.5
p=1e8
et,1,shell93
mp,ex,1,3.3e10
mp,prxy,1,0.3
r,1,h
*afun,deg
cita=asin(0.5*l/r)
csys,1
k,1,r,90+cita
k,2,r,90
k,3,r,90-cita
k,10,r,90,b
l,1,2
l,2,3
l,2,10
csys,0
adrag,1,2,,,,,3
ldele,3
dl,8,,all
dl,5,,all
esize,0.5
amesh,all
nsel,s,loc,x,0
*get,nodenum,node,,count
f,all,fy,-p/nodenum
allsel,all
finish
/solu
pstres,on
solve
finish
/solu
antype,1
bucopt,lanb,2
mxpand,2
outres,all,all
solve
finish
/post1
set,list
!EX7.2D 集中荷载作用下圆弧无铰拱的屈曲特征值
!------------------
!solid95单元
finish
/clear
/prep7
r=8
l=10
b=7
h=0.5
p=1e8
et,1,solid95
mp,ex,1,3.3e10
mp,prxy,1,0.3
*afun,deg
cita=asin(0.5*l/r)
cyl4,,,r-h/2,90-cita,r+h/2,90+cita,b
asel,s,,,5,6
da,all,all
allsel,all
esize,0.5
vmesh,all
nsel,s,loc,x,0
nsel,r,loc,y,r+h/2
*get,nodenum,node,,count
f,all,fy,-p/nodenum
allsel,all
finish
/solu
pstres,on
solve
finish
/solu
antype,1
bucopt,lanb,2
mxpand,2
outres,all,all
solve
finish
/post1
set,list
solid95	shell93	beam189	beam4
12.678	13.552	12.636	13.211
19.828	20.001	19.174	20.554