tntdialogsex.pas

TntExUpdate 是 流行的 TntUnicodeControls控件的扩展包.包括很难找到的 TntJVCL 也在里面. TntSysUtils2.pas/TntSysUtilsEx.pa

{*****************************************************************************}
{                                                                             }
{    Tnt Delphi Unicode Controls                                              }
{      http://tnt.ccci.org/delphi_unicode_controls/                           }
{        Version: 2.1.11                                                      }
{                                                                             }
{    Copyright (c) 2002-2004, Troy Wolbrink ([e-mail])          }
{                                                                             }
{  This is an extension for WideString Button Text                            }
{  This allows you to set the buttons text in Open and Save Dialog            }
{  Rainer Geigenberger                                                        }
{*****************************************************************************}

unit TntDialogsEx;

{$INCLUDE TntCompilers.inc}

interface

uses
  Classes, CommDlg,Windows, Tntdialogs,dlgs;

type
  TTntOpenDialogEx = class(TTntOpenDialog)
  private
    FOKText: WideString;
    FCancelText: WideString;
    FDriveText: WideString;
    FFileNameText: WideString;
    FFileTypeText: WideString;
    FReadOnlyText: WideString;
    FHelpText: WideString;
  protected
    procedure DoShow; override;
  public
    constructor Create(AOwner: TComponent); override;
    procedure SetControlText (Setid: Integer; s: WideString);
  published
    property OKText: WideString read FOKText write FOKText;
    property CancelText: WideString read FCancelText write FCancelText;
    property DriveText: WideString read FDriveText write FDriveText;
    property FileNameText: WideString read FFileNameText write FFileNameText;
    property FileTypeText: WideString read FFileTypeText write FFileTypeText;
    property ReadOnlyText: WideString read FReadOnlyText write FReadOnlyText;
    property HelpText: WideString read FHelpText write FHelpText;
  end;

  TTntSaveDialogEx = class(TTntOpenDialogEx)
  public
   constructor Create (AOwner: TComponent); override;
  end;


implementation

uses
  {$IFDEF COMPILER_6_UP} Types, {$ENDIF} TntSysUtils;

procedure TTntOpenDialogEx.SetControlText(Setid: Integer; s: WideString);
begin
  if not Win32PlatformIsUnicode then
   begin
    SendMessage(GetParent(Handle),CDM_SETCONTROLTEXT,Setid,Longint(PChar(AnsiString(s))));
   end
  else
    SendMessageW(GetParent(Handle),CDM_SETCONTROLTEXT,Setid,Longint(PWideChar(s)));
end;

procedure TTntOpenDialogEx.DoShow;
begin
  inherited;
  SetControlText(IDOK,FOKText);
  SetControlText(IDCANCEL,FCancelText);
  SetControlText(chx1,FReadOnlyText);
  SetControlText(stc2,FFileTypeText);
  SetControlText(stc3,FFileNameText);
  SetControlText(stc4,FDriveText);
  SetControlText(pshHelp,FHelpText);
end;

constructor TTntSaveDialogEx.Create (AOwner: TComponent);
begin
  inherited;
  FOKText := '&Save';
end;

constructor TTntOpenDialogEx.Create(AOwner: TComponent);
begin
  inherited;
  FOKText := '&Open';
  FCancelText := 'Cancel';
  FDriveText := 'Look &in';
  FFileNameText := 'File&name';
  FFileTypeText := 'File&type';
  FReadOnlyText := 'Open as &read-only';
  FHelpText := '&Help';
end;

end.