main.bak

foxpro连接sqlserver的例子

para xxx
if type("xxx") # "L"
	if  messagebox("这个是华嘉系统，你想拿这个程序做什么？"+chr(13)+chr(13)+"如果继续执行可能会产生程序的意外错误！",1+48+256,"红虎在问你呢 ：）") = 2
		quit
	endif
endif

#include ../inc/system.h
*-- 设置当前的路径
public gcDefaultPath,gcExecuteFileName,gcVersion
gcExecuteFileName = sys(16)
lcProgram_path	= substr(gcExecuteFileName,1,rat("\",gcExecuteFileName,1)-1)
gcDefaultPath = lcProgram_path
set default to  "&lcProgram_path"

*-- 将程序的信息取出放置到一个数组中
AGETFILEVERSION(laProgramInfo,gcExecuteFileName)
gcVersion	= laProgramInfo(4)	&& 版本

public oLogo
do form logo name oLogo

_screen.visible = .F.
_screen.autocenter = .T.

with oLogo

	lcCaption = vfpSoftname + " (版本: " + gcVersion + ") - " + vfpCompanyName 

	Declare integer FindWindow in win32api string cClass,String lcCaption
	if FindWindow(0,lcCaption)#0
		set curs off
		.msg.caption = "该已经运行，初始化失败！"
		.msg.forecolor=rgb(255,0,0)
		??chr(7)
		wait wind "" timeout 1

		lnType = 3	&& 最大化
		declare integer FindWindow in win32api integer,string
		declare integer ShowWindow in win32api integer,integer
		FoxHWND=FindWindow(0,"&lcCaption")  &&里面那个为数字0
		FoxGone=ShowWindow(FoxHWND,lnType)
		quit
	endif
	_screen.caption = lcCaption

	.msg.caption = "正在初始化系统文件 ..."
	do init_file

	.msg.caption = "正在初始化系统环境 ..."
	do init_var
	set talk off
	set sysmenu to
	gcRightsList	= ""

	.msg.caption = "正在初始化系统菜单 ..."
	do sys_menu

	*-- 显示功能工具条
	ShowFuncToolsBar()

	*-- 显示编辑工具条
	*!*	ShowEditToolsBar()

	*-- 显示状态条时钟
	glShowStatus = !glShowStatus
	ShowStatusBar()

	*-- 判断版本号
	.msg.caption = "正在检验系统版本号 ..."
	IF ConnectData()
		IF !GetCompanyInfo()
			CloseConnect()
			MESSAGEBOX("无法获取正确的版本号，系统终止！",16,stop_loc)
			ON SHUTDOWN quit
			QUIT
		ENDIF
		
		IF RunSQL("Select * From SystemData where item='Version'")
			IF RECCOUNT() = 0
				RunSQL("usp_UpdateSystemData 'Version','&gcVersion'")
			ELSE
				IF value > gcVersion
					CloseConnect()
					MESSAGEBOX("当前运行的程序版本号为 &gcVersion." + CHR(13) + CHR(13) + ;
							"最新版本信息为 " + ALLTRIM(value) + CHR(13) + CHR(13) + ;
							"你必须更新系统后才能正常使用！",48,stop_loc)
					IF !EMPTY(gcDownloadURL)
						OpenURL(gcDownloadURL)
					ENDIF
					ON SHUTDOWN quit 		
					QUIT
				ELSE
					.msg.caption	= "正在获取系统设置参数 ..."
					RunSQL("usp_UpdateSystemData 'Version','&gcVersion'")
				ENDIF
			ENDIF 
		ENDIF 
		CloseConnect()
	ELSE
		MESSAGEBOX("无法连接系统指定的服务器，请联系管理员协助解决！",48,stop_loc)
		ON SHUTDOWN quit
		QUIT 
	ENDIF

Endwith

_screen.autocenter	= .t.
_screen.windowstate	= 2
_screen.picture		= gcBackGround
_screen.visible		= .t.

oLogo.msg.caption = "初始化完毕，进入系统 ..."
oLogo.timer1.enabled = .t.

release oLogo
oMsgSend = Createobject("msg_form")

_screen.show

sele 0
set message to "【"+vfpSoftName+"】【&gcUser.】"
read events