见招拆招《windows程序设计》(十) .txt

会变语言实现的一些程序

见招拆招《Windows程序设计》(十) 
相关的例子:下载>>>  作者：Zoologist 于2008-8-17上传   

--------------------------------------------------------------------------------

对话框

如果有很多输入超出了菜单可以处理的程度，那么我们可以使用对话框来取得输入信息。程序写作者可以通过在某选项后面加上省略号（…）来表示该菜单项将启动一个对话框。

当程序呼叫依据模板建立的对话框时，Microsoft Windows负责建立弹出式对话框窗口和子窗口控件，并提供处理对话框消息（包括所有键盘和鼠标输入）的窗口消息处理程序。有时候称呼完成这些功能的Windows内部程序代码为「对话框管理器」。

Windows的内部对话框窗口消息处理程序所处理的许多消息也传递给您自己程序中的函数，这个函数即是所谓的「对话框程序」或者「对话程序」。对话程序与普通的窗口消息处理程序类似，但是也存在着一些重要区别。一般来说，除了在建立对话框时初始化子窗口控件，处理来自子窗口控件的消息以及结束对话框之外，程序写作者不需要再给对话框程序增加其它功能。对话程序通常不处理WM_PAINT消息，也不直接处理键盘和鼠标输入。

对话框这个主题的含义太广了，因为它还包含子窗口控件的使用。不过，我们已经在前面研究过子窗口控件。当您在对话框中使用子窗口控件时，前面所提到的许多工作都可以由Windows的对话框管理器来完成。尤其是，在程序COLORS1中遇到在滚动条之间切换输入焦点的问题也不会在对话框中出现。Windows会处理对话框中的控件之间切换输入焦点所必需完成的全部工作。

不过，在程序中添加对话框要比添加图标或者菜单更麻烦一些。我们将从一个简单的对话框开始，让您对各部分之间的相互联系有所了解。

模态对话框


对话框分为两类：「模态的」和「非模态的」，其中模态对话框最为普遍。当您的程序显示一个模态对话框时，使用者不能在对话框与同一个程序中的另一个窗口之间进行切换，使用者必须主动结束该对话框，这藉由通过按一下「OK」或者「Cancel」键来完成。不过，在显示模态对话框时，使用者通常可以从目前的程序切换到另一个程序。而有些对话框（称为「系统模态」）甚至连这样的切换程序操作也不允许。在Windows中，显示了系统模态对话框之后，要完成其它任何工作，都必须先结束该对话框。

建立「About」对话框


Windows程序即使不需要接收使用者输入，也通常具有由菜单上的「About」选项启动的对话框，该对话框用来显示程序的名字、图标、版权旗标和标记为「OK」的按键，也许还会有其它信息（例如技术支持的电话号码）。我们将要看到的第一个程序除了显示一个「About」对话框外，别无它用。这个ABOUT1程序如程序11-1所示：

程序11-1 ABOUT1 

        
ABOUT1.ASM

;MASMPlus 代码模板 - 普通的 Windows 程序代码

.386
.Model Flat, StdCall
Option Casemap :None

Include windows.inc
Include user32.inc
Include kernel32.inc
Include gdi32.inc

includelib gdi32.lib
IncludeLib user32.lib
IncludeLib kernel32.lib
include macro.asm
	
	WinMain PROTO :DWORD,:DWORD,:DWORD,:DWORD
	IDM_APP_ABOUT     equ        40001
.DATA
	szAppName	TCHAR	"About1",0
.DATA?
	hInstance	HINSTANCE	?
.CODE
START:
	invoke GetModuleHandle,NULL
	invoke WinMain,eax,NULL,NULL,SW_SHOWDEFAULT
	invoke ExitProcess,0
WinMain proc hInst:DWORD,hPrevInst:DWORD,szCmdLine:DWORD,iCmdShow:DWORD
	LOCAL wndclass   :WNDCLASSEX
	LOCAL msg  :MSG
	LOCAL hWnd :HWND

	mov wndclass.cbSize,sizeof WNDCLASSEX	
	mov wndclass.style,CS_HREDRAW or CS_VREDRAW	
	mov wndclass.lpfnWndProc,offset WndProc

	mov wndclass.cbClsExtra,0
	mov wndclass.cbWndExtra,0
	
	push hInst
	pop wndclass.hInstance
	
	invoke LoadIcon,hInst,addr szAppName
	mov wndclass.hIcon,eax	
	
	invoke LoadCursor,NULL,IDC_ARROW
	mov wndclass.hCursor,eax	
	
	invoke GetStockObject,WHITE_BRUSH
	mov wndclass.hbrBackground,EAX
	
	lea eax,szAppName
	mov wndclass.lpszMenuName,eax
	mov wndclass.lpszClassName,eax

	mov wndclass.hIconSm,0
	
	invoke RegisterClassEx, ADDR wndclass
	.if (eax==0)
	   invoke MessageBox,NULL,CTXT("This program requires Windows NT!"),szAppName, MB_ICONERROR
           ret
	.endif
        
   
	invoke CreateWindowEx,NULL,
			ADDR szAppName, 					;window class name
			CTXT("No-Popup Nested Menu Demonstration"), 
			WS_OVERLAPPEDWINDOW,					;window style
			CW_USEDEFAULT,						;initial x position
			CW_USEDEFAULT,						;initial y position
			CW_USEDEFAULT, 						;initial x size
			CW_USEDEFAULT,						;initial y size
			NULL,							;parent window handle
			NULL,							;window menu handle
			hInst,							;program instance handle
			NULL										;creation parameters
	mov hWnd,eax


  	invoke ShowWindow,hWnd,iCmdShow
	invoke UpdateWindow,hWnd
	

	StartLoop:
		invoke GetMessage,ADDR msg,NULL,0,0
			cmp eax, 0
			je ExitLoop
				invoke TranslateMessage, ADDR msg
				invoke DispatchMessage,  ADDR msg
			jmp StartLoop
	ExitLoop:
	
	mov eax,msg.wParam
	ret
