formattime.asp

OFFICE办公自动化

<%
'==================================================
' 格式化显示时间
'==================================================
function FormatTime(s_Time, n_Flag)
		If IsDate(s_Time) = False Then Exit function
		Dim y, m, d, h, mi, s, w
		FormatTime = ""
		y = CStr(Year(s_Time))
		m = CStr(Month(s_Time))
		If Len(m) = 1 Then m = "0" & m
		d = CStr(Day(s_Time))
		If Len(d) = 1 Then d = "0" & d
		h = CStr(Hour(s_Time))
		If Len(h) = 1 Then h = "0" & h
		mi = CStr(Minute(s_Time))
		If Len(mi) = 1 Then mi = "0" & mi
		s = CStr(Second(s_Time))
		If Len(s) = 1 Then s = "0" & s
		
		w = Weekday(s_Time)
		Select Case w
			Case 1 w = "星期日"
			Case 2 w = "星期一"
			Case 3 w = "星期二"
			Case 4 w = "星期三"
			Case 5 w = "星期四"
			Case 6 w = "星期五"
			Case 7 w = "星期六"
		End Select
		
		Select Case n_Flag
			Case 1 ' yyyy-mm-dd hh:mm:ss
				FormatTime = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
			Case 2 ' yyyy-mm-dd
				FormatTime = y & "-" & m & "-" & d
			Case 3 ' hh:mm:ss
				FormatTime = h & ":" & mi & ":" & s
			Case 4 ' yyyy年mm月dd日
				FormatTime = y & "年" & m & "月" & d & "日"
			Case 5 ' yyyymmddhhmmss
				FormatTime = y & m & d & h & mi & s
			Case 6 ' yyyy年mm月dd日 hh时mm分ss秒
				FormatTime = y & "年" & m & "月" & d & "日" & " " & h & "时" & mi & "分" & s & "秒"
			Case 7 ' mm-dd
				FormatTime = m & "-" & d
			Case 8 ' yyyy年mm月dd日 星期w
				FormatTime = y & "年" & m & "月" & d & "日" & " " & w
		End Select
	End function
%>