imageshow.asp

asp+sql软件系统

<!--#include file="conn.asp"-->
<%
Response.Buffer = true
Response.Clear

Sub imageshow(filename)
 On error resume next
 Server.scriptTimeOut=360
 Dim fso,fl,flsize,filesname
 Dim objStream,ContentType,isre

 Set fso=Server.CreateObject("Scripting.FileSystemObject")
  If Not fso.FileExists(filename) Then
	Call imageshow(Server.MapPath("Images/error.jpg"))
	Exit Sub  
  End If
  Set fl=fso.getfile(filename)
  flsize=fl.size
  filesname=fl.name
  Set fl=Nothing
  Set fso=Nothing
  If err Then
	Response.Write("<h1>错误: </h1>" & err.Description & "<p>")
	Response.End 
  End If

  Set objStream = Server.CreateObject("ADODB.Stream")
  objStream.Open
  objStream.Type = 1
  objStream.LoadFromFile filename

   Select Case lcase(Right(filesname, 4))
    Case ".asf"
     ContentType = "video/x-ms-asf"
    Case ".avi"
     ContentType = "video/avi"
    Case ".doc"
     ContentType = "application/msword"
    Case ".zip"
     ContentType = "application/zip"
    Case ".xls"
     ContentType = "application/vnd.ms-excel"
    Case ".gif"
     ContentType = "image/gif"
    Case ".jpg", "jpeg"
     ContentType = "image/jpeg"
    Case ".wav"
     ContentType = "audio/wav"
    Case ".mp3"
     ContentType = "audio/mpeg3"
    Case ".mpg", "mpeg"
     ContentType = "video/mpeg"
    Case ".rtf"
     ContentType = "application/rtf"
    Case ".htm", "html"
     ContentType = "text/html"
    Case ".txt"
     ContentType = "text/plain"
    Case Else
     ContentType = "application/octet-stream"
   End Select

   Response.AddHeader "Content-Disposition", "attachment; filename=" & filesname
   Response.AddHeader "Content-Length", flsize

   Response.Charset = "UTF-8"
   Response.ContentType = ContentType

   Response.BinaryWrite objStream.Read
   Response.Flush
   response.Clear()
  objStream.Close
  Set objStream = Nothing

End Sub

Dim filename
filename=Trim(Request.QueryString("filename"))
filename=Replace(filename,"..","")
filename=Replace(filename,"/","")
filename=Replace(filename,"\","")
If Request.Servervariables("HTTP_REFERER")="" Or InStr(Request.Servervariables("HTTP_REFERER"),Request.Servervariables("SERVER_NAME"))=0 Or filename="" Then
	Call imageshow(Server.MapPath("Images/error.jpg"))
Else
	Call imageshow(Server.MapPath(UplaodPath&filename))
End If
%>