grammar.txt

编译原理语法分析(LL1文法) 编译原理语法分析(LL1文法)

program ::= block .
block ::= const-decl var-decl proc-decl statement
const-decl ::= const const-assignment-list ;
const-decl ::= <empty>
const-assignment-list ::= ident = number const-assignment-list2
const-assignment-list2 ::= , ident = number const-assignment-list2
const-assignment-list2 ::= <empty>
var-decl ::= var ident-list ;
var-decl ::= <empty>
ident-list ::= ident ident-list2
ident-list2 ::= , ident ident-list2
ident-list2 ::= <empty>
proc-decl ::= proc-decl2
proc-decl2 ::= procedure ident ; block ; proc-decl2
proc-decl2 ::= <empty>
statement ::= ident := expression
statement ::= call ident
statement ::= begin statement-list end
statement ::= if condition then statement
statement ::= while condition do statement
statement ::= <empty>
statement-list ::= statement statement-list2
statement-list2 ::= ; statement statement-list2
statement-list2 ::= <empty>
condition ::= odd expression
condition ::= expression relation expression
relation ::= =
relation ::= <>
relation ::= >
relation ::= <
relation ::= >=
relation ::= <=
expression ::= term expression2
expression ::= adding-operator term expression2
expression2 ::= adding-operator term expression2
expression2 ::= <empty>
adding-operator ::= +
adding-operator ::= -
term ::= factor term2
term2 ::= multiplying-operator factor term2
term2 ::= <empty>
multiplying-operator ::= *
multiplying-operator ::= /
factor ::= ident
factor ::= number
factor ::= ( expression )