common.inc

会议事务系统

<%
dim adoConn	'定义数据库连接变量
response.expires=0

public sub checkError()
	if err.Number<>0 then raiseErr err.description
end sub

public function getConnection
	if isEmpty(adoConn) then
		set adoConn= server.createobject("ADODB.Connection")
		adoConn.Open "DSN=meetmng;UID=sa;PWD="
	end if
	set getConnection=adoConn
end function

public function getUser()
	checkSession
	getUser=session("user")
end function

public function getUserRank()
	checkSession
	getUserRank=session("userrank")
end function

public sub closeConnection()
	if not isEmpty(adoConn) then adoConn.Close()
end sub

public sub checkSession
	if isEmpty(session("user")) then
		response.redirect "../default.htm"
	end if
end sub

public sub raiseErr (sErr)
	closeConnection
	response.redirect "../err.asp?err=" & sErr
end sub

public sub WriteOption(val,curVal,text)
	response.write "<option value='" & val & "'"
	if val=curVal then response.write " selected "
	response.write ">" & text & "</option>"
end sub

public function getUserRankById(userid)
	checkSession
	dim adoRS
	dim strQuery
	strQuery="select * from userinfo where userid='" & "" & userid & "'"
	set adoRS=server.createobject("ADODB.Recordset")
	adoRS.Open strQuery, getConnection(), , , adCmdText
	if adoRS.EOF then
		getUserRankById = null
	else
		getUserRankById = adoRS("purview")
	end if
	set adoRS = Nothing
end function

public function getRankStr(userId)
	checkSession
	dim strRet
	if getUserRankById(userId) = 1 then
		strRet = "系统管理员"
	else
		strRet = "普通用户" 
	end if
	getRankStr = strRet
end function

public sub addlog(operation, tablename)
	checkSession
	Dim strInsert
	strInsert = "insert into operationlog(operator,operation,tablename) values('"
	strInsert = strInsert & getUser() & "','" & operation & "','" & tablename & "')"
	getConnection().Execute strInsert
end sub

public sub addmsg(touser, msg)
	checkSession
	Dim strInsert
	strInsert = "insert into message(fromuser,touser,message,state) values('"
	strInsert = strInsert & getUser() & "','" & touser & "','" & msg & "',0)"
	getConnection().Execute strInsert
end sub

public sub writeUserListOption(userid)
	checkSession
	dim selUser
	dim adoRS
	dim strQuery
	selUser = "" & userid
	strQuery="select * from userinfo"
	set adoRS=server.createobject("ADODB.Recordset")
	adoRS.Open strQuery, getConnection(), , , adCmdText
	while not adoRS.EOF
		WriteOption adoRS("userid"),selUser,adoRS("userid")
		adoRS.MoveNext
	Wend
	set adoRS = Nothing
end sub

public sub writeYearOption(intYear)
	checkSession
	dim selYear
	if "" & intYear = "" then
		selYear = Year(Now)
	else
		selYear = CInt(intYear)
	end if
	for i=1990 to 2100
		WriteOption i,selYear,i
	Next
end sub

public sub writeMonthOption()
	for i=1 to 12
		WriteOption i,Month(Now),i
	Next
end sub

public sub writeDayOption()
	for i=1 to 31
		WriteOption i,Day(Now),i
	Next
end sub

public sub writeHourOption()
	for i=1 to 24
		WriteOption i,Hour(Now),i
	Next
end sub

public sub writeMinuteOption()
	for i=1 to 60
		WriteOption i,Minute(Now),i
	Next
end sub

public function insertBR(str)
	dim strRet
	dim strLeave
	strLeave = str
	strRet = ""
	while Len(strLeave) >=15
		strRet = strRet & Left(strLeave,14) & "<BR>"
		strLeave = Mid(strLeave,15)
	Wend
	strRet = strRet & strLeave
	insertBR = strRet
end function

public function getMsgRS()
	checkSession
	dim adoRS
	dim strQuery
	strQuery="select * from message where state=0 and touser='" & getUser() & "'"
	set adoRS=server.createobject("ADODB.Recordset")
	adoRS.Open strQuery, getConnection(), , , adCmdText
	set getMsgRS = adoRS
end function

public sub setMsgOver(id)
	checkSession
	Dim strQuery
	strQuery = "update message set state=1 where id=" & id
	getConnection().Execute strQuery
end sub
%>