passwdinfo.cls

sql的实例源码

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "PasswdInfo"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'1 UserName varchar 20 用户名 Allow Null = False 主键
'2 Passwd varchar 50 密码 Allow Null = True
'3 UserType tinyint 用户类型 Allow Null = False 默认值：2（1－超级用户，2－普通用户）

Public UserName As String
Public Passwd As String
Public UserType As Byte

'初始化
Public Sub Init()
  UserName = ""
  Passwd = ""
  UserType = 2
End Sub

'判断是否存在此用户
Public Function IsExistUser(ByVal paraUser As String) As Boolean
  '定义rs变量
  Dim rs As New ADODB.Recordset
  
  '设置SQL语句
  SQLStmt = "SELECT * FROM PasswdInfo WHERE UserName = '" + Trim(StrReplace(paraUser)) + "'"
  Set rs = SQLQuery(SQLStmt)
  If rs.EOF Then
    IsExistUser = False
  Else
    IsExistUser = True
  End If
  
  '断开连接
  DBDisconnect
End Function

'根据用户名得到其他信息
Public Function GetInfo(ByVal paraUser As String) As Boolean
  '设置rs变量
  Dim rs As New ADODB.Recordset
  
  '设置SQL语句
  SQLStmt = "SELECT * FROM PasswdInfo WHERE UserName = '" + Trim(StrReplace(paraUser)) + "'"
  Set rs = SQLQuery(SQLStmt)
  If rs.EOF Then
    '若没有数据，则需要初始化
    Init
    '返回False
    GetInfo = False
  Else
    '===========写入RecordSet集中的数据===============
    '写入用户名
    UserName = Trim(paraUser)
    '得到密码
    If IsNull(rs.Fields(1)) Then
      Passwd = ""
    Else
      Passwd = Trim(rs.Fields(1))
    End If
    '得到用户类型
    UserType = rs.Fields(2)
    '=========写入RecordSet集中的数据成功=============
    
    '返回True
    GetInfo = True
  End If
  
  '断开连接
  DBDisconnect
End Function

'插入操作
Public Sub Insert()
  '设置INSERT语句
  SQLStmt = "INSERT INTO PasswdInfo VALUES('" + Trim(StrReplace(UserName)) _
          + "', '" + Trim(StrReplace(Passwd)) + "', " + Trim(Str(UserType)) _
          + ")"
  '执行INSERT语句
  SQLExt SQLStmt
End Sub

'更新数据
Public Sub Update(ByVal paraUser As String)
  SQLStmt = "UPDATE PasswdInfo SET Passwd = '" + Trim(StrReplace(Passwd)) _
          + "', UserType = " + Trim(Str(UserType)) _
          + " WHERE UserName = '" + Trim(StrReplace(paraUser)) + "'"
  '执行UPDATE语句
  SQLExt SQLStmt
End Sub

'删除操作
Public Sub Delete(ByVal paraUser As String)
  SQLStmt = "DELETE FROM PasswdInfo WHERE UserName = '" _
          + Trim(StrReplace(paraUser)) + "'"
  '执行DELETE语句
  SQLExt SQLStmt
End Sub