moddb.bas

sql的实例源码

Attribute VB_Name = "modDb"
Private IsConnect As Boolean      '标记数据库是否连接
Private cnn As ADODB.Connection   '连接数据库的Connection对象
Private rs As ADODB.Recordset     '保存结果集的Recordset对象

'连接数据库
Public Sub DBConnect()
  '如果连接标记为真，表明数据库已连接，则直接返回。
  If IsConnect = True Then
    Exit Sub
  End If
  
  '关键字New用于创建新对象cnn
  Set cnn = New ADODB.Connection
  '设置连接字符串的ConnectionString属性
  cnn.ConnectionString = CONSTR
  '打开到数据库的连接
  cnn.Open
  '判断连接的状态
  If cnn.State <> adStateOpen Then
    '如果连接不成功，则显示提示信息，退出程序
    MsgBox "数据库连接失败", vbOKOnly + vbCritical, "连接失败"
    End
  End If
  
  '设置连接标记，表示已经连接到数据库
  IsConnect = True
End Sub

'断开与数据库的连接
Public Sub DBDisconnect()
  '如果连接标记为假，表明已经断开连接，则直接返回
  If IsConnect = False Then
    Exit Sub
  End If
  '关闭连接
  cnn.Close
  '释放cnn
  Set cnn = Nothing
  '设置连接标记，表示已经断开与数据库的连接
  IsConnect = False
End Sub

'执行数据库操作语句
Public Sub SQLExt(ByVal SQLStmt As String)
  '创建Command对象cmd
  Dim cmd As New ADODB.Command
  '调用DBConnect过程，来连接到数据库
  DBConnect
  '设置cmd的ActiveConnection属性，指定与其关联的数据库连接
  Set cmd.ActiveConnection = cnn
  '设置要执行的命令文本
  cmd.CommandText = SQLStmt
  '执行命令
  cmd.Execute
  '清空cmd对象
  Set cmd = Nothing
  '调用DBDisconnect过程，来断开与数据库的连接
  DBDisconnect
End Sub

'执行数据库查询语句
Public Function SQLQuery(ByVal SQLStmt As String) As ADODB.Recordset
  '创建Recordset对象rst
  Dim rst As New ADODB.Recordset
  
  '调用DBConnect过程，来连接到数据库
  DBConnect
  '设置rst的ActiveConnection属性，指定与其关联的数据库连接
  Set rst.ActiveConnection = cnn
  '设置游标类型
  rst.CursorType = adOpenDynamic
  '设置锁定类型
  rst.LockType = adLockOptimistic
  '打开记录集
  rst.Open SQLStmt
  '返回记录集
  Set SQLQuery = rst
End Function