e2.04.txt

185个ANSYS工程结构数值分析非常实用的命令流

!EX2.4 V带轮建模命令流（未含键槽）
FINISH
/CLEAR
/PREP7
!1.定义几何参数
DD=200
FAI=38
B=13
Z=4
S=14
HA=3
HF=9
E=15
F=10
KS=8
R1=0.5
R2=1.0
R3=1.5
DTA=6
C1=2
C2=2
PD=25
D0=24
D1=1.9*D0
S1=1.5*S
S2=0.5*S
L=2*D0
DA=DD+2*HA
UB=(Z-1)*E+2*F
RK1=DD/2-HF-DTA-0.5*(UB-S)/PD-S2
RK2=D1/2+0.5*(L-S)/PD+S1
RK=(RK1-RK2)/2
DK=RK1+RK2
!2.创建轮槽部分截面
*AFUN,DEG
Y0=HF+HA
B0=B-2*TAN(FAI/2)*Y0
LOCAL,12,0,-UB/2,DD/2-HF
K,,0,Y0
K,,F-B/2,Y0
K,,F-B0/2
*DO,I,1,Z-1
X0=F+(I-1)*E
K,,X0+B0/2
K,,X0+B/2,Y0
K,,X0+E-B/2,Y0
K,,X0+E-B0/2
*ENDDO
K,,UB-F+B0/2
K,,UB-F+B/2,Y0
K,,UB,Y0
*GET,KP1,KP,0,NUM,MAX
*DO,I,1,KP1-1
L,I,I+1
*ENDDO	
*GET,L1,LINE,0,NUM,MAX
*DO,I,1,Z
J=4*(I-1)
LFILLT,J+1,J+2,R1
LFILLT,J+2,J+3,R2
LFILLT,J+3,J+4,R2
LFILLT,J+4,J+5,R1
*ENDDO
CSDELE,12
KSLL,S
KSEL,INVE
KDELE,ALL
ALLSEL
NUMCMP,ALL
CM,L1CM,LINE
!3.创建带轮腹板及轴部
!3.1创建关键点和线
*GET,KP1,KP,0,NUM,MAX
Y0=DD/2-HF-DTA
K,,-UB/2,Y0+C1-C1/PD
K,,-UB/2+C1,Y0-C1/PD
K,,-S/2,Y0-0.5*(UB-S)/PD
K,,-S/2,D1/2+0.5*(L-S)/PD
K,,-L/2,D1/2
K,,-L/2,D0/2+C2
K,,-L/2+C2,D0/2
L,1,KP1+1
*DO,I,KP1+1,KP1+6
L,I,I+1
*ENDDO
!3.2对腹板与轴部或轮槽部分倒角
LSEL,S,LOC,Y,Y0-C1/PD,D1/2+0.5*(L-S)/PD
*GET,L1,LINE,0,NUM,MIN
L2=LSNEXT(L1)
LFILLT,L1,L2,R3
LSEL,ALL
LFILLT,L2,L2+1,R3
CMSEL,U,L1CM
!3.3对称生成另侧腹板及轴截面
LSYMM,X,ALL
KSEL,S,LOC,Y,D0/2
*GET,KP1,KP,0,NUM,MIN
KP2=KPNEXT(KP1)
L,KP1,KP2
ALLSEL
NUMMRG,ALL
NUMCMP,ALL
!4.创建带轮截面并旋转创建体
AL,ALL
*GET,KP1,KP,0,NUM,MAX
K,KP1+10,-UB/2
K,KP1+20,UB/2
VROTAT,ALL,,,,,,KP1+10,KP1+20,,KS
KDELE,KP1+10,KP1+20,10
!5.创建腹板上的圆孔
CM,V1CM,VOLU
WPOFF,UB/2
WPROTA,,,90
X0=DK/2*SIN(180/KS
Y0=DK/2*COS(180/KS)
CYL4,X0,Y0,RK,,,,-UB
*GET,V1,VOLU,,NUM,MAX
CSWPLA,12,1
VGEN,KS,V1,,,,360/KS
CMSEL,U,V1CM
CM,V2CM,VOLU
ALLSEL
VSBV,V1CM,V2CM
!6.整理和视图
CSDELE,12
WPCSYS
NUMCMP,ALL
/VIEW,1,1,1,1
/ANG,1,-90,YS,1
VPLOT