document_file_sc_save.asp

OFFICE办公自动化

<%
'功能：公文收藏
%>

<!--#include file="../inc/Secure.asp"-->
<!--#include file="../inc/conn.asp"-->
<!--#include file="../inc/Const.asp"-->

<%
  mRecordID=request.form("RecordID")	'文档编号
  mFile_Man=request.form("File_Man")	'收藏人ID
  mFile_Date=request.form("File_Date")  '收藏日期
  mFLH=request.form("FLH")		'公文分类号
  mCXQX=request.form("input_CXQX")	'公文查询权限
  Response.Buffer=true
  mSql="Select * From tbioaOffice_Document Where RecordID='"+ mRecordID + "'"
  Set TbMainRs=Server.CreateObject("ADODB.RecordSet")
  TbMainRs.Open mSql,oConn,1,3

  If TbMainRs.Eof then '如果无文档记录则退出
  	response.write msql
  	response.write "该公文不存在!"
  	response.end
  else  '如果有记录则取记录参数
	'------------------------------------------------
	mRecordID = TbMainRs("RecordID")  '公文编号
	mFileType = TbMainRs("FileType")  '文件类型
	'---------------------------------
	mDocFileNo	   = TbMainRs("DocFileNo")	  '公文文号
	mDocType 	   = TbMainRs("DocType")	  '内外部公文
	mDocMod		   = TbMainRs("DocMod")           '收发文
	mDC_Doc_Sort	   = TbMainRs("DC_Doc_Sort")	  '公文种类
	mDC_Doc_Security   = TbMainRs("DC_Doc_Security")  '公文密级
	mSubject	   = TbMainRs("Subject")	  '公文标题
	mAuthor		   = TbMainRs("Author")		  '作者
	mFileDate 	   = TbMainRs("FileDate")  	  '入库日期
	'------------------------------------------------
	'如果已经收藏则返回
	TmpSQL="select File_Man from tbioaDocument_File_Dep where RecordID='"&mRecordID&"' and DEPID="&Session("DepID")
	set TmpRS=Server.CreateObject("ADODB.RecordSet")
	TmpRS.open TmpSQL,oconn,1,1
	if not TmpRS.eof then
		response.write "<script>alert('该公文已被("&getusername(TmpRS("File_Man"))&")收藏在部门收藏夹中，你不能重复收藏!');history.back()</script>"
	  	TmpRS.close
	  	response.end
	end if
	TmpRS.close
	'------------------------------------------------
	mSql="Select * From tbioaDocument_File_Dep Where RecordID='"& mRecordID & "'"
	Set Rs=Server.CreateObject("ADODB.RecordSet")
	Rs.Open mSql,oConn,3,3
	Rs.Addnew
		'--------------------------------------------
		if mRecordID <> "" then Rs("RecordID")=mRecordID			    '公文编号
		Rs("DEPID")=Session("DepID")						    '收藏部门
		if mFLH<>"" then Rs("FLH")=mFLH						    '收藏分类
		if mFile_Man<>"" then Rs("File_Man")=mFile_Man				    '收藏人ID
		if mFile_Date<>"" then Rs("File_Date")=mFile_Date			    '收藏时间
		if mDocFileNo <> "" then Rs("DocFileNo") = mDocFileNo		 	    '公文文号
		if mDocType <> "" then Rs("DocType")=mDocType	     	 		    '内外部公文
		if mDocMod <> "" then Rs("DocMod")=mDocMod	     	 		    '收发文
		if mDC_Doc_Sort <> "" then  Rs("DC_Doc_Sort")=mDC_Doc_Sort	  	    '公文种类
		if mDC_Doc_Security <> "" then Rs("DC_Doc_Security")=mDC_Doc_Security	    '公文密级
		if mSubject <> "" then Rs("Subject")=mSubject				    '公文标题
		if mAuthor <> "" then Rs("Author")=mAuthor				    '拟稿人
		if mFileDate <> "" then Rs("FileDate")=mFileDate			    '拟稿日期
		if mCXQX <> "" then Rs("CXQX")=mCXQX					    '公文查询权限
	Rs.Update
	Rs.close
	Set Rs = Nothing
	response.write "<script language=javascript> alert('已成功收藏！'); history.go(-2); </SCRIPT>"
    end if
%>