tntjvitemssearchs.pas

TntExUpdate 是 流行的 TntUnicodeControls控件的扩展包.包括很难找到的 TntJVCL 也在里面. TntSysUtils2.pas/TntSysUtilsEx.pa

{-----------------------------------------------------------------------------
The contents of this file are subject to the Mozilla Public License
Version 1.1 (the "License"); you may not use this file except in compliance
with the License. You may obtain a copy of the License at
http://www.mozilla.org/MPL/MPL-1.1.html

Software distributed under the License is distributed on an "AS IS" basis,
WITHOUT WARRANTY OF ANY KIND, either expressed or implied. See the License for
the specific language governing rights and limitations under the License.

The Original Code is: JvItemsSearchs.PAS, released on 2001-02-28.

The Initial Developer of the Original Code is Sébastien Buysse [sbuysse att buypin dott com]
Portions created by Sébastien Buysse are Copyright (C) 2001 Sébastien Buysse.
All Rights Reserved.

Contributor(s): Michael Beck [mbeck att bigfoot dott com].

You may retrieve the latest version of this file at the Project JEDI's JVCL home page,
located at http://jvcl.sourceforge.net

Known Issues:
-----------------------------------------------------------------------------}
// $Id: JvItemsSearchs.pas,v 1.15 2005/04/28 18:25:54 obones Exp $

unit TntJvItemsSearchs;

{$I jvcl.inc}

interface

uses
  {$IFDEF UNITVERSIONING}
  JclUnitVersioning,
  {$ENDIF UNITVERSIONING}
  {$IFDEF COMPILER9_UP}
  Windows,
  {$ENDIF COMPILER9_UP}
  SysUtils, Classes, TntClasses;

type
  // (rom) made them all class functions
  TTntJvItemsSearchs = class(TObject)
  public
    class function SearchExactString(Items: TTntStrings; const Value: WideString;
      CaseSensitive: Boolean = True; StartIndex: Integer = -1): Integer;
    class function SearchPrefix(Items: TTntStrings; Value: WideString;
      CaseSensitive: Boolean = True; StartIndex: Integer = -1): Integer;
    class function SearchSubString(Items: TTntStrings; Value: WideString;
      CaseSensitive: Boolean = True; StartIndex: Integer = -1): Integer;
    class function DeleteExactString(Items: TTntStrings; const Value: WideString; All: Boolean;
      CaseSensitive: Boolean = True): Integer;
  end;

{$IFDEF UNITVERSIONING}
const
  UnitVersioning: TUnitVersionInfo = (
    RCSfile: '$RCSfile: JvItemsSearchs.pas,v $';
    Revision: '$Revision: 1.14 $';
    Date: '$Date: 2005/02/17 10:20:40 $';
    LogPath: 'JVCL'run'
  );
{$ENDIF UNITVERSIONING}

implementation


class function TTntJvItemsSearchs.DeleteExactString(Items: TTntStrings; const Value: WideString;
  All: Boolean; CaseSensitive: Boolean): Integer;
var
  I: Integer;
begin
  Result := 0;
  Items.BeginUpdate;
  try
    I := SearchExactString(Items, Value, CaseSensitive);
    while I <> -1 do
    begin
      Inc(Result);
      Items.Delete(I);
      if All then
        I := SearchExactString(Items, Value, CaseSensitive)
      else
        Exit;
    end;
  finally
    Items.EndUpdate;
  end;
end;

class function TTntJvItemsSearchs.SearchExactString(Items: TTntStrings; const Value: WideString;
  CaseSensitive: Boolean; StartIndex: Integer): Integer;
var
  I: Integer;
  HasLooped: Boolean;
begin
  Result := -1;
  I := StartIndex + 1;
  HasLooped := False;
  if CaseSensitive then
  begin
    while not HasLooped or (I <= StartIndex) do
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end
      else
      if WideCompareStr(Value, Items[I]) = 0 then
      begin
        Result := I;
        Exit;
      end
      else
        Inc(I);
  end
  else
  begin
    while not HasLooped or (I <= StartIndex) do
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end
      else
      if WideSameText(Value, Items[I]) then
      begin
        Result := I;
        Exit;
      end
      else
        Inc(I);
  end;
end;

class function TTntJvItemsSearchs.SearchPrefix(Items: TTntStrings; Value: WideString;
  CaseSensitive: Boolean; StartIndex: Integer): Integer;
var
  I: Integer;
  HasLooped: Boolean;
begin
  Result := -1;
  I := StartIndex + 1;
  HasLooped := False;
  if CaseSensitive then
  begin
    while not HasLooped or (I <= StartIndex) do
    begin
      if Pos(Value, Items[I]) = 1 then
      begin
        Result := I;
        Exit;
      end;
      Inc(I);
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end;
    end;
  end
  else
  begin
    Value := WideUpperCase(Value);
    while not HasLooped or (I <= StartIndex) do
    begin
      if Pos(Value, WideUpperCase(Items[I])) = 1 then
      begin
        Result := I;
        Exit;
      end;
      Inc(I);
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end;
    end;
  end;
end;

class function TTntJvItemsSearchs.SearchSubString(Items: TTntStrings; Value: WideString;
  CaseSensitive: Boolean; StartIndex: Integer): Integer;
var
  I: Integer;
  HasLooped: Boolean;
begin
  Result := -1;
  I := StartIndex + 1;
  HasLooped := False;
  if CaseSensitive then
  begin
    while not HasLooped or (I <= StartIndex) do
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end
      else
      if Pos(Value, Items[I]) <> 0 then
      begin
        Result := I;
        Exit;
      end
      else
        Inc(I);
  end
  else
  begin
    Value := WideUpperCase(Value);
    while not HasLooped or (I <= StartIndex) do
      if I >= Items.Count then
      begin
        I := 0;
        HasLooped := True;
      end
      else
      if Pos(Value, WideUpperCase(Items[I])) <> 0 then
      begin
        Result := I;
        Exit;
      end
      else
        Inc(I);
  end;
end;

{$IFDEF UNITVERSIONING}
initialization
  RegisterUnitVersion(HInstance, UnitVersioning);

finalization
  UnregisterUnitVersion(HInstance);
{$ENDIF UNITVERSIONING}

end.