configure.in

libfxb是linux下只写操作framebuffer的一个轻量级的库。

dnl
dnl libfbx configure.in -- process with autoconf to generate configure
dnl
dnl $Id: configure.in,v 1.25 2001/02/25 20:40:07 lethal Exp $
dnl
AC_INIT(libfbx/libfbx.h)
AM_CONFIG_HEADER(config.h)

LIBFBX_LIBRARY_NAME=libfbx
LIBFBX_SHORT_NAME=fbx
LIBFBX_MAJOR_VERSION=0
LIBFBX_MINOR_VERSION=2
LIBFBX_MICRO_VERSION=0
LIBFBX_GUI_MAJOR_VERSION=0
LIBFBX_GUI_MINOR_VERSION=1
LIBFBX_GUI_MICRO_VERSION=1

AC_SUBST(LIBFBX_MAJOR_VERSION)
AC_SUBST(LIBFBX_MINOR_VERSION)
AC_SUBST(LIBFBX_MICRO_VERSION)
AC_SUBST(LIBFBX_GUI_MAJOR_VERSION)
AC_SUBST(LIBFBX_GUI_MINOR_VERSION)
AC_SUBST(LIBFBX_GUI_MICRO_VERSION)

LIBFBX_LIBRARY_VERSION=$LIBFBX_MINOR_VERSION:$LIBFBX_MICRO_VERSION:$LIBFBX_MAJOR_VERSION
LIBFBX_GUI_LIBRARY_VERSION=$LIBFBX_GUI_MINOR_VERSION:$LIBFBX_GUI_MICRO_VERSION:$LIBFBX_GUI_MAJOR_VERSION

AC_SUBST(LIBFBX_LIBRARY_VERSION)
AC_SUBST(LIBFBX_GUI_LIBRARY_VERSION)

PACKAGE=$LIBFBX_LIBRARY_NAME
AC_SUBST(LIBFBX_LIBRARY_NAME)
AC_SUBST(LIBFBX_SHORT_NAME)

LIBFBX_VERSION=$LIBFBX_MAJOR_VERSION.$LIBFBX_MINOR_VERSION.$LIBFBX_MICRO_VERSION
LIBFBX_RELEASE=$LIBFBX_MAJOR_VERSION.$LIBFBX_MINOR_VERSION
LIBFBX_GUI_VERSION=$LIBFBX_GUI_MAJOR_VERSION.$LIBFBX_GUI_MINOR_VERSION.$LIBFBX_GUI_MICRO_VERSION
LIBFBX_GUI_RELEASE=$LIBFBX_GUI_MAJOR_VERSION.$LIBFBX_GUI_MINOR_VERSION

AC_SUBST(LIBFBX_RELEASE)
AC_SUBST(LIBFBX_VERSION)
AC_SUBST(LIBFBX_GUI_RELEASE)
AC_SUBST(LIBFBX_GUI_VERSION)

AC_DEFINE_UNQUOTED(LIBFBX_MAJOR_VERSION, $LIBFBX_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(LIBFBX_MINOR_VERSION, $LIBFBX_MINOR_VERSION)
AC_DEFINE_UNQUOTED(LIBFBX_MICRO_VERSION, $LIBFBX_MICRO_VERSION)
AC_DEFINE_UNQUOTED(LIBFBX_GUI_MAJOR_VERSION, $LIBFBX_GUI_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(LIBFBX_GUI_MINOR_VERSION, $LIBFBX_GUI_MINOR_VERSION)
AC_DEFINE_UNQUOTED(LIBFBX_GUI_MICRO_VERSION, $LIBFBX_GUI_MICRO_VERSION)

VERSION=$LIBFBX_VERSION

AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)

dnl Checks for programs.
AC_PROG_CC
AM_PROG_LIBTOOL
AM_SANITY_CHECK
AC_LANG_C

dnl Add some flags for compile time
CFLAGS="$CFLAGS -Wall"
AC_SUBST(CFLAGS)

dnl Checks for libraries.
dnl The following checks for PNG were taken from the SNG package

AC_ARG_WITH(png,[  --with-png=DIR          location of png lib/inc],
                [LDFLAGS="${LDFLAGS} -L${withval}"
                CFLAGS="${CFLAGS} -I${withval}"])

AC_ARG_WITH(png-lib,[  --with-png-lib=DIR      location of png library],
                    [LDFLAGS="${LDFLAGS} -L${withval}"])

AC_ARG_WITH(png-inc,[  --with-png-inc=DIR      location of png includes],
                    [CFLAGS="${CLFAGS} -I${withval}"])

AC_CHECK_LIB(z, deflate)
AC_CHECK_LIB(png, png_info_init, , , $LIBS)

if test "$ac_cv_lib_png_png_info_init" = "no"; then
	AC_WARN([PNG library not found. Building without PNG support.])
fi

if test "$ac_cv_lib_z_deflate" = "no"; then
        AC_WARN([ZLIB library is missing. You will need it for PNG support.])
fi

if test "$ac_cv_lib_png_png_info_init" = "yes" && test "$ac_cv_lib_z_deflate" = "yes"; then
	AC_DEFINE(HAVE_PNG)
fi

if test "$prefix" = "NONE"; then
	MODULEDIR=/usr/local/lib/$LIBFBX_LIBRARY_NAME/modules
	IMAGEDIR=/usr/local/share/$LIBFBX_LIBRARY_NAME/images
else
	MODULEDIR=$prefix/lib/$LIBFBX_LIBRARY_NAME/modules
	
	dnl
	dnl This could probably use fixing so that we follow the
	dnl $datadir variable.. but if we do that it substitutes in
	dnl $prefix/share into the actual definition, which is of
	dnl no use to us. Ideas? -Lethal
	dnl
	IMAGEDIR=$prefix/share/$LIBFBX_LIBRARY_NAME/images
fi

AC_ARG_WITH(moduledir,
  [  --with-moduledir=PATH   directory to install modules to],
  [MODULEDIR=$withval],
)

AC_DEFINE_UNQUOTED(MODULEDIR, "${MODULEDIR}")
AC_SUBST(MODULEDIR)

AC_DEFINE_UNQUOTED(IMAGEDIR, "${IMAGEDIR}")
AC_SUBST(IMAGEDIR)

dnl
dnl Add any new targets for optimizations here.
dnl
case "$target" in
	i[3-6]86-*)
		AC_DEFINE(__i386__)
	    ;;
	dnl
	dnl FIXME: Add support for MIPS and SuperH (once we
	dnl know for a fact that they actually _work_).
	dnl
esac

AC_CHECK_LIB(c, main)
AC_CHECK_LIB(m, main)

dnl Check for libtimer and libkbd, both are essential.
AM_PATH_LIBTIMER(0.1.0, , AC_MSG_ERROR([*** libtimer >= 0.1.0 not installed - please install first ***]))
AM_PATH_LIBKBD(0.1.0, , AC_MSG_ERROR([*** libkbd >= 0.1.0 not installed - please install first ***]))

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(png.h fcntl.h sys/ioctl.h unistd.h linux/fb.h)

dnl Checks for typedefs, structures, and compiler characteristics.

dnl Checks for library functions.
AC_PROG_GCC_TRADITIONAL
AC_FUNC_MMAP

AC_OUTPUT(Makefile \
          libfbx.spec \
          libfbx-config \
	  tests/Makefile \
          libfbx/Makefile \
          libfbx/drivers/Makefile \
          libfbx/arch/Makefile \
	  libfbx/gui/Makefile \
)