WinMain endp

AboutDlgProc	proc hDlg:HWND,message:UINT,wParam:WPARAM,lParam:LPARAM
	.if	message == WM_INITDIALOG
		mov	eax,TRUE
	.elseif	message == WM_COMMAND
		mov	eax,wParam
		and	eax,0FFFFh
		.if	(eax==IDOK)||(eax==IDCANCEL)
			invoke	EndDialog,hDlg, 0
			mov	eax,TRUE
		.endif	
	.else
		mov	eax,FALSE
	.endif	
  	ret
AboutDlgProc	endp

WndProc proc hwnd:DWORD,uMsg:DWORD,wParam :DWORD,lParam :DWORD
	.if	uMsg == WM_CREATE
		mov	esi,lParam
		mov	eax,[esi+4]
		mov	hInstance,eax

		xor	eax,eax
		ret			
	.elseif uMsg == WM_COMMAND
		mov	eax,wParam
		and	eax,0FFFFh
		.if	eax == IDM_APP_ABOUT
			invoke	DialogBoxParamA,hInstance, CTXT ("AboutBox"), hwnd,addr AboutDlgProc,0
		.endif
	        xor	eax,eax
	        ret
	.elseif uMsg == WM_DESTROY
	        invoke 	PostQuitMessage,NULL
	        xor	eax,eax
	        ret
	.endif

	invoke DefWindowProc,hwnd,uMsg,wParam,lParam
	ret
WndProc endp
END START
ABOUT1.RC （摘录） 

#include "resource.h"
#define DS_MODALFRAME					0x80L
#define IDM_APP_ABOUT                   40001

ABOUTBOX DIALOG DISCARDABLE  32, 32, 180, 102
STYLE DS_MODALFRAME | WS_POPUP
FONT 8, "MS Sans Serif"
BEGIN
    DEFPUSHBUTTON   "OK",IDOK,66,81,50,14
    ICON            "ABOUT1",IDC_STATIC,7,7,21,20
    CTEXT           "About1",IDC_STATIC,40,12,100,8
    CTEXT           "About Box Demo Program",IDC_STATIC,7,40,166,8
    CTEXT           "(c) Charles Petzold, 1998",IDC_STATIC,7,52,166,8
END



ABOUT1 MENU DISCARDABLE 
BEGIN
    POPUP "&Help"
    BEGIN
        MENUITEM "&About About1...",            IDM_APP_ABOUT
    END
END

ABOUT1                  ICON    DISCARDABLE     "About1.ico"


ABOUT1.ICO


 


　

　

藉由后面章节中介绍的方法，您还可以在程序中建立图标和菜单。图示和菜单的ID名均为「About1」。菜单有一个选项，它产生一条ID名为IDM_APP_ABOUT的WM_COMMAND消息。这使得程序显示的图11-1所示的对话框。


　



图11-1 程序ABOUT1的对话框
 

对话框及其模板


要把一个对话框添加到Visual C++ Developer Studio会有的应用程序上，可以先从Insert菜单中选择 Resource，然后选择Dialog Box。现在一个对话框出现在您的眼前，该对话框带有标题列、标题（Dialog）以及 OK和Cancel按钮。Controls工具列允许您在对话框中插入不同的控件。

Developer Studio将对话框的ID设为标准的IDD_DIALOG1。您可以在此名称上（或者在对话框本身）单击右键，然后从菜单中选择 Properties。在本程序中，将ID改为「AboutBox」（带有引号）。为了与我建立的对话框保持一致，请将 X Pos和Y Pos字段改为32。这表示对话框相对于程序窗口显示区域左上角的显示位置待会会有关于对话框坐标的详细讨论）。

现在，继续在Properties对话框中选择Styles页面标签。因为此对话框没有标题列，所以不要选取 Title Bar复选框。然后请单击Properties对话框的 关闭按钮。

现在可以设计对话框了。因为不需要Cancel按钮，所以先单击该按钮，然后按下键盘上的 Delete键。接着单击OK按钮，将其移动到对话框的底部。在Developer Studio窗口下面的工具列上有一个小位图，它可使控件在窗口内水平居中对齐，请按下此钮。

如果您要让程序的图标出现在对话框中，可以这样做：先在浮动的Controls工具列中按下「 Pictures」按钮。将鼠标移动到对话框的表面，按下左键，然后拉出一个矩形。这就是图标将出现的位置。然后在次矩形上按下鼠标右键，从菜单中选择 Properties。保持ID为IDC_STATIC。此标识符在RESOURCE.H中定义为-1，用于程序中不使用的所有ID。将 Type改为Icon。您可以在Image字段输入程序图标的名称，或者，如果您已经建立了一个图示，那么您也可以从下拉式清单方块中选择一个名称（About1）。

对于对话框中的三个静态字符串，可以从Controls工具列中选择 Static Text，然后确定文字在对话框中的位置。右键单击控件，然后从菜单中选择 Properties。在Properties框的 Caption字段中输入要显示的文字。选择Styles页面标签，从 Align Text字段选择Center。

在添加这些字符串的时候，若希望对话框可以更大一些，请先选中对话框，然后拖曳边框。您也可以选择并缩放控件。通常用键盘上的光标移动键完成此操作会更容易些。箭头键本身移动控件，按下Shift键后按箭头键，可以改变控件的大小。所选控件的坐标和大小显示在Developer Studio窗口的右下角。

如果您建立了一个应用程序，那么以后在查看资源描述档ABOUT1.RC时，您将发现Developer Studio建立的模板。我所设计的对话框模板如下：

ABOUTBOX DIALOG DISCARDABLE  32, 32, 180, 100
        
STYLE DS_MODALFRAME | WS_POPUP
        
FONT 8, "MS Sans Serif"
        
BEGIN
        
  DEFPUSHBUTTON   "OK",IDOK,66,80,50,14
        
   ICON                                                "ABOUT1",IDC_STATIC,7,7,21,20
        
   CTEXT                                                "About1",IDC_STATIC,40,12,100,8
        
   CTEXT       "About Box Demo Program",IDC_STATIC,7,40,166,8
        
   CTEXT       "(c) Charles Petzold, 1998",IDC_STATIC,7,52,166,8
        
END
        
第一行给出了对话框的名称（这里为ABOUTBOX）。如同其它资源，您也可以使用数字作为对话框的名称。名称后面是关键词DIALOG和DISCARDABLE以及四个数字。前两个数字是对话框左上角的x、y坐标，该坐标在程序呼叫对话框时，是相对于父窗口显示区域的。后两个数字是对话框的宽度和高度。

这些坐标和大小的单位都不是图素。它们实际上依据一种特殊的坐标系统，该系统只用于对话框模板。数字依据对话框使用字体的大小而定（这里是8点的MS Sans Serif字体）：x坐标和宽度的单位是字符平均宽度的1/4；y坐标和高度的单位是字符高度的1/8。因此，对这个对话框来说，对话框左上角距离主窗口显示区域的左边是5个字符，距离顶边是2-1/2个字符。对话框本身宽40个字符，高10个字符。

这样的坐标系使得程序写作者可以使用坐标和大小来大致勾勒对话框的尺寸和外观，而不管视讯显示器的分辨率是多少。由于系统字体字符的高度大致为其宽度的两倍，所以，x轴和y轴的量度差不多相等。

模板中的STYLE叙述类似于CreateWindow呼叫中的style字段。对于模态对话框，通常使用WS_POPUP和DS_MODALFRAME，我们将在稍后介绍其它的选项。

在BEGIN和END叙述（或者是左右大括号，手工设计对话框模板时，您可能会使用）之间，定义出现在对话框中的子窗口控件。这个对话框使用了三种型态的子窗口控件，它们分别是DEFPUSHBUTTON（内定按键）、ICON（图标）和CTEXT（文字居中）。这些叙述的格式为：

control-type "text" id, xPos, yPos, xWidth, yHeight, iStyle
        
其中，后面的iStyle项是可选的，它使用Windows表头文件中定义的标识符来指定其它窗口样式。

DEFPUSHBUTTON、ICON和CTEXT等标识符只可以在对话框中使用，它们是某种特定窗口类别和窗口样式的缩写。例如，CTEXT指示这个子窗口控件类别是「静态的」，其样式为：

WS_CHILD | SS_CENTER | WS_VISIBLE | WS_GROUP
        
虽然前面没有出现过WS_GROUP标识符，但是在前面的COLORS1程序中已经出现过WS_CHILD、SS_CENTER和WS_VISIBLE窗口样式，我们在建立静态子窗口文字控件时已经用到了它们。

对于图标，文字字段是程序的图标资源名称，它也在ABOUT1资源描述档中定义。对于按键，文字字段是出现在按键里的文字，这个文字相同于在程序中建立子窗口控件时呼叫CreateWindow所指定的第二个参数。