e8.24.txt

185个ANSYS工程结构数值分析非常实用的命令流

!ex8.24 伞形索网找形分析
finish
/clear
/filname,ex824
/prep7
netn=36
l0=60
r0=1.2
nets=l0/netn
f=25.0
a1=0.01
a2=0.0006
a3=0.01
t1=1800e3
t2=200e3
t3=500e3
em=1.8e11
istran=0.999
et,1,link10
r,1,a1,t1/(a1*em)
r,2,a2,istran
r,3,a3,t3/(a3*em)
mp,ex,1,t2/(istran*a2)
mp,prxy,1,0.3
mp,ex,2,em
mp,prxy,2,0.3
!创建边界线
csys,1
*do,i,1,12
k,i,l0/2,(i-1)*30
*enddo
*do,i,1,4
k,12+i,r0,(i-1)*90
*enddo
csys,0
*do,i,1,11
l,i,i+1
*enddo
l,1,12
!将边界线切分
wpoff,-l0/2
wprota,,,90
*do,i,1,netn-1
wpoff,,,nets
lsbw,all
*enddo
wpcsys,-1
wpoff,,-l0/2
wprota,,-90
*do,i,1,netn-1
wpoff,,,nets
lsbw,all
*enddo
wpcsys,-1
cm,outline,line
!创建边界上点与点的连线
*do,i,1,netn-1
xi=(i-netn/2)*nets
ksel,s,loc,x,xi
*get,kp1,kp,,num,min
kp2=kpnext(kp1)
l,kp1,kp2
*enddo
*do,i,1,netn-1
yi=(i-netn/2)*nets
ksel,s,loc,y,yi
*get,kp1,kp,,num,min
kp2=kpnext(kp1)
l,kp1,kp2
*enddo
allsel,all
!删除对称轴上的线并重建
lsel,s,length,,l0
ldele,all
lsel,all
l,13,1
l,14,4
l,15,7
l,16,10
lovlap,all
lsel,s,loc,x,0
lsel,a,loc,y,0
cm,mainlin,line
cmsel,a,outline
lsel,inve
cm,midline,line
latt,1,2,1
cmsel,s,mainlin
latt,2,1,1
cmsel,s,outline
latt,2,3,1
allsel,all
lesize,all,,,1
lmesh,all
!选择边界线上的特征点施加约束
ksel,s,,,1,12
dk,all,all
ksel,s,,,13,16
dk,all,ux,,,,uy
dk,all,uz,f
ksel,all

/solu
antype,0
nlgeom,on
nsubst,10
solve
finish
/prep7
upgeom,1,last,last,ex824,rst
ksel,s,,,13,16
dk,all,uz
ksel,all
*do,i,1,6
finish
/solu
solve
finish
/prep7
upgeom,1,last,last,ex824,rst
*enddo
/post1
set,1,last
plesol,smisc,1
cmsel,s,mainlin
esll,s
plesol,smisc,1
cmsel,s,midline
esll,s
plesol,smisc,1
cmsel,s,outline
esll,s
plesol,smisc,1