detailsnamelink.mxml

flex 实现的一个showcase 喜欢flex的朋友可以

<?xml version="1.0" encoding="utf-8"?>
<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" 
	width="100%" height="{companyNameLabel.height}"
	 horizontalScrollPolicy="off"
	 verticalScrollPolicy="off"
	>
	
	<mx:Script>
		<![CDATA[
		
		
			//////////////////////////////////////////////////
			//import
			
			//////////////////////////////////////////////////
			//private varibales
			
			private var __labelName:String;
			private var __companyName:String;
			private var __companyEmail:String;
			private var __companyUrl:String;
			
			
			/////////////////////////////////////////////////////////////////////////////////////
			//GETTER/SETTER
			
			[Bindable] 
			public function set labelName(val:String):void{
				this.__labelName = val;
			};
			
			public function get labelName():String{
				return this.__labelName;
			};
			
			//---------------------------------------------------------------------------
			
			[Bindable] 
			public function set companyName(val:String):void{
				if(val!=""&&val!=null){
					this.__companyName = val;
				} else {
					this.__companyName = "N/A";
				}
			
				this.handleCompanyName()
			};
			
			public function get companyName():String{
				return this.__companyName;
			};
			
			private function handleCompanyName():void{
				//
			}
			
			//---------------------------------------------------------------------------
			
			[Bindable] 
			public function set companyEmail(val:String):void{
				if(val!=""&&val!=null){
					this.__companyEmail = val;
					if(companyName=="N/A"){
						this.companyEmailLink.visible=false
					}else{
						this.companyEmailLink.visible=true
					}
					
				} else {
					this.__companyEmail = "N/A";
					this.companyEmailLink.visible=false
				}
			
				this.handleCompanyEmail()
			};
			
			public function get companyEmail():String{
				return this.__companyEmail;
			};
			
			private function handleCompanyEmail():void{
				//
			}
			
			//---------------------------------------------------------------------------
			
			[Bindable] 
			public function set companyUrl(val:String):void{
				
				if(val!=""&&val!=null&&val!="http://"){
					this.__companyUrl = val;
					if(companyName=="N/A"){
						this.companyUrlLink.visible=false
					}else{
						this.companyUrlLink.visible=true
					}
					
					
					this.companyNameText.addEventListener(MouseEvent.ROLL_OVER,handleLabelRollOver)
					this.companyNameText.addEventListener(MouseEvent.ROLL_OUT,handleLabelRollOut)
					this.companyNameText.addEventListener(MouseEvent.CLICK,launchCompanyLink)
					this.companyNameText.buttonMode=true
				} else {
					this.__companyUrl = "N/A";
					this.companyUrlLink.visible=false
					this.companyNameText.removeEventListener(MouseEvent.ROLL_OVER,handleLabelRollOver)
					this.companyNameText.removeEventListener(MouseEvent.ROLL_OUT,handleLabelRollOut)
					this.companyNameText.removeEventListener(MouseEvent.CLICK,launchCompanyLink)
					this.companyNameText.buttonMode=false;
				}
			
				this.handleCompanyUrl()
			};
			
			public function get companyUrl():String{
				return this.__companyUrl;
			};
			
			private function handleCompanyUrl():void{
				//
			}
			
			//rollover/rollout----------------------------------------------------------------------
			private function handleLabelRollOver(event:Event):void{
				var lab:Label=event.target as Label;
				lab.setStyle("color",0x00CCFF);
			}
			
			private function handleLabelRollOut(event:Event):void{
				var lab:Label=event.target as Label;
				lab.setStyle("color",0xFFFFFF);
			}
			
			//client----------------------------------------------------------------------------
			private function launchCompanyLink(event:Event=null):void {
				if (companyUrl != null && companyUrl != "" && companyUrl!="http://") {
					var urlreq:URLRequest = new URLRequest(companyUrl);
					navigateToURL(urlreq, "_blank");
				}
			}
			
			private function emailCompany(event:Event=null):void {
				var urlreq:URLRequest = new URLRequest("mailto:"+companyEmail + "?subject=Flex.org: " + companyName);
				navigateToURL(urlreq, "_self");
				
			}
			
			
	]]>
	</mx:Script>
	
	
	<mx:Label id="companyNameLabel" text="{labelName+':'}" styleName="myriadRegular" color="0x333333"/>
	<mx:Text id="companyNameText" styleName="myriadRegular" selectable="false" htmlText="{companyName}"
		color="0x666666" x="{companyNameLabel.x+companyNameLabel.width-3}" mouseChildren="false"/>
	<mx:Button id="companyUrlLink" styleName="detailsPanelLinkButton" 
		x="{companyNameText.x+companyNameText.width+5}" y="3" buttonMode="true" 
		click="launchCompanyLink()" toolTip="Visit Website"/>
	<mx:Button id="companyEmailLink" styleName="detailsPanelEmailButton" 
		x="{companyUrlLink.x+companyUrlLink.width+7}" y="-2" buttonMode="true" 
		click="emailCompany()" visible="false" toolTip="Send An Email"/>
</mx:Canvas>