使用parameter对象进行参数查询.asp

flash如何连接后台的数据库开发

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<!--#include file="conn.asp"-->
<%
   dim objcmd,Rs
   set objcmd=server.CreateObject("ADODB.Command")
   '创建一个RecordSet对象
   set Rs=server.CreateObject("ADODB.RecordSet")
%>
<form action="<%=request.ServerVariables("SCRIPT_NAME")%>" name="frm">
   查询<select name="sex">
            <option value="男">男</option>
			<option value="女">女</option>
	   </select>
	   <input type="submit" value="查询">
</form>
<%
    if request.QueryString("sex")<>"" then
	     strSQL="select * from Student where 性别=?"
		 with objcmd
		      .ActiveConnection=conn
			  .CommandText=strSQL
			  .CommandType=adcmdText
		 end with
		 set para=objcmd.CreateParameter("性别",adVarChar,adParamInput,10)
		 '设置Parameter对象的值
		 para.value=request.QueryString("sex")
		 '将参数添加到Parameters集合中
		 objcmd.Parameters.Append para
		 '根据设置的参数执行查询
		 set Rs=objcmd.execute
		 response.Write("查询结果如下：<br>")
%>
          <table border="1" cellpadding="0" cellspacing="0">
		  <tr bgcolor="#CCCCCC">
		      <th>学号</th><th>性别</th><th> 政治面貌</th><th>省份</th>
		  </tr>
<%
	     '输出查询结果
		 do while not rs.eof
%>
             <tr>
             <td><%=rs("学号")%></td>
			 <td><%=rs("性别")%></td>
			 <td><%=rs("政治面貌")%></td>
			 <td><%=rs("省份")%></td>
			 </tr>
<% 
             rs.MoveNext
		 loop 
%>
</table>
<%
    end if
	set objcmd=Nothing
%>