📄 admin_class.asp

📁 asp+sql软件系统
💻 ASP
字号:
<!--#include file="../conn.asp"-->
<!--#include file="CheckAdmin.asp"-->
<%
ErrTitle = "管理分类出错："
SucTitle = "管理分类成功："
%>

<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>管理分类</title>
</head>

<body>
<%
Dim Cid,CRs
Cid=Request.QueryString("Cid")
Dim Cname,Cflag
Cname=Trim(Request.Form("Cname"))
Cflag=Request.Form("Cflag")

Select Case Action
	Case "Add"
		Call Add()
	Case "SaveAdd"
		Call SaveAdd()
	Case "Edit"
		Call Edit()
	Case "SaveEdit"
		Call SaveEdit()
	Case "Del"
		Call Del()
	Case Else
		Call Main()
End Select

Sub Main()
Call OpenDatabase()
Set Rs=Conn.Execute("SELECT Classid,Classname FROM [Class] WHERE Flag=0")
%>
<table width="50%" border="1" align="center" cellpadding="2" cellspacing="0">
  <tr>
    <td>管理分类</td>
  </tr>
<%If Rs.Eof Then%>
  <tr>
    <td>暂无分类,<a href="Admin_Class.asp?Action=Add">添加分类</a></td>
  </tr>
<%Else
While Not Rs.EOF%>
  <tr>
    <td>主类: <%=Rs(1)%> <a href="Admin_Class.asp?Action=Add&Cid=0">添加</a> | <a href="Admin_Class.asp?Action=Edit&Cid=<%=Rs(0)%>">修改</a> | <a href="Admin_Class.asp?Action=Del&Cid=<%=Rs(0)%>">删除</a></td>
  </tr>
<%
Set CRs=Conn.Execute("SELECT Classid,Classname FROM [Class] WHERE Flag="&Rs(0)&"")
If CRs.Eof Then
%>
  <tr>
    <td>此主暂无任何子类,<a href="Admin_Class.asp?Action=Add&Cid=<%=Rs(0)%>">添加子类</a></td>
  </tr>
<%Else
While Not CRs.EOF%>
  <tr>
    <td>&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;子类: <%=CRs(1)%> <a href="Admin_Class.asp?Action=Add&Cid=<%=Rs(0)%>">添加</a> | <a href="Admin_Class.asp?Action=Edit&Cid=<%=CRs(0)%>">修改</a> | <a href="Admin_Class.asp?Action=Del&Cid=<%=CRs(0)%>">删除</a></td>
  </tr>
<%
CRs.MoveNext
Wend

CRs.Close
Set CRs=Nothing

End If
Rs.MoveNext
Wend

End If%>
</table>
<%
Rs.Close
Set Rs=Nothing
Call CloseDatabase()
End Sub

Sub Add()
%>
<form name="form1" method="post" action="Admin_Class.asp?Action=SaveAdd">
<table width="50%" border="1" align="center" cellpadding="2" cellspacing="0">
  <tr>
    <td colspan="2">添加分类</td>
  </tr>
  <tr>
    <td width="25%" align="right">名称</td>
    <td width="75%"><input name="Cname" type="text" id="Cname"></td>
  </tr>
  <tr>
    <td align="right">标识</td>
    <td><select name="Cflag">
    <option value="0" <%If CInt(Cid)=0 Then Response.Write ("selected")%>>主类</option>
    <%
    Call OpenDatabase()
    Set Rs=Conn.Execute("SELECT Classid,Classname FROM [Class] WHERE Flag=0")
    While Not Rs.EOF
    %>
    <option value="<%=Rs(0)%>" <%If CInt(Cid)=Rs(0) Then Response.Write ("selected")%>><%=Rs(1)%></option>
    <%
    Rs.MoveNext
    Wend
    Rs.Close
    Set Rs=Nothing
    Call CloseDatabase()%>
    </select></td>
  </tr>
  <tr align="center">
    <td colspan="2"><input type="submit" name="Submit" value="添加"></td>
    </tr>
</table>
</form>
<%End Sub

Sub SaveAdd()
If Cname="" or Cflag="" Then
	ErrInfo = ErrInfo&"<li>名称与标识不能为空。</li>"
	FoundErr=True
End If

If FoundErr Then
	Call ErrorMsg()
Else
    Call OpenDatabase()
	Conn.Execute("INSERT INTO [Class](Classname,Flag)VALUES('"&Cname&"','"&Cflag&"')")
    Call CloseDatabase()
    Call SucMsg("<li>添加分类成功！</li>","Admin_Class.asp")
End If
End Sub

Sub Edit()
Call OpenDatabase()
Set Rs=Conn.Execute("SELECT Classname,Flag FROM [Class] WHERE Classid="&CInt(Cid)&"")
%>
<form name="form1" method="post" action="Admin_Class.asp?Action=SaveEdit&Cid=<%=Cid%>">
<table width="50%" border="1" align="center" cellpadding="2" cellspacing="0">
  <tr>
    <td colspan="2">修改分类</td>
  </tr>
  <tr>
    <td width="25%" align="right">名称</td>
    <td width="75%"><input name="Cname" type="text" id="Cname" value="<%=Rs(0)%>"></td>
  </tr>
  <tr>
    <td align="right">标识</td>
    <td><select name="Cflag">
    <option value="0" <%If Rs(1)=0 Then Response.Write ("selected")%>>主类</option>
    <%
    Set CRs=Conn.Execute("SELECT Classid,Classname FROM [Class] WHERE Flag=0")
    While Not CRs.EOF
    %>
    <option value="<%=CRs(0)%>" <%If Rs(1)=CRs(0) Then Response.Write ("selected")%>><%=CRs(1)%></option>
    <%
    CRs.MoveNext
    Wend
    CRs.Close
    Set CRs=Nothing%>
    </select></td>
  </tr>
  <tr align="center">
    <td colspan="2"><input type="submit" name="Submit" value="修改"></td>
    </tr>
</table>
</form>
<%
Rs.Close
Set Rs=Nothing
Call CloseDatabase()
End Sub

Sub SaveEdit()
If Cname="" or Cflag="" Then
	ErrInfo = ErrInfo&"<li>名称与标识不能为空。</li>"
	FoundErr=True
End If

If FoundErr Then
	Call ErrorMsg()
Else
    Call OpenDatabase()
	Conn.Execute("UPDATE [Class] SET Classname='"&Cname&"',Flag="&Cflag&" WHERE Classid="&CInt(Cid)&"")
    Call CloseDatabase()
    Call SucMsg("<li>修改分类成功！</li>","Admin_Class.asp")
End If
End Sub

Sub Del()
Call OpenDatabase()
	Conn.Execute("DELETE FROM [Class] WHERE Classid="&CInt(Cid)&"")
	Conn.Execute("DELETE FROM [Class] WHERE Flag="&CInt(Cid)&"")
	Call SucMsg("<li>删除分类成功！</li>","Admin_Class.asp")
Call CloseDatabase()
End Sub

%>
</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -