e2.02.txt

185个ANSYS工程结构数值分析非常实用的命令流

!EX2.2螺栓杆建模命令流
FINISH
/CLEAR
/PREP7
!1.定义几何参数
D=20
L=60
B=46
P=2.5
DW=28.2
SMAX=30
KGC=12.5
C=0.8
REFA=60
*AFUN,DEG
H=0.5*P*COS(REFA/2)/SIN(REFA/2)
D1=D-2*5/8*H
D2=D-2*3/8*H
DBANGL=30
TKPD=30
!2.创建螺旋线（采用分段螺旋线）
CSYS,1
N=(B-3*P/4)/P
TDEG=N*360
TDEG1=MOD(TDEG,TKPD)
N0=(TDEG-TDEG1)/TKPD+1
*DO,I,1,N0
CTA=(I-1)*TKPD
Z=P/360*CTA
K,I,D1/2,CTA,Z
*ENDDO
*IF,TDEG1,LT,1.0E-2,THEN
*ELSE
N0=N0+1
CTA=CTA+TDEG1
Z=P/360*CTA
K,N0,D1/2,CTA,Z
*ENDIF
*DO,I,1,N0-1
L,I,I+1
*ENDDO
CM,L1CM,LINE
!3.在螺旋线端部创建齿截面
CSYS,0
KM=KPINQR(0,14)
K,KM+1,D1/2,,-3*P/8
K,KM+2,D1/2,,3*P/8
K,KM+3,D/2,,P/16
K,KM+4,D/2,,-P/16
A,KM+1,KM+2,KM+3,KM+4
VDRAG,1,,,,,,L1CM
NUMCMP,ALL
!4.创建圆柱体（未考虑退刀槽）
WPOFF,0,0,-3*P/8
CYL4,,,D1/2,,,,B
V1=VLINQR(0,14)
!5.创建部分螺杆的圆柱体及头部圆柱体
WPOFF,,,B
CYL4,,,D/2,,,,L-B
V2=V1+1
WPOFF,,,L-B
CYL4,,,DW/2,,,,C
V3=V1+2
!6.螺杆头部,正六边形棱柱
RPRISM,C,KGC,6,,,SMAX/2
V4=V1+3
!7.螺杆齿部端倒角处理
WPCSYS 
CONE,D,D,-3*P/8,(D-D1)/2-3*P/8
CONE,D1/2,D/2,-3*P/8,(D-D1)/2-3*P/8
V5=VLINQR(0,14)
VSBV,V5-1,V5
V5=VLINQR(0,14)
VSEL,S,LOC,Z,0,2*P
VSEL,A,,,V1
VSEL,U,,,V5
CM,V2CM,VOLU
VSEL,A,,,V5
VSBV,V2CM,V5
ALLSEL
!8.倒C处角，方向同上
VSEL,NONE
WPOFF,,,L-3*P/8
CONE,D,D,0,C
CONE,DW/2-C,DW/2,0,C
*GET,V5,VOLU,0,NUM,MIN
V6=VLNEXT(V5)
VSBV,V5,V6
*GET,V5,VOLU,0,NUM,MIN
ALLSEL
VSBV,V3,V5
!9.螺杆头倒角，即对正六棱柱倒角。采用球体相减完成
VSEL,NONE
RQ=SMAX/2/SIN(DBANGL)
WPOFF,,,KGC-RQ*COS(DBANGL)
SPHERE,RQ,RQ+KGC
*GET,V5,VOLU,0,NUM,MIN
ALLSEL
VSBV,V4,V5
WPCSYS
NUMCMP,ALL