📄 newsshow.asp
字号:
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<!--#include file="inc/config.asp"-->
<%
'========================================================================================
' 文 件 名: NewsShow.asp
' 版 本: WapForum教程--WAP新闻系统
' 说 明: 新闻内容显示文件 | 请勿删除此说明内容，转载请注明出处。多谢合作！
' 文件日期: 2007-03-01
' 讨论网站: WapForum.cn
'========================================================================================
' Copyright (C) 2007 WapForum.cn. All rights reserved.
' 网 站: http://WapForum.cn
' 电子邮件: Service@WapForum.cn
' 联系ＱＱ: 13431619,44459416,82890065
' QQ交流群: 36508170
'========================================================================================
Response.ContentType="text/vnd.wap.wml;charset=UTF-8" '将文件的格式转换成wml，编码为UTF-8
%>
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE wml PUBLIC "-//WAPFORUM//DTD WML 1.1//EN" "http://www.wapforum.org/DTD/wml_1.1.xml">
<wml>
<head>
<meta http-equiv="Cache-Control" content="max-age=0"/><!-- 每次都需通过连接服务器调用本页内容 -->
<meta http-equiv="Cache-Control" content="no-cache"/><!-- 禁止浏览器从缓存中访问页面内容 -->
</head>
<card id="NewsShow" title="查看内容">
<p align="left"><!-- 页面居左对齐 -->
<%
Dim ID,rs,i,typeID,content '定义变量
ID=int(request.QueryString("ID"))
Call openConn() '打开数据库
Set rs=conn.execute("Select typeID,title,content,comment From [NewsContent] where ID="& ID &"") '读取新闻内容表
If Not rs.eof Then
typeID=rs(0)
content=rs(2) '将新闻内容传给变量content
Dim gopage,PS,conlen,page,pagecount,ys,startc
PS = 300
conlen=len(content) '获取内容的长度(字数)
page=request.QueryString("page")
if page<=0 or page="" then page=1
pagecount=cint(conlen/PS) '计算出页数(记住,cint是对数值变量四舍五入取整,这也直接关系到下面余数加多一页的问题)
ys=conlen mod PS '取余数
if ys<=PS/2 and ys>0 then
pagecount=pagecount+1 '当余数大于内容长度的一半并余数大于0的时候,页数加1(因为上面取页数的时候是四舍五入,所以这里把PS除于2)
end if
startc=PS*(page-1)+1 '计算出每页截取字符号的位置
content=mid(content,startc,PS) '节取内容
Response.Write (rs(1)&"<br/>=*=*=*=*=*=<br/>"&replaceStr(content)) '将内容中的回车替换成换行
gopage="NewsShow.asp?ID="& ID &"&" '定义翻页地址变量
if pagecount>1 then response.Write "<br/>=*=*=*=*=*=<br/>当前为第"&page&"/"&pagecount&"页<br/>"
if page-pagecount<0 then response.write "<a href="""&gopage&"page="&page+1&""">下一页-</a>"
if page>1 then response.write "<a href="""&gopage&"page="&page-1&""">上一页-</a>"
if pagecount>2 then response.write "<br/><input name=""page"" format=""*N"" value="""&page&""" type=""text"" maxlength=""5""/><br/><a href="""&gopage&"page=$(page)"">[跳转到该页]</a>"
'//读取最后一条回复
Dim rsReply
Set rsReply=conn.execute("Select top 1 content from [NewsComment] where newsID="& ID &" order by ID desc")
If Not rsReply.eof Then
Response.Write("<br/>=*=*=*=*=*=<br/>")
Response.Write ("最新回复：<br/>"&_
replaceStr(rsReply(0))&"<br/>"&_
"<a href=""ReplyList.asp?ID="& ID &""">阅读所有回复</a>")
End If
rsReply.close()
set rsReply=nothing
Response.Write("<br/>=*=*=*=*=*=<br/>")
Response.Write ("快速回复：<br/>"&_
"<input name=""content"&ID&""" emptyok=""true"" type=""text""/><br/>"&_
"<anchor>马上回复"&_
"<go href=""SaveReply.asp"" method=""post"">"&_
"<postfield name=""ID"" value="""&ID&""" />"&_
"<postfield name=""content"" value=""$(content"&ID&":n)"" />"&_
"<postfield name=""Method"" value=""POST"" />"&_
"</go>"&_
"</anchor>")
'//注：这里（$content:n）是WML变量的写法，以$符号开头，WML中表单提交有:n，:e，:u，和空，
'//四种状态，其中:n是强制不进行URL转义；:e是转义；:u是反转义。
Else
typeID=1
Response.Write ("该新闻不存在")
End If
Call rsClose()
Call ConnClose()
%>
<br/>=*=*=*=*=*=<br/>
<a href="NewsList.asp?ID=<%=typeID%>">返回新闻列表</a><br/>
<a href="index.asp">返回网站首页</a><br/>
</p>
</card>
</wml>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -