fmmain.pas

delphi老牌的浏览器控件

//*************************************************************
//                    EmbeddedWB - Tabs Demo                  *
//                                                            *
//                            by                              *
//                     Eran Bodankin (bsalsa)                 *
//                     [e-mail]                      *
//                                                            *
//     Documentation and updated versions:                    *
//               http://www.bsalsa.com                        *
//*************************************************************
{*******************************************************************************}
{LICENSE:
THIS SOFTWARE IS PROVIDED TO YOU "AS IS" WITHOUT WARRANTY OF ANY KIND,
EITHER EXPRESSED OR IMPLIED INCLUDING BUT NOT LIMITED TO THE APPLIED
WARRANTIES OF MERCHANTABILITY AND/OR FITNESS FOR A PARTICULAR PURPOSE.
YOU ASSUME THE ENTIRE RISK AS TO THE ACCURACY AND THE USE OF THE SOFTWARE
AND ALL OTHER RISK ARISING OUT OF THE USE OR PERFORMANCE OF THIS SOFTWARE
AND DOCUMENTATION. [YOUR NAME] DOES NOT WARRANT THAT THE SOFTWARE IS ERROR-FREE
OR WILL OPERATE WITHOUT INTERRUPTION. THE SOFTWARE IS NOT DESIGNED, INTENDED
OR LICENSED FOR USE IN HAZARDOUS ENVIRONMENTS REQUIRING FAIL-SAFE CONTROLS,
INCLUDING WITHOUT LIMITATION, THE DESIGN, CONSTRUCTION, MAINTENANCE OR
OPERATION OF NUCLEAR FACILITIES, AIRCRAFT NAVIGATION OR COMMUNICATION SYSTEMS,
AIR TRAFFIC CONTROL, AND LIFE SUPPORT OR WEAPONS SYSTEMS. VSOFT SPECIFICALLY
DISCLAIMS ANY EXPRESS OR IMPLIED WARRANTY OF FITNESS FOR SUCH PURPOSE.

You may use, change or modify the demo under 4 conditions:
1. In your website, add a link to "http://www.bsalsa.com"
2. In your application, add credits to "Embedded Web Browser"
3. Mail me  ([e-mail]) any code change in the unit
   for the benefit of the other users.
4. Please,  consider donation in our web site!
{*******************************************************************************}

unit fmMain;

interface

uses
   Classes, Controls, Forms, ComCtrls, ExtCtrls, StdCtrls, OleCtrls,
   IEAddress, EwbCore, EmbeddedWB, ShDocVw_Ewb;

type
   TTabSheetEx = class(TTabSheet)
   private
      EWB: TEmbeddedWB;
      CanBack: Boolean;
      CanForward: Boolean;
   end;

type
   TForm1 = class(TForm)
      Panel1: TPanel;
      PageControl1: TPageControl;
      btnGo: TButton;
      btnBack: TButton;
      btnForward: TButton;
      IEAddress1: TIEAddress;
      StatusBar1: TStatusBar;
      cbOpenNew: TCheckBox;
      procedure PageControl1Change(Sender: TObject);
      procedure btnGoClick(Sender: TObject);
      procedure btnForwardClick(Sender: TObject);
      procedure btnBackClick(Sender: TObject);
      procedure FormShow(Sender: TObject);
   private
    { Private declarations }
      procedure DownloadCompleteEvent(Sender: TObject);
      procedure ScriptErrorEvent(Sender: TObject; Context: OleVariant; var Action: TScriptErrorAction);
      procedure CommandStateChangeEvent(Sender: TObject; Command: Integer; Enable: WordBool);
      procedure UpdateControls;
      procedure CreateNewTabBrowser(Url: string);
      procedure NewWindow2Event(Sender: TObject; var ppDisp: IDispatch; var Cancel: WordBool);
      procedure StatusTextChangeEvent(Sender: TObject; const Text: WideString);

   public
    { Public declarations }
      function GetActiveWB: TEmbeddedWB;
   end;

var
   Form1: TForm1;
   TabSheetEx: TTabSheetEx;

implementation

{$R *.dfm}

function Tform1.GetActiveWB: TEmbeddedWB;
begin
   Result := nil;
   with PageControl1 do
      if (ActivePage.ControlCount > 0) and (ActivePage.Controls[0] is TEmbeddedWB) then
         Result := (TEmbeddedWB(ActivePage.Controls[0]));
end;

procedure Tform1.UpdateControls;
var
   TabEx: TTabSheetEx;
begin
   TabEx := (PageControl1.ActivePage as TTabSheetEx);
   IEAddress1.Text := TabEx.EWB.LocationURL;
   PageControl1.ActivePage.Caption := TabEx.EWB.LocationName;
   Form1.Caption := TabEx.EWB.LocationName;
   BtnForward.Enabled := TabEx.CanForward;
   btnBack.Enabled := TabEx.CanBack;
end;

procedure Tform1.DownloadCompleteEvent(Sender: TObject);
begin
   UpdateControls;
end;

procedure Tform1.ScriptErrorEvent(Sender: TObject; Context: OleVariant;
   var Action: TScriptErrorAction);
begin
   Action := eaContinue;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
   CreateNewTabBrowser('http://bsalsa.com/forum/');
   UpdateControls;
end;

procedure TForm1.CreateNewTabBrowser(Url: string);
begin
   TabSheetEx := TTabSheetEx.Create(PageControl1);
   with TabSheetEx do
      begin
         PageControl := PageControl1;
         EWB := TEmbeddedWB.Create(TabSheetEx);
         Caption := 'Loading..';
         TOleControl(TabSheetEx.EWB).Parent := TabSheetEx;
         PageControl1.ActivePage := TabSheetEx;
         with EWB do
            begin
               LoadSettings;
               Align := alClient;
               OnStatusTextChange := StatusTextChangeEvent;
               OnNewWindow2 := NewWindow2Event;
               OnDownloadComplete := DownloadCompleteEvent;
               OnCommandStateChange := CommandStateChangeEvent;
               if (URL) <> '' then
                  Go(URL);
            end;
      end;
end;

procedure TForm1.btnBackClick(Sender: TObject);
begin
   btnBack.Enabled := False;
   TabSheetEx.EWB.GoBack;
end;

procedure TForm1.btnForwardClick(Sender: TObject);
begin
   btnForward.Enabled := False;
   TabSheetEx.EWB.GoForward;
end;

procedure TForm1.btnGoClick(Sender: TObject);
begin
   if cbOpenNew.Checked then
      CreateNewTabBrowser(IEAddress1.Text)
   else
      TabSheetEx.EWB.Go(IEAddress1.Text);
end;

procedure Tform1.CommandStateChangeEvent(Sender: TObject; Command: Integer; Enable: WordBool);
begin
   case Command of
      CSC_NAVIGATEBACK:
         ((Sender as TEmbeddedWB).Owner as TTabSheetEx).CanBack := Enable;
      CSC_NAVIGATEFORWARD:
         ((Sender as TEmbeddedWB).Owner as TTabSheetEx).CanForward := Enable;
   end;
end;

procedure Tform1.NewWindow2Event(Sender: TObject; var ppDisp: IDispatch; var Cancel: WordBool);
begin
   CreateNewTabBrowser(TabSheetEx.EWB.LocationURL);
   PageControl1.ActivePage := TabSheetEx;
   ppdisp := TabSheetEx.EWB.Application;
end;

procedure TForm1.PageControl1Change(Sender: TObject);
begin
   UpdateControls;
end;

procedure Tform1.StatusTextChangeEvent(Sender: TObject;
   const Text: WideString);
begin
   StatusBar1.SimpleText := Text;
end;

end.