📄 kq_qjsq_edit.asp

📁 OFFICE办公自动化
💻 ASP
字号:
<!--#include file="../inc/Secure.asp"-->
<!--#include file="../inc/conn.asp"-->
<!--#include file="../inc/Const.asp"-->
<%
	dim ssqxh
	ssqxh=Request.QueryString("sqxh")
	if ssqxh & ""="" then
		Response.Write "申请序号错误"
		Response.End
	end if 
%>
<!-- #include file="../inc/pubfun_a.inc" -->
<html>
<head>
	<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
	<link rel="stylesheet" href="../css/main.css" type=text/css>
	<title>请假申请</title>
	<script language=vbscript src="..\js\pubfun_a_c.vbs"></script>
	<script language=javascript src="../js/fun_Script.js"></script>
	<script language=vbscript>
	<!--
		sub doSave
			frmxx.yjkssj.value=trim(frmxx.yjkssj.value)
			frmxx.yjjssj.value=trim(frmxx.yjjssj.value)
			frmxx.sqsy.value=trim(frmxx.sqsy.value)
			if frmxx.jb.value="" then
				msgbox "必须选择假别",vbInformation	,"提示"
				exit sub
			end if
			if not isdate(frmxx.yjkssj.value) then
				msgbox "预计开始时间必须输入日期格式，如" & formatdatetime_activenew(now,"yyyy-mm-dd hh:nn"),vbInformation,"提示"
				frmxx.yjkssj.focus
				exit sub
			end if
			frmxx.yjkssj.value=formatdatetime_activenew(frmxx.yjkssj.value,"yyyy-mm-dd hh:nn")
			if not isdate(frmxx.yjjssj.value) then
				msgbox "预计结束时间必须输入日期格式，如" & formatdatetime_activenew(now,"yyyy-mm-dd hh:nn"),vbInformation,"提示"
				frmxx.yjjssj.focus
				exit sub
			end if
			frmxx.yjjssj.value=formatdatetime_activenew(frmxx.yjjssj.value,"yyyy-mm-dd hh:nn")
			if frmxx.yjjssj.value<frmxx.yjkssj.value then
				msgbox "预计开始时间必须早于预计结束时间",vbInformation,"提示"
				frmxx.yjkssj.focus
				exit sub
			end if
			frmxx.submit
		end sub
	//-->
	</script>
</head>
<body>
<div class="TitleBar">请假单信息</div>
<%
	Dim rs
	set rs=server.CreateObject("ADODB.recordset")
	dim sygbh
	sygbh=session("LoginID")
	dim skqyqsrq
	rs.Open "select * from kq_csb",oConn,1,1
	if rs.EOf then
	  rs.Close
	  set rs=nothing
	oConn.close
	set oConn=nothing
	Response.Write "未定义考勤参数"
	Response.End
	end if
	skqyqsrq=rs("kqyqsrq")
	rs.Close
	dim syjkssj,syjjssj,sjb,ssqr,ssqrxm,ssqzw,ssqzwmc,ssqsy
	rs.Open "select a.*,b.sqsy,b.sqr,b.sqzw from kq_qjd a,oa_sqjbxx b  where a.sqxh=b.sqxh  and a.sqxh=" & ssqxh,oConn,1,1
	if rs.EOf then
	  rs.Close
	  set rs=nothing
	oConn.close
	set oConn=nothing
	Response.Write "未找到对应请假单"
	Response.End
	end if
	syjkssj=rs("yjkssj") & ""
	syjjssj=rs("yjjssj") & ""
	sjb=rs("jb") & ""
	ssqr=rs("sqr") & ""
	ssqzw=rs("sqzw") & ""
	ssqsy=rs("sqsy") & ""
	rs.Close
	rs.Open "Select Name from tbioaUser where ID="  & ssqr,oConn,1,1
	if not rs.eof then
		ssqrxm=rs(0) & ""
	end if
	rs.Close
	rs.Open "Select A.zwmc as zwmc,B.bmmc as bmmc from oa_qx_zw A,rs_bmb B where zwbh="  & ssqzw & " and A.bmbh=B.bmbh",oConn,1,1
	if not rs.eof then
		ssqzwmc=rs("zwmc") & "[" & rs("bmmc") & "]"
	end if
	rs.Close
%>

<table align="center" width="480" class="InputframeMain"><tr><td><table border=0 align=center cellpadding=0 cellspacing=0 style="Margin:5px 5px 5px 5px">
	<form name="frmxx" id=frmxx method="post" action="kq_qjsq_edit_save.asp">
	<input type=hidden id=sqxh name=sqxh value="<%=ssqxh%>">
	<tr class=InputframeLine>
		<td width=80 class=InputLabelCell align=right>假别</td>
		<td class=InputAreaCell colspan=3>
			<select id=jb name=jb rows=1>
		<%
			rs.Open "Select * from KQ_JBZD",oConn,1,1
			do while not rs.EOf 
				%>
				<option <%if sjb=rs("dm") then Response.Write " selected "%> value="<%=rs("dm") & ""%>"><%=server.HTMLEncode(rs("mc") & "")%></option>
				<%
				rs.Movenext  
			loop
			rs.Close
		%>
			</select>
		</td>
	</tr>
	<tr class=InputframeLine>
		<td width=80 class=InputLabelCell align=right>申请人</td>
		<td class=InputAreaCell><%=server.HTMLEncode(ssqrxm)%></td>
		<td width=80 class=InputLabelCell align=right>职位[部门]</td>
		<td class=InputAreaCell><%=server.HTMLEncode(ssqzwmc)%></td>
	</tr>
	<tr class=InputframeLine>
		<td width=80 class=InputLabelCell align=right>预计开始时间</td>
		<td class=InputAreaCell><input type=text class=input id=yjkssj name=yjkssj size=20 maxlength=20 value='<%=syjkssj%>'></td>
		<td width=80 class=InputLabelCell align=right>预计结束时间</td>
		<td class=InputAreaCell><input type=text class=input id=yjjssj name=yjjssj size=20 maxlength=20 value='<%=syjjssj%>'></td>
	</tr>
	<tr class=InputframeLine>
		<td width=80 class=InputLabelCell align=right>事由</td>
		<td class=InputAreaCell colspan=3><textarea class=inputarea rows=3 cols=50 id=sqsy name=sqsy><%=server.HTMLEncode(ssqsy)%></textarea></td>
	</tr>
	<tr class=InputframeButtonLine>
		<td align="center" colspan="4">
			<input type=button class=button id=bBC name=bBC onclick="vbscript:doSave" value="确定">
			<input type=button class=button id=bfH name=bfH onclick="javascript:history.back();" value="返回">
		</td>
	</tr>
	</form>
</table></td></tr></table>
<br>
<%
	set rs=nothing
	oConn.close
	set oConn=nothing
%>
</body>
</html>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -