📄 admin_login.asp

📁 asp+sql软件系统
💻 ASP
字号:
<!--#include file="../conn.asp"-->
<!--#include file="../Include/MD5.asp"-->
<%
ErrTitle = "管理员登陆失败："
SucTitle = "管理员登陆成功："
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>后台管理员登陆</title>
</head>

<body>
<%
Select Case Action
	Case "LoginCheck"
		Call LoginCheck()
	Case Else
		Call Main()
End Select

Sub Main()
%>
<form name="form1" method="post" action="?Action=LoginCheck">
<table width="500" border="1" align="center" cellpadding="2" cellspacing="0">
  <tr>
    <td colspan="2">后台管理员登陆</td>
  </tr>
  <tr>
    <td width="149" align="right">账号</td>
    <td width="337"><input name="name" type="text" id="name" size="25" maxlength="25"></td>
  </tr>
  <tr>
    <td align="right">密码</td>
    <td><input name="pass" type="password" id="pass" size="25" maxlength="25">
    </td>
  </tr>
  <tr>
    <td align="right">认证码</td>
    <td><input name="getcode" type="text" id="getcode" size="15" maxlength="15">
       <img src="../Include/GetCode.asp"></td>
  </tr>
  <tr align="center">
    <td height="22" colspan="2"><input type="submit" name="Submit" value="jstu登陆">
      <input type="reset" name="Submit2" value="数据重置"></td>
  </tr>
</table>
</form>
<%
End Sub

Sub LoginCheck()
Dim Name,Pass,getcode
Name = Trim(Request.Form("name"))
Pass = Trim(Request.Form("pass"))
Getcode = Trim(Request.Form("getcode"))

	If Name="" Or Pass="" Then
		ErrInfo = ErrInfo&"<li>请输入账号与密码。</li>"
		FoundErr = True
	ElseIf Getcode="" Then
		ErrInfo = ErrInfo&"<li>请输入认证码。</li>"
		FoundErr = True
	Else
		Name = NetCom.checkStr(Name)
		Pass = MD5(Pass,16)
		Call OpenDatabase()
			Set Rs = Conn.Execute("SELECT Adminid,Adminname,Adminpassword FROM [Admin] WHERE Adminname='"&Name&"' AND Flag=1")
				If Rs.EOF Then
					ErrInfo = ErrInfo&"<li>无此管理员或此管理员已经被禁用。</li>"
					FoundErr = True
				ElseIf Pass<>Rs(2) Then
					ErrInfo = ErrInfo&"<li>账号与密码不相符。</li>"
					FoundErr = True
				ElseIf CInt(Getcode)<>CInt(Session("GetCode")) Then
					ErrInfo = ErrInfo&"<li>认证码不正确。</li>"
					FoundErr = True
				Else
					Session("NetCom_Admin_Id")=Rs(0)
					Session("NetCom_Admin_Name")=Rs(1)
					Session("NetCom_Admin_Password")=Rs(2)
					Conn.Execute("INSERT INTO [AdminLogin](Adminid,Adminname,Loginip)VALUES('"&Rs(0)&"','"&Rs(1)&"','"&Request.ServerVariables("REMOTE_ADDR")&"')")
				End If
			Rs.Close
			Set Rs = Nothing
		Call CloseDatabase()
	End If
	If FoundErr Then
		Call ErrorMsg()
	Else
		Call SucMsg("<li>登陆成功，欢迎"&Name&"管理员的到来！</li>","Admin_Index.asp")
	End If
End Sub
%>
</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -