📄 kq_xjhz.asp

📁 OFFICE办公自动化
💻 ASP
字号:
<!--#include file="../inc/Secure.asp"-->
<!--#include file="../inc/conn.asp"-->
<!--#include file="../inc/Const.asp"-->
<!-- #INCLUDE fILE = "../public/showpage.asp" -->
<!-- #include file="../inc/pubfun_a.inc" -->

<html>
<head>
	<title>考勤管理</title>
	<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
	<link rel="stylesheet" href="../css/main.css" type=text/css>
	<script language=javascript src="../js/fun_Script.js"></script>
</head>
<body>
<div class="TitleBar">销假核准</div>
<%
	dim ssj,slb
	ssj=Request("sj")
	slb=Request("lb")
	if ssj="" then ssj="X1"
	if slb="" then slb="X1"
%>
<table width=98% class=tabletoolbar border=0 cellspacing="1" cellpadding="0" align=center>
	<form name=frmCX id=frmCX method="post" action="kq_xjhz.asp">
	<tr>
		<td align="left"><div class="TableTitleText">请假单列表</div></td>
		<td align="right">
			按请假时间： <select name="sj" id=sj size="1">
			<option value="XX" selected>全部</option>
			<option value="X1"<% if ssj="X1" then Response.Write " selected" %>>本周</option>
			<option value="X2"<% if ssj="X2" then Response.Write " selected" %>>本月</option>
			</select> 
			按审批销假情况： <select name="lb" id =lb size="1" >
			<option value="XX" selected>全部</option>
			<option value="X1"<% If slb="X1" Then Response.Write " selected" %>>未核准</option>
			<option value="X2"<% If slb="X2" Then Response.Write " selected" %>>核准未同意</option>
			<option value="X3"<% If slb="X3" Then Response.Write " selected" %>>核准同意</option>
			</select>  
			<input type="button" class="button"  onclick="vbscript:frmcx.submit()" value="查询"  id=button1 name=button1></input>
		</td>
	</tr>
	</form>
</table>
<%
 'djr 的值为NULL或为空, 表示此类别的全部员工都不可登记
 'djr 的值为all,  表示此类别的全部员工都可登记
 'djr 的值为其他, 表示此类别的登记人为所选人员 
		
	dim rs,ssql,sygbh,rs1	
	sygbh=session("LoginID")
	set rs=server.CreateObject("adodb.recordset")
	set rs1=server.CreateObject("adodb.recordset")
	ssql="select a.*,b.spbz,c.mc,b.sqsy,b.sqr,b.sqbm from kq_qjd a,oa_sqjbxx b,KQ_JBZD c,oa_sqlb d " _
			& "where a.jb=c.dm and a.sqxh=b.sqxh and d.lbbh='08'" _
			& " and (cast(d.djr as varchar(8000)) = 'all' or ','+cast(d.djr as varchar(8000))+',' like '%,"&sygbh&",%')" 		
	dim bdate,edate
	select case ssj
		case "XX"
			ssql=ssql & " "
		case "X1"
			bdate=formatdatetime_activenew(dateadd("d",1-Weekday(now,vbMonday),now),"yyyy-mm-dd")
			edate=formatdatetime_activenew(dateadd("d",7-Weekday(now,vbMonday),now),"yyyy-mm-dd")
			ssql=ssql & "and substring(YJKSSJ,1,10)>='" & bdate & "' and substring(YJKSSJ,1,10)<='" & edate & "' "
		case "X2"
			bdate=formatdatetime_activenew(now,"yyyy-mm-01")
			edate=formatdatetime_activenew(dateadd("m",1,now),"yyyy-mm-01")
			ssql=ssql & "and substring(YJKSSJ,1,10)>='" & bdate & "' and substring(YJKSSJ,1,10)<'" & edate & "' "
	end select
	select case slb
		case "XX"
			ssql=ssql & " and a.xjqk<>'0' and b.spbz='1' "
		case "X1"
			ssql=ssql & " and a.xjqk='1' and b.spbz='1' "
		case "X2"
			ssql=ssql & " and a.xjqk='2'  and b.spbz='1' "
		case "X3"
			ssql=ssql & " and a.xjqk='3' and b.spbz='1' "
	end select
	
	ssql=ssql & " order by a.sqxh desc"
	'Response.Write ssql
	rs.Open ssql,oConn,1,1
	dim page
	rs.Pagesize=application("RecPerPage")
	page=Request("page")
	if isempty(page) then 
		  page=1
	end if
	if rs.recordcount>0 then
		rs.absolutepage=page
	end if
%>
<table class="tab" width="98%" align="center" border="0" cellpadding="2" cellspacing="1">
	<form name=frmSC id=frmSC method="post" action="kq_qjsq_del.asp">
	<tr align="center"> 
		<td class="tdTop" >假别</td>
		<td class="tdTop" >申请人</td>
		<td class="tdTop" >申请部门</td>
		<td class="tdTop" >预计起止时间</td>
		<td class="tdTop" >申请事由</td>
		<td class="tdTop" >实际起止时间</td>
		<td class="tdTop" >核准情况</td>
	</tr>
<% 
   dim i
   i=0 
   do while i<application("RecPerPage") and Not rs.EOf 
   %>
	<tr class=td1>
		<td class=listcellrow><nobr>
		&nbsp;&nbsp;&nbsp;<%=server.HTMLEncode(rs("mc") & "") %>&nbsp;<a href="javascript:gotourl('kq_qjsq_view.asp?sqxh=<%=rs("sqxh")%>','qjdview','600px','400px',1,0);" title="请点击查看详细信息">详细</a>
		</nobr></td>
		<td class=listcellrow><nobr><%
			rs1.Open "Select Name from tbioaUser where ID=" & rs("sqr"),oConn,1,1
			if not rs1.EOf then
				Response.Write server.HTMLEncode(rs1("Name") & "")
			end if
			rs1.close	
		%>&nbsp;</nobr></td>
		<td class=listcellrow><nobr><%
			rs1.Open "Select bmmc from rs_bmb where bmbh='" & rs("sqbm") & "'",oConn,1,1
			if not rs1.EOf then
				Response.Write server.HTMLEncode(rs1("bmmc") & "")
			end if
			rs1.close	
		%>&nbsp;</nobr></td>
		<td class=listcellrow align=center><nobr>
			&nbsp;从：<%=formatdatetime_activenew(rs("yjkssj"),"yyyy-mm-dd hh:nn")%>
			<br>&nbsp;到：<%=formatdatetime_activenew(rs("yjjssj"),"yyyy-mm-dd hh:nn")%></nobr></td>
		<td class=listcellrow><%=replace(server.HTMLEncode(rs("sqsy") & ""),vbcr,"<br>") %>&nbsp;</td>
		<td class=listcellrow align=center><nobr>
			&nbsp;<%if rs("sjkssj") & ""<>"" then Response.Write "从：" & formatdatetime_activenew(rs("sjkssj"),"yyyy-mm-dd hh:nn")%>
			<br>&nbsp;<%if rs("sjjssj") & ""<>"" then Response.Write "到：" & formatdatetime_activenew(rs("sjjssj"),"yyyy-mm-dd hh:nn")%></nobr></td>
		<td class=listcellrow><nobr>&nbsp;
		<a href="kq_xjhz_edit.asp?sqxh=<%=rs("sqxh")%>">
		<%
			select  case rs("xjqk")
				case "0"
					Response.Write "未销假"
				case "1"
					Response.Write "已销未核"
				case "2"
					Response.Write "未同意"
				case "3"
					Response.Write "同意"
			end select
		%></a>
		</nobr></td>
	</tr>
	<%
		rs.MoveNext
		i=i+1
	loop
%>
</form>
	<tr>
	<%if rs.RecordCount<>0 then%>
		<td colspan="7" class="td2" align=right><%call ShowPage_new(cint(rs.recordcount),cint(rs.pagesize),cint(page),cint(rs.pagecount),"kq_xjhz.asp?sj=" & ssj & "&lb=" & slb & "")%></td>
	<%else%>
		<td colspan="7" class="td2" align=center>没有符合条件的请假单</td>
	<%end if%>
	</tr>
</table>
</body>
</html>

<%
	rs.Close
	set rs=nothing
	set rs1=nothing
	oConn.close
	set oConn=nothing
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -