engy_tdif.f90

CCSM Research Tools: Community Atmosphere Model (CAM)

#include <misc.h>
#include <params.h>

subroutine engy_tdif(cwava   ,w       ,t       ,tm1     ,pdel    , &
                     difft   ,nlon    )

!----------------------------------------------------------------------- 
! 
! Purpose: 
! Calculate contribution of current latitude to del-T integral
! 
! Method: 
! 
! Author: J. Olson
! 
!-----------------------------------------------------------------------
!
! $Id: engy_tdif.F90,v 1.1.2.1 2002/02/01 00:00:28 olson Exp $
! $Author: olson $
!
!-----------------------------------------------------------------------
!
  use precision
  use pmgrid
  implicit none
!
!------------------------------Arguments--------------------------------
!
  integer , intent(in)  :: nlon                 ! longitude dimension  
  real(r8), intent(in)  :: cwava                ! normalization factor    l/(g*plon)
  real(r8), intent(in)  :: w                    ! gaussian weight this latitude
  real(r8), intent(in)  :: t   (plond,plev)     ! temperature
  real(r8), intent(in)  :: tm1 (plond,plev)     ! temperature (previous timestep)
  real(r8), intent(in)  :: pdel(plond,plev)     ! pressure diff between interfaces
  real(r8), intent(out) :: difft                ! accumulator
!
!---------------------------Local variables-----------------------------
!
  integer i,k               ! longitude, level indices
  real(r8) const            ! temporary constant
!
!-----------------------------------------------------------------------
!
! Integration factor (the 0.5 factor arises because gaussian weights sum to 2)
!
  const = cwava*w*0.5
  difft = 0.
!
! Compute mass integral
!
  do k=1,plev
     do i=1,nlon
        difft = difft + abs( t(i,k) - tm1(i,k) )*pdel(i,k)
     end do
  end do

  difft = difft*const

  return
end subroutine engy_tdif