ronger.asp

OFFICE办公自动化

<%
'==============================================================
'版本: 1.2.0 -- 2004-10-13
'程序版权：(c) 2004 by 展亮
'说明：本代码为自由代码，用户可以自由使用，但请保留作者文件头部说明
'　　　在使用过程中如出现什么问题请及时与作者联系。
'　　　电子邮件：[e-mail] QQ:2343397
'=============================================================
'-------------------------------------------------------------
	'*******************************'
	'				'
	'新增记录[表名,调试]		'
	'				'
	'*******************************'
	function insert(ByVal target,ByVal printsql)
		on error resume next
		insert=-1
		dim thing,value,item,itemvalue
		item=""
		itemvalue=""
		if target="" then
			insert = "<p>无效的操作对象表名."
		else
			sql="insert " & target
			for each thing in Request.Form
				if instr(thing,"_")<=0 then
					value=request.Form(thing)
					if value<>"" then
						value=trim(replace(value,"'","''"))
						item=item & thing & ","
						if value="" then
							itemvalue=itemvalue & "NULL,"
						else
							itemvalue=itemvalue & "'" & value & "',"
						end if
					end if
				end if
			next

			if right(item,1)="," then item=left(item,len(item)-1)
			if right(itemvalue,1)="," then itemvalue=left(itemvalue,len(itemvalue)-1)
			sql= sql & "(" & item & ") values (" & itemvalue & ")"
			if printsql then
				insert = sql
			else
				oConn.Execute sql
				insert = true
			end if
			if err.number<>0 then
				response.write "程序执行过程中发生错误，错误信息如下:<p>" & err.description
				insert = false
			end if
			err.clear
		end if
	end function
'------------------------------------------------------------------
	'*******************************'
	'				'
	'修改记录[表名,调试]		'
	'				'
	'*******************************'
	function update(ByVal target, ByVal keyname, ByVal keyvalue, ByVal printsql)
		on error resume next
		update=-1
		dim thing,value
		if keyvalue="" then
			update = "<p>无效的操纵目标记录"
		elseif target="" then
			update = "<p>无效的操作对象表名."
		else
			sql="update " & target & " set "
			for each thing in Request.Form
				if instr(thing,"_")<=0 then
					value=request.Form(thing)
					value=trim(replace(value,"'","''"))
					if value="" then
						sql=sql & thing  & "=" & "NULL,"
					else
						sql=sql & thing  & "=" & "'" & value & "',"
					end if
				end if
			next
			if right(sql,1)="," then sql=left(sql,len(sql)-1)
			sql=sql & " where " & keyname & "='" & replace(keyvalue,"'","''") & "'"
			if printsql then
				update = sql
			else
				oConn.Execute sql
				update = true
			end if
			if err.number<>0 then
				response.write "程序执行过程中发生错误，错误信息如下:<p>" & err.description
				update = false
			end if
			err.clear
		end if
	end function
'------------------------------------------------------------------
	'*******************************'
	'				'
	'删除记录[表名,调试]		'
	'				'
	'*******************************'
	function delete(ByVal target, ByVal keyname, ByVal keyvalue, ByVal printsql)
		on error resume next
		if keyvalue="" then
			delete = "<p>无效的操纵目标记录"
		elseif target="" then
			delete = "<p>无效的操作对象表名."
		else
			sql="delete " & target & " where " & keyname & "='" & replace(keyvalue,"'","''") & "'"
			if printsql then
				delete = sql
			else
				oConn.Execute sql
				delete = true
			end if
			if err.number<>0 then
				Response.Write "程序执行过程中发生错误，错误信息如下:<p>" & err.description
			else
				delete = false
			end if
			err.clear
		end if
	end function
%>