e6.34.txt

王新敏的ANSYS工程结构数值分析命令流 王新敏的ANSYS工程结构数值分析命令流

!EX6.34 3D梁单元与3D实体单元刚接
!采用刚性区法
finish
/clear
/prep7
b=10
h=20
l1=100
l2=150
a1=b*h
i1=b*h**3/12
i2=h*b**3/12
et,1,solid95
et,2,beam4
mp,ex,1,3e5
mp,prxy,1,0.3
r,1,a1,i1,i2,b,h
blc5,,,b,h,l1
wprota,0,90 
vsbw,all
wprota,,,90 
vsbw,all
wpcsys,-1
kp0=kp(0,0,l1)
k,100,,,l1+l2
l,kp0,100
lsel,s,loc,z,l1+1,l1+l2
latt,1,1,2
lesize,all,,,10
lmesh,all
vatt,1,,1
esize,2.5
lsel,s,loc,z,1,l1-1
lesize,all,b/2
mshape,0
mshkey,1
vmesh,all
asel,s,loc,z,0
da,all,all
fk,100,fx,100
fk,100,fy,-200
nsel,s,loc,z,l1
cerig,1,all
allsel,all
/solu
solve
/post1
pldisp,1
!===========================
!采用mpc184
finish
/clear
/prep7
b=10
h=20
l1=100
l2=150
a1=b*h
i1=b*h**3/12
i2=h*b**3/12
et,1,solid95
et,2,beam4
et,3,mpc184,1
mp,ex,1,3e5
mp,prxy,1,0.3
r,1,a1,i1,i2,b,h
blc5,,,b,h,l1
wprota,0,90 
vsbw,all
wprota,,,90 
vsbw,all
wpcsys,-1
kp0=kp(0,0,l1)
k,100,,,l1+l2
l,kp0,100
lsel,s,loc,z,l1+1,l1+l2
latt,1,1,2
lesize,all,,,10
lmesh,all
vatt,1,,1
esize,2.5
lsel,s,loc,z,1,l1-1
lesize,all,b/2
mshape,0
mshkey,1
vmesh,all
lsel,s,loc,z,l1
latt,,,3
lmesh,all
asel,s,loc,z,0
da,all,all
fk,100,fx,100
fk,100,fy,-200
/solu
solve
/post1
pldisp,1
!----------------------------
!实体模型
finish
/clear
/prep7
b=10
h=20
l1=100
l2=150
et,1,solid95
mp,ex,1,3e5
mp,prxy,1,0.3
blc5,,,b,h,l1+l2
vatt,1,,1
esize,2.5
lsel,s,loc,z,1,l1+l2-1
lesize,all,b/2
mshape,0
mshkey,1
vmesh,all
asel,s,loc,z,0
da,all,all
nsel,s,loc,z,l1+l2
nsel,r,loc,y,0
*get,n1,node,,count
f,all,fy,-200/n1
nsel,s,loc,z,l1+l2
nsel,r,loc,x,0
*get,n1,node,,count
f,all,fx,100/n1
allsel,all
/solu
solve
/post1
pldisp,1