advnce.f90

来自「CCSM Research Tools: Community Atmospher」· F90 代码 · 共 92 行

#include <misc.h>
#include <params.h>

subroutine advnce
!-----------------------------------------------------------------------
!
! Purpose: 
! Advance time information
!
! Method: 
!
! Author: CCM1, CMS Contact: J. Truesdale
!
!-----------------------------------------------------------------------
  use precision
  use chemistry, only: chem_time_interp
  use so4bnd
  use ramp_so4_mod
  use time_manager, only: get_nstep

#if ( ! defined COUP_CSM ) && ( ! defined COUP_SOM )
  use ice_data, only: iceint
  use sst_data, only: sstint
#endif

  implicit none

#include <comctl.h>
#include <comlun.h>
!
!-----------------------------------------------------------------------
!
! Local workspace
!
  integer :: nstep             ! current timestep number
!-----------------------------------------------------------------------

  nstep = get_nstep()
!
! Determine whether it is time for a shortwave or longwave radiation 
! calculation
!
  dosw = nstep.eq.0 .or. iradsw.eq.1 .or. (mod(nstep-1,iradsw).eq.0 .and. nstep.ne.1)
  dolw = nstep.eq.0 .or. iradlw.eq.1 .or. (mod(nstep-1,iradlw).eq.0 .and. nstep.ne.1)
!
! Determine whether it is time for an absorptivity/emissivity calculation
!
  doabsems = nstep.eq.0 .or. iradae.eq.1 .or. (mod(nstep-1,iradae).eq.0 .and. nstep.ne.1)
  aeres = (mod(nstep,iradae).ne.0)
!
! Update ozone data on shortwave or longwave time step. 
! Note that the ozone data is not needed on a longwave time step unless the
! absorptivities are being updated ("doabsems").
!
  if (dosw .or. dolw) then
     call oznint
  end if
!
! Time interpolate sst data
!
#if ( ! defined COUP_CSM )
#if ( defined COUP_SOM )
  call t_startf ('somint')
  call somint ()
  call t_stopf ('somint')
#else
  call sstint ()
  call iceint ()
#endif
#endif
!
! Ramping ghg if appropriate
!
  if (doRamp_ghg ) call ramp_ghg
!
! Ramp solar constant if appropraite
!
  if (doRamp_scon) call ramp_scon
!
! Time interpolate for chemistry, if appropriate
!
  if (trace_gas) call chem_time_interp
!
! sulfate aerosols
!
  if ( doRamp_so4 ) then
     call ramp_so4
     call sulfint
  endif

end subroutine advnce