flexdotorgwindow.mxml

flex 实现的一个showcase 喜欢flex的朋友可以

<?xml version="1.0" encoding="utf-8"?>
<mx:VBox 
	xmlns:mx="http://www.adobe.com/2006/mxml"
	
	width="100%"
	height="100%"
	
	styleName="flexPopUp"
	
	horizontalScrollPolicy="off"
	verticalScrollPolicy="off"
	
	paddingLeft="{PADDING}"
	paddingRight="{PADDING}"
	paddingTop="{PADDING}"
	paddingBottom="{PADDING}">
	
	
	<mx:Script>
		<![CDATA[
		
		
			//////////////////////////////////////////////////
			//import
			
			import mx.binding.utils.BindingUtils;
			import mx.containers.HBox;
			import mx.controls.*;
			import mx.effects.Fade;
			import mx.events.TweenEvent;
			
			
			//////////////////////////////////////////////////
			//static public variables
			
			static public const PADDING:uint = 35;
			
			//////////////////////////////////////////////////
			//getter/setter variables
			
			private var __showclosebutton:Boolean = true;
			
			///////////////////////////////////////////////////////////////////////////
			//getter/setter functions
			
			[Bindable]
			public function set showclosebutton(i_val:Boolean):void {
				__showclosebutton=i_val;
			}
			public function get showclosebutton():Boolean {
				return __showclosebutton;
			}
			
			//////////////////////////////////////////////////
			//initialization
			
			override protected function createChildren():void{
				var topbar:HBox=new HBox();
				topbar.percentWidth=100;
				
				var leftbox:HBox=new HBox();
				leftbox.percentWidth=100;
				leftbox.setStyle("horizontalAlign","left");
				
				var rightbox:HBox=new HBox();
				rightbox.percentWidth=100;
				rightbox.setStyle("horizontalAlign","right");
				
				var label:Label=new Label();
				BindingUtils.bindProperty(label,"text",this,"label")
				label.styleName="flexDarkTitle";
				leftbox.addChild(label);
				
				var close_but:Button=new Button();
				close_but.visible=showclosebutton;
				BindingUtils.bindProperty(close_but,"visible",this,"showclosebutton");
				close_but.styleName="mainNavSearchBarCloseButton";
				close_but.buttonMode=true;
				close_but.addEventListener(MouseEvent.CLICK,cancelClickHandler);
				rightbox.addChild(close_but);
				
				topbar.addChild(leftbox);
				topbar.addChild(rightbox);
				this.addChild(topbar);

				super.createChildren();
			}
			
			//////////////////////////////////////////////////
			//public functions
			
			public function center():void {
				x = parent.width / 2 - width / 2;
				y = parent.height / 2 - height / 2;
			}
			public function show():void {
				center();
				visible = true;
				var fade:Fade = new Fade(this)
				fade.duration = 200;
				fade.alphaFrom = alpha;
				fade.alphaTo = 1;
				fade.play();
			}
			public function hide():void {
				var fade:Fade = new Fade(this);
				fade.addEventListener(TweenEvent.TWEEN_END, hideCompleteHandler);
				fade.duration = 200;
				fade.alphaFrom= alpha;
				fade.alphaTo = 0;
				fade.play();
			}
			
			
			//////////////////////////////////////////////////
			//handler functions
			
			private function hideCompleteHandler(tweenEvent:TweenEvent):void {
				visible = false;
			}
			private function cancelClickHandler(mouseEvent:MouseEvent):void {
				hide();
			}
			
			
		]]>
	</mx:Script>
	
	
</mx:VBox>