tagutils.as

flex 实现的一个showcase 喜欢flex的朋友可以

package com.flexShowcase.utils {
	
	
	//////////////////////////////////////////////////
	//import
	
	import com.flexShowcase.data.Tag;
	
	import mx.collections.ArrayCollection;
	import mx.collections.Sort;
	import mx.collections.SortField;
	
	
	//////////////////////////////////////////////////
	//class
	
	public class TagUtils {
		
		
		//////////////////////////////////////////////////
		//public static functions
		
		public static function getTagCloud(tags:ArrayCollection, showWeight:Boolean):String {
			if (tags.length > 0) {
				var cloud:String;
				
				var sortField:SortField = new SortField("name");
				
				var sort:Sort = new Sort();
				sort.fields = new Array(sortField);
				
				tags.sort = sort;
				
				var tag:Tag = tags[0];
				
				cloud = new String(buildHTMLTag(tag, showWeight));
				for (var i:uint = 1; i < tags.length; ++i) {
					tag = tags[i];
					cloud += ', ' + buildHTMLTag(tag, showWeight);
				}
			} else {
				cloud = new String('');
			}
			
			return cloud;
		}
		public static function getVariablesFromHTMLTag(htmlTag:String):Object {
			var statements:Array = htmlTag.split(",");
			
			var variables:Object = new Object();
			
			for each (var statement:String in statements) {
				var statementSplit:Array = statement.split("=");
				var property:String = statementSplit[0];
				var value:String = statementSplit[1];
				variables[property] = value;
			}
			
			return variables;
		}
		
		
		//////////////////////////////////////////////////
		//private static functions
		
		private static function buildHTMLTag(tag:Tag, showWeight:Boolean):String {
			var tagHTML:String = '';
			
			if (showWeight == true) {
				tagHTML += '<font size="' + tag.weight + '">';
			}
			
			tagHTML += '<a href="Event:id=' + tag.id + ',name=' + tag.name + '" class="tagLink">' + tag.name + '</a>';
			
			if (showWeight == true) {
				tagHTML += '</font>';
			}
			
			return tagHTML;
		}
	}
}