📄 f_point_index.asp
字号:
<%
'功能：公文工作流程设置-工作点列表
'作者：展亮
'时间：2003-12-13 17:10
%>
<!--#include file="../inc/NoCatch.asp"-->
<!--#include file="../inc/Secure.asp"-->
<!--#include file="../inc/Conn.asp"-->
<!--#include file="../inc/Const.asp"-->
<%
'------------------------------------------------设置参数
sRecordID=Request("RecordID")
'------------------------------------------------
if sRecordID="" then
call MsgOut("没有指定公文号","javascript:history.back()",1)
oConn.close
set oConn=nothing
Response.End
end if
'------------------------------------------------取记录
set rs=server.CreateObject("ADODB.recordset")
rs.open "Select Subject,Template from tbioaOffice_Document where RecordID='" & sRecordID & "'" ,oConn,1,1
if rs.eof then
call MsgOut("指定的公文不存在","javascript:history.back()",1)
rs.close
set rs=nothing
oConn.close
set oConn=nothing
Response.End
end if
'------------------------------------------------赋值
slcmc=rs("Subject")
LCBH=GetTableValue("tbioaOffice_Template","LCBH","RecordID",rs("Template"))
if LCBH="" then LCBH=0
LCBH=0
'------------------------------------------------
FlowNum=GetTableNum("tbioaOffice_Flow","where RecordID='" & sRecordID & "'")
'------------------------------------------------读入默认流程
if LCBH<>0 and FlowNum=0 then
slcbh=LCBH
'套用模板
oConn.begintrans
oConn.execute "delete from tbioaOffice_FlowPoint where RecordID='" & sRecordID & "'"
oConn.execute "delete from tbioaOffice_Flow where RecordID='" & sRecordID & "'"
oConn.execute "insert into tbioaOffice_FlowPoint(RecordID,blgzbh,gzdxh,gzdmc,blrylb,blrysm,tqqx,jqqx,cxqx,lzbz,txzb,gzsx) " _
& "select '" & sRecordID & "' as RecordID,blgzbh,gzdxh,gzdmc,blrylb,blrysm,tqqx,jqqx,cxqx,lzbz,txzb,gzsx from tbioaOffice_FlowPoint_Template where lcbh='" & slcbh & "'"
oConn.execute "insert into tbioaOffice_Flow(RecordID,gzlbh,sgzbh,sgzdxh,zgzbh,zgzdxh,txzb) " _
& "select '" & sRecordID & "' as RecordID,gzlbh,sgzbh,sgzdxh,zgzbh,zgzdxh,txzb from tbioaOffice_Flow_Template where lcbh='" & slcbh & "'"
oConn.committrans
end if
'------------------------------------------------
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="../css/main.css">
<title>工作流程之工作点定义</title>
<script language=vbscript>
sub doMB
if selmb.value="" then
msgbox "请先选择要套用的模板",vbExclamation,"提示"
exit sub
end if
if msgbox("是否确定要套用指定的模板?原有的工作点定义信息将被删除",vbquestion+vbyesno,"删除确认")=vbno then exit sub
frmcz.lcbh.value=selmb.value
frmcz.action="F_Point_Applytemp.asp"
frmcz.submit
end sub
sub doedit(sgzdxh,sprev,sprevtype,snexttype)
frmcz.gzdxh.value=sgzdxh
frmcz.prev.value=sprev
frmcz.prevtype.value=sprevtype
frmcz.nexttype.value=snexttype
frmcz.action="F_Point_Edit.asp"
frmcz.submit
end sub
sub doSC(sgzdxh)
if msgbox("是否确定要删除选定的工作点?相关的信息会一并被删除",vbquestion+vbyesno,"删除确认")=vbno then exit sub
frmcz.gzdxh.value=sgzdxh
frmcz.action="F_Point_Del.asp"
frmcz.submit
end sub
</script>
<script language="javascript">
var strblr="";
function checkblr(){
if (strblr!=""){
alert(strblr+"\n请指定办理人员后再提交。\n提示：点击流程名称即可修改该流程的办理人员。")
return false
}else{return true}
}
</script>
</head>
<body topmargin="10" leftmargin="10">
<table width=98% border=0 align=center>
<tr valign=center><td align=left><img src="../images/icon_title.gif" align="absmiddle"> 设置工作点－<%=server.HTMLEncode(slcmc)%></td>
<td align=right valign=bottom>
<select id=selmb name=selmb <%if LCBH<>0 then response.write "disabled"%>>
<OPTGROUP LABEL='公司通用模板' style='color: #888888;'></OPTGROUP>
<%
set rs1=server.CreateObject("ADODB.recordset")
rs1.Open "select * from tbioaOffice_Flow_TemplateName where bmbh=0 order by LCMC desc",oConn,1,1
do while not rs1.EOF
%>
<option value=<%=rs1("LCBH")%>><%=server.HTMLEncode(rs1("LCMC"))%></option>
<%
rs1.MoveNext
loop
rs1.Close
%>
<OPTGROUP LABEL='部门流程模板' style='color: #888888;'></OPTGROUP>
<%
rs1.Open "select * from tbioaOffice_Flow_TemplateName where bmbh="&Session("DepID")&" order by LCMC desc",oConn,1,1
do while not rs1.EOF
%>
<option value=<%=rs1("LCBH")%>><%=server.HTMLEncode(rs1("LCMC"))%></option>
<%
rs1.MoveNext
loop
rs1.Close
%>
</select>
<input type=button class="button0" value="套用模板" id=bMB name=bMB onclick='vbscript:doMB' <%if LCBH<>0 then response.write "disabled"%>>
<input type=button class="button0" value="关闭" id=bQuery name=del_button onclick="javascript:window.close()">
</td></tr>
</table>
<hr width="100%" size=1 color="#000000">
<br>
<table width=98% border=0 align=center>
<tr valign=center><td align=center>
<b>工作点情况
</td>
</tr>
</table>
<form id=frmcz method=post>
<input type=hidden id=RecordID name=RecordID value=<%=sRecordID%>>
<input type=hidden id=gzdxh name=gzdxh>
<input type=hidden id=prev name=prev>
<input type=hidden id=prevtype name=prevtype>
<input type=hidden id=nexttype name=nexttype>
<input type=hidden id=lcbh name=lcbh>
</form>
<%
set rs=server.CreateObject("ADODB.recordset")
'取得入度为0的工作点（只可能有一个）
sql = "select a.*,b.blgzmc from tbioaOffice_FlowPoint a,tbioaOffice_Flow_Bldy b " _
& "where a.RecordID='" & sRecordID & "' " _
& "and a.gzdxh not in(" _
& "select zgzdxh as gzdxh from tbioaOffice_Flow " _
& "where RecordID='" & sRecordID & "') " _
& "and a.blgzbh=b.blgzbh "
'response.write sql
rs.Open sql,oConn,1,1
lfirst=-1
bend=true
if not rs.EOF then
lfirst=rs("gzdxh") & ""
bend=false
end if
if not bend then '不是一个都没有
%>
<table align=center cellspacing=0 cellpadding=0 border=0 width="400">
<tr>
<td>
<table width=100% border=0 cellspacing=1 cellpadding=2 class=tab>
<tr><td nowrap align=center class=tdtop>公文办理开始</td></tr>
</table>
</td>
</tr>
<tr>
<td>
<table width=100% border=0 cellspacing=0 cellpadding=2>
<tr>
<td align=right width=50%><b>↓</b></td>
<td align=left width=50% nowrap></td>
</tr>
</table>
</td>
</tr>
<%
do while not rs.EOF
'如果该点的后继节点可以接在该点的前驱节点上则显示删除链接
dim ssPrev,ssNext,ssPrevType,ssNextType
ssPrev=0
ssPrevType=""
ssNext=0
ssNextType=""
sql="select sgzbh,sgzdxh from tbioaOffice_Flow Where RecordID='" & sRecordID & "' And zgzdxh=" & rs("gzdxh")
rs1.Open sql,oConn,1,1
if not rs1.EOF then
ssPrev=rs1("sgzdxh")
ssPrevType=rs1("sgzbh")
end if
rs1.Close
sql="select zgzbh,zgzdxh from tbioaOffice_Flow Where RecordID='" & sRecordID & "' And sgzdxh=" & rs("gzdxh")
rs1.Open sql,oConn,1,1
if not rs1.EOF then
ssNext=rs1("zgzdxh")
ssNextType=rs1("zgzbh")
end if
rs1.Close
dim bShowDel
bShowDel=false
'Response.Write ssprev & "/" & ssprevtype & "/" & ssnext & "/" & ssnexttype
if ssNext=0 then
bshowDel=true
else
'判断
if ssPrevType<>"" then
rs1.Open "Select blgzbh from tbioaOffice_Flow_Bldy " _
& "where blgzbh='" & ssNextType & "' " _
& "and ','+qtgzbh+',' like '%," & ssPrevtype & ",%'" _
,oConn,1,1
if not rs1.eof then
bShowDel=true
end if
rs1.close
else
'看ssNextType能不能在最前面
rs1.Open "Select blgzbh from tbioaOffice_Flow_Bldy " _
& "where blgzbh='" & ssNextType & "' " _
& "and (qtgzbh='' or qtgzbh is null or qtgzbh='" & ssNextType & "') " _
,oConn,1,1
if not rs1.eof then
bShowDel=true
end if
rs1.close
end if
end if
'显示信息
%>
<tr>
<td>
<table width=100% border=0 cellspacing=1 cellpadding=2 class=tab>
<tr>
<td nowrap width=120 class=tdtop><%=server.HTMLEncode(rs("blgzmc"))%></td>
<td nowrap width=235 class=tdtop2>
<%if LCBH=0 then%>
<a href='javascript:doedit("<%=rs("gzdxh")%>","<%=ssPrev%>","<%=ssPrevType%>","<%=ssNextType%>")' class=LinkTop><%=server.HTMLEncode(rs("gzdmc"))%></a>
<%else%>
<%=server.HTMLEncode(rs("gzdmc"))%>
<%end if%>
</td>
<td width=45 nowrap class=tdtop>
<%if bShowDel then%>
<%if LCBH=0 then%><a href='javascript:doSC(<%=rs("gzdxh")%>)'><img src="../images/icon_dele1.gif" border=0 alt="删除"></a><%end if%>
<%end if%>
</td>
</tr>
<tr>
<form name="frmblr<%=rs("gzdxh")%>" method=post>
<td colspan=3 class=td2><a style="cursor:default" title=<%=Server.HTMLEncode(GetUserNames(rs("blrylb") & "",","))%>>办理人员:
<script language="javascript">
<%if rs("blrylb")="" then%>strblr+="流程(<%=server.HTMLEncode(rs("gzdmc"))%>)未指定办理人员\n";<%end if%>
</script>
<%if rs("blrysm")="" then response.write GetUserNames(rs("blrylb"),",")%>
<%=server.HTMLEncode(rs("blrysm"))%>
</td>
</form>
</tr>
<tr>
<td colspan=1 class=tdbottom>
<%if rs("lzbz") & ""="1" then Response.Write "全部完成继续" else Response.Write "一人完成继续"%>
</td>
<td colspan=2 class=tdbottom>
<%if rs("tqqx") & ""="1" then Response.Write "<font color='green'>√退签</font>" else Response.Write "<font color='red'>×退签</font>"%>
<%if rs("jqqx") & ""="1" then Response.Write "<font color='green'>√加签</font>" else Response.Write "<font color='red'>×加签</font>"%>
<%if rs("cxqx") & ""="1" then Response.Write "<font color='green'>√撤销</font>" else Response.Write "<font color='red'>×撤销</font>"%>
</td>
</tr>
</table>
<table width=100% border=0 cellspacing=0 cellpadding=2>
<tr>
<td align=right width=50%><b>↓</b></td>
<td align=left width=50% nowrap><%if LCBH=0 then%>←<a href='javascript:doedit("","<%=rs("gzdxh")%>","<%=rs("blgzbh") & ""%>","<%=ssNextType%>")'>插入工作点</a><%end if%><td>
</tr>
</table>
</td>
</tr>
<%
'取得下一点的信息
lfirst=rs("gzdxh")
rs.Close
rs.Open "select a.*,c.blgzmc from tbioaOffice_FlowPoint a,tbioaOffice_Flow b,tbioaOffice_Flow_Bldy c " _
& "where a.RecordID='" & sRecordID & "' " _
& "and a.RecordID=b.RecordID " _
& "and b.sgzdxh=" & lfirst & " " _
& "and b.zgzdxh=a.gzdxh " _
& "and a.blgzbh=c.blgzbh " _
,oConn,1,1
loop
%>
<tr>
<td>
<table width=100% border=0 cellspacing=1 cellpadding=2 class=tab>
<tr><td nowrap align=center class=tdtop>公文待归档</td></tr>
</table>
</td>
</tr>
</table>
<br><center>
<form action="IntoFlow.asp" method="post" onsubmit="javascript:return checkblr() && confirm('是否将要开始当前公文的流转？进入流转后您将不能继续在公文拟制页面中修改该公文！')">
<input type=hidden name=RecordID value=<%=sRecordID%>>
<input type="submit" name="go" value="进入流转>>" class="button0">
</form>
<%else%>
<table align=center cellspacing=0 cellpadding=0 border=0 width="400">
<tr>
<td>
<table width=100% border=0 cellspacing=1 cellpadding=2 class=tab>
<tr><td nowrap align=center class=tdtop>公文办理开始</td></tr>
</table>
</td>
</tr>
<tr>
<td>
<table width=100% border=0 cellspacing=0 cellpadding=2 style="border-collapse:collapse">
<tr style="background-color:#ffffff;">
<td align=right width=50%><b>↓</b></td>
<td align=left width=50% nowrap>←<a href='javascript:doedit("",0,"","")'>插入工作点</a><td>
</tr>
</table>
</td>
</tr>
<tr>
<td>
<table width=100% border=0 cellspacing=1 cellpadding=2 class=tab>
<tr><td nowrap align=center class=tdtop>公文待归档</td></tr>
</table>
</td>
</tr>
</table>
<%
end if
rs.Close
set rs=nothing
set rs1=nothing
%>
</body>
</html>
<%'释放对象变量
oConn.close
%> ⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -