function.asp

来自「BBS论坛的开发和设计」· ASP 代码 · 共 87 行

<%
'#################################################################################
'#	SetSafeStr 将字符串转换成用于网页显示和SQL查询的安全字符串
'#		参数：str {即将转换的字符串}
'#
'#		返回：字符串
'#################################################################################
Function SetSafeStr(str)

	Dim strResult,iLen,i

	If IsNULL(str) Then
		SetSafeStr = ""
		Exit Function
	End If

	iLen = Len(str)
	strResult = ""

	For i = 1 To iLen
		Select Case Mid(str,i,1)
			Case "<"
				strResult = strResult & "&lt;"
			Case ">"
				strResult = strResult & "&gt;"
			Case Chr(13)
				strResult = strResult & "<br>"
			Case Chr(34)
				strResult = strResult & "&quot;"
			Case "&"
				strResult = strResult & "&amp;"
			Case Chr(32)
				strResult = strResult & "&nbsp;"
			Case Chr(9)
				strResult = strResult & "	"
			Case Chr(39)
				strResult = strResult & ""
			Case Else
				strResult = strResult & Mid(str,i,1)

		End Select
	Next 'i

	SetSafeStr = strResult

End Function
'#################################################################################


'#################################################################################
'#	GetSafeStr 从数据库中得到字符串用于在网页控件中还原显示，适应多行文本
'#		参数：str {数据库里的字符串}
'#
'#		返回：字符串
'#################################################################################
Function GetSafeStr(str)

	Dim strResult
	strResult = str

	strResult = Replace (strResult,"<br>",chr(13))
	strResult = Replace (strResult,"''",chr(39))
	strResult = Replace (strResult,"&nbsp;",chr(32))

	strResult = Replace (strResult,"<center><img src=","[img]")
	strResult = Replace (strResult,"></img></center>","[/img]")
	strResult = Replace (strResult,"<font color=CC0000>","[red]")
	strResult = Replace (strResult,"</font>","[/red]")
	strResult = Replace (strResult,"<b>","[b]")
	strResult = Replace (strResult,"</b>","[/b]")
	strResult = Replace (strResult,"<div align=""center"">","[c]")
	strResult = Replace (strResult,"</div>","[/c]")

	GetSafeStr = strResult

End Function
'#################################################################################


'############################################################
'#	出错返回子程序
'############################################################
Sub errorMsg(theError)
response.write"<script language=javascript>alert('"& theError &"');history.back();</script>"
response.End
End Sub
%>