softchannel.asp

来自「小游戏网站演示www.4399.io 拥有4万条游戏数据」· ASP 代码 · 共 1,455 行 · 第 1/5 页

ASP
1,455 行
字号
12345
<!--#include file="ubbcode.asp"-->
<!--#include file="base64.asp"-->
<%
Dim NewCloud
Set NewCloud = New SoftChannel_Cls

Class SoftChannel_Cls
	Private ChannelID, CreateHtml, keyword
	Private Rs, SQL, ChannelRootDir, HtmlContent, strIndexName
	Private softid, SoftIntro, skinid, ClassID, SoftType
	Private maxperpage, TotalNumber, TotalPageNum, CurrentPage, i, totalrec
	Private strFileDir, ParentID, strParent, strClassName, ChildStr, Child
	Private ListContent, TempListContent, HtmlTemplate, HtmlFilePath
	Private SpecialID, SpecialName, SpecialDir, PageType, ForbidEssay
	Private IsShowFlush, strInstallDir, j
	Private FoundErr,strlen,RandomCodes,m_strFileDir
	Public MakeHtmlMode,MakePageDone,MakeListNum
	Private ThunderPidArray,m_strDownLinks,m_strCurrPageName
	Public ThunderUnionID,FlashGetUnionID,strBasicPath

	Public Property Let Channel(chanid)
		ChannelID = chanid
	End Property
	Public Property Let ShowFlush(para)
		IsShowFlush = para
	End Property
	Private Sub Class_Initialize()
		On Error Resume Next
		FoundErr = False
		ChannelID = 2
		strlen = 0
		MakeHtmlMode = 0
		MakePageDone = 0
		'--每页生成数
		MakeListNum = 50
		ThunderPidArray = Split(Newasp.ThunderPid & "|||", "|")
		ThunderUnionID = Trim(ThunderPidArray(0))
		If ThunderUnionID = "" Then ThunderUnionID = "0"
		FlashGetUnionID = Trim(ThunderPidArray(1))
		If FlashGetUnionID = "" Then FlashGetUnionID = "0"
		m_strDownLinks = ""
	End Sub
	Private Sub Class_Terminate()
		Set HTML = Nothing
	End Sub
	Public Sub ChannelMain()
		Newasp.ReadChannel (ChannelID)
		CreateHtml = CInt(Newasp.IsCreateHtml)
		If Newasp.BindDomain = "0" Then
			ChannelRootDir = Newasp.InstallDir & Newasp.ChannelDir
			strBasicPath = ""
			strInstallDir = Newasp.InstallDir
		Else
			ChannelRootDir = "/"
			strInstallDir = Newasp.SiteUrl & "/"
			If Len(Newasp.NamedPath) > 2 Then
				strBasicPath = Newasp.NamedPath
			Else
				strBasicPath = Server.MapPath(Newasp.InstallDir & Newasp.ChannelDir)
			End If
			
		End If
		strIndexName = "<a href=""" & ChannelRootDir & """>" & Newasp.ChannelName & "</a>"
		ubb.BasePath = ChannelRootDir
		ubb.setUbbcode = Join(Newasp.setUserEditor,"|")
		ubb.Keyword = Newasp.ContentKeyword
	End Sub

	'#############################\\执行软件下载首页开始//#############################
	'=================================================
	'过程名：ShowDownIndex
	'作  用：显示下载首页
	'=================================================
	Public Sub ShowDownIndex()
		LoadDownIndex
		'If CreateHtml <> 0 Then
			'Response.Write "<meta http-equiv=""refresh"" content=""0;url=index" & Newasp.HtmlExtName & """ />"
		'Else
			Response.Write HtmlContent
		'End If
	End Sub
	'=================================================
	'过程名：CreateDownIndex
	'作  用：生成下载首页的HTML
	'=================================================
	Public Sub CreateDownIndex()
		LoadDownIndex
		Dim FilePath
		
		If Newasp.BindDomain = "0" Then
			FilePath = ChannelRootDir & "index" & Newasp.HtmlExtName
		Else
			FilePath = "\index" & Newasp.HtmlExtName
		End If
		Newasp.CreatedTextFile strBasicPath & FilePath, HtmlContent
		If IsShowFlush = 1 Then Response.Write "<li style=""font-size: 12px;"">生成" & Newasp.ModuleName & "首页HTML完成... " & FilePath & "</li>" & vbNewLine
		Response.Flush
	End Sub
	Public Sub LoadDownIndex()
		Dim FilePath
		
		Newasp.LoadTemplates ChannelID, 1, Newasp.ChkNumeric(Newasp.ChannelSkin)
		HtmlContent = Newasp.HtmlContent
		HtmlContent = Replace(HtmlContent, "{$ChannelRootDir}", ChannelRootDir)
		HtmlContent = Replace(HtmlContent, "{$InstallDir}", strInstallDir)
		HtmlContent = Replace(HtmlContent, "{$ChannelID}", ChannelID)
		If Len(Newasp.HtmlSetting(1)) < 2 Then
			HtmlContent = Replace(HtmlContent, "{$PageTitle}", Newasp.ChannelName)
		Else
			HtmlContent = Replace(HtmlContent, "{$PageTitle}", Newasp.ChannelName & Newasp.HtmlSetting(1))
		End If
		HtmlContent = Replace(HtmlContent, "{$ChannelName}", Newasp.ChannelName)
		HtmlContent = Replace(HtmlContent, "{$ModuleName}", Newasp.ModuleName)
		HtmlContent = Replace(HtmlContent, "{$SoftIndex}", strIndexName)
		HtmlContent = Replace(HtmlContent, "{$IndexTitle}", strIndexName)
		HtmlContent = HTML.ReadAnnounceContent(HtmlContent, ChannelID)
		HtmlContent = ReadClassMenu(HtmlContent)
		HtmlContent = ReadClassMenubar(HtmlContent)
		HtmlContent = HTML.ReadArticlePic(HtmlContent)
		HtmlContent = HTML.ReadSoftPic(HtmlContent)
		HtmlContent = HTML.ReadArticleList(HtmlContent)
		HtmlContent = HTML.ReadSoftList(HtmlContent)
		HtmlContent = HTML.ReadFlashList(HtmlContent)
		HtmlContent = HTML.ReadFlashPic(HtmlContent)
		HtmlContent = HTML.ReadFriendLink(HtmlContent)
		HtmlContent = HTML.ReadNewsPicAndText(HtmlContent)
		HtmlContent = HTML.ReadSoftPicAndText(HtmlContent)
		HtmlContent = HTML.ReadGuestList(HtmlContent)
		HtmlContent = HTML.ReadAnnounceList(HtmlContent)
		HtmlContent = HTML.ReadPopularArticle(HtmlContent)
		HtmlContent = HTML.ReadPopularSoft(HtmlContent)
		HtmlContent = HTML.ReadPopularFlash(HtmlContent)
		HtmlContent = HTML.ReadStatistic(HtmlContent)
		HtmlContent = HTML.ReadUserRank(HtmlContent)
		HtmlContent = Replace(HtmlContent, "{$SkinPath}", Newasp.SkinPath)
		HtmlContent = Replace(HtmlContent, "{$InstallDir}", strInstallDir)
		HtmlContent = Replace(HtmlContent, "{$ChannelID}", ChannelID)
		HtmlContent = HtmlContent
	End Sub
	'#############################\\执行软件信息开始//#############################
	'=================================================
	'过程名：ShowArticleInfo
	'作  用：显示下载内容页面
	'=================================================
	Public Sub ShowDownIntro()
		If CreateHtml <> 0 Then
			Response.Redirect (ChannelRootDir & "index" & Newasp.HtmlExtName)
			Exit Sub
		Else
			Newasp.PreventInfuse
			softid = Newasp.ChkNumeric(Request("id"))
			Response.Write ReadSoftIntro(softid)
		End If
	End Sub
	'=================================================
	'函数名：ReadSoftIntro
	'作  用：读取软件内容
	'参  数：SoftID ----软件ID
	'=================================================
	Public Function ReadSoftIntro(softid)
		Dim SoftImageUrl, SoftImage, Previewimg, PreviewUrl, re
		Dim strImageSize, strPreviewSize, SoftReadme, softname, SoftVer
		Dim MemberSoft, HomePage, HomePageUrl, strContact, DownloadAddress
		Dim strDecode, strRegsite, strAuthor
		Dim strRegsites, strPreviewImg,ThisUrl
		Dim subtitle, HeaderTitle,HeaderTitles,HeaderTopic
		Dim m_intPlugin,m_strPluginInfo

		SQL = "SELECT A.*,C.ClassName,C.ParentID,C.ParentStr,C.skinid,C.HtmlFileDir,C.ChildStr,C.UseHtml,C.AdsCode,C.stopad FROM [NC_SoftList] A INNER JOIN [NC_Classify] C On A.ClassID=C.ClassID WHERE A.ChannelID=" & ChannelID & " And A.isAccept > 0 And A.SoftID=" & softid
		Set Rs = Newasp.Execute(SQL)
		If Rs.BOF And Rs.EOF Then
			ReadSoftIntro = ""
			If CreateHtml = 0 Then
				Response.Write "<meta http-equiv=""refresh"" content=""2;url=/"" />" & vbNewLine
				Response.Write "<p align=""center"" style=""font-size: 16px;color: red;"">对不起，该页面发生了错误，无法访问! 系统两秒后自动转到网站首页......</p>" & vbNewLine
			End If
			Set Rs = Nothing
			Exit Function
		End If

		If Rs("skinid") <> 0 Then
			skinid = Rs("skinid")
		Else
			skinid = Newasp.ChkNumeric(Newasp.ChannelSkin)
		End If
		Newasp.LoadTemplates ChannelID, 3, skinid
		SoftReadme = Rs("content")

		Set re = New RegExp
		re.IgnoreCase = True
		re.Global = True
		If Newasp.HtmlSetting(18) <> "0" Then
			re.Pattern = "\[br\]"
			SoftReadme = re.Replace(SoftReadme, "<BR>")
			re.Pattern = "\[align=right\]"
			SoftReadme = re.Replace(SoftReadme, "<div align=right>")
			re.Pattern = "\[\/align\]"
			SoftReadme = re.Replace(SoftReadme, "</div>")
		Else
			re.Pattern = "\[br\]"
			SoftReadme = re.Replace(SoftReadme, "")
			re.Pattern = "\[align=right\](.*)\[\/align\]"
			SoftReadme = re.Replace(SoftReadme, "")
		End If
		Set re = Nothing
		DownloadAddress = ShowDownAddress(Rs("softid"))
		SoftIntro = ubb.UbbCode(SoftReadme)
		HtmlContent = Newasp.HtmlContent
		'--当前页URL
		If CreateHtml <> 0 Then
			ThisUrl = Newasp.ReadDestination(Newasp.InfoDestination, Newasp.ChannelDir, Rs("HtmlFileDate"),Rs("HtmlFileDir"),Rs("ClassID"),Rs("softid"),1,"")
		Else
			If IsURLRewrite Then
				ThisUrl = ChannelRootDir & Rs("softid") & Newasp.HtmlExtName
			Else
				ThisUrl = ChannelRootDir & "show.asp?id=" & Rs("softid")
			End If
		End If
		strImageSize = Split(Newasp.HtmlSetting(14), "|")
		strPreviewSize = Split(Newasp.HtmlSetting(15), "|")
		If Newasp.CheckNull(Rs("SoftImage")) Then
			SoftImageUrl = Newasp.GetImageUrl(Rs("SoftImage"), ChannelRootDir)
			SoftImage = Newasp.GetFlashAndPic(SoftImageUrl, CInt(strImageSize(0)), CInt(strImageSize(1)))
			SoftImage = "<a href=""" & ChannelRootDir & "Previewimg.asp?SoftID=" & softid & """ title=""" & Rs("SoftName") & """ target=""_blank"">" & SoftImage & "</a>"
			Previewimg = Newasp.GetFlashAndPic(SoftImageUrl, CInt(strPreviewSize(0)), CInt(strPreviewSize(1)))
			PreviewUrl = ChannelRootDir & "Previewimg.asp?SoftID=" & softid
			PreviewUrl = Replace(Newasp.HtmlSetting(17), "{$PreviewUrl}", PreviewUrl)
		Else
			If Newasp.CheckNull(Rs("Previewimg")) Then
				Previewimg = Newasp.GetFlashAndPic(Newasp.GetImageUrl(Rs("Previewimg"), ChannelRootDir), CInt(strPreviewSize(0)), CInt(strPreviewSize(1)))
				PreviewUrl = ChannelRootDir & "Previewimg.asp?SoftID=" & softid
				PreviewUrl = Replace(Newasp.HtmlSetting(17), "{$PreviewUrl}", PreviewUrl)
			Else
				Previewimg = ""
				PreviewUrl = Newasp.HtmlSetting(16)
			End If
			SoftImage = Newasp.HtmlSetting(13)
		End If		
		
		If Newasp.CheckNull(Rs("Homepage")) Then
			HomePageUrl = Rs("Homepage")
			HomePage = Replace(Newasp.HtmlSetting(10), "{$HomePageUrl}", Rs("Homepage"))
			HomePage = Replace(HomePage, "{$Home_Page}", Newasp.GotTopic(Rs("Homepage"),30))
		Else
			HomePage = Newasp.HtmlSetting(9)
			HomePageUrl = ""
		End If
		If Newasp.CheckNull(Rs("Contact")) Then
			strContact = Replace(Newasp.HtmlSetting(12), "{$ContactSite}", AutoPlusLinks(Rs("Contact")))
		Else
			strContact = Newasp.HtmlSetting(11)
		End If
		If Newasp.CheckNull(Rs("Decode")) Then
			strDecode = Replace(Newasp.HtmlSetting(20), "{$strDecode}", Rs("Decode"))
		Else
			strDecode = Newasp.HtmlSetting(19)
		End If
		If Rs("UserGroup") <> 0 Then
			MemberSoft = Newasp.HtmlSetting(8)
		End If
		If Newasp.CheckNull(Rs("SoftVer")) Then
			softname = Trim(Rs("SoftName") & " " & Rs("SoftVer"))
		Else
			softname = Trim(Rs("SoftName"))
		End If
		HtmlContent = Replace(HtmlContent, "{$Soft_Name}", Rs("SoftName"))
		If Newasp.CheckNull(Rs("Regsite")) Then
			strRegsite = Replace(Newasp.HtmlSetting(24), "{$RegsiteUrl}", Rs("Regsite"))
			strRegsites = Trim(Rs("Regsite"))
		Else
			strRegsite = Newasp.HtmlSetting(23)
			strRegsites = "#"
		End If
		If strRegsites = "#" Then
			strPreviewImg = ""
		Else
			strPreviewImg = "<img src=""" & strRegsites & """ border=""0""/>"
			strPreviewImg = strPreviewImg
		End If
		If Newasp.CheckNull(Rs("Author")) Then
			strAuthor = Rs("Author")
		Else
			strAuthor = Newasp.HtmlSetting(25)
		End If
		softname = Newasp.ReadFontMode(softname, Rs("ColorMode"), Rs("FontMode"))
		'--副标题
		subtitle = Rs("subtitle") & ""
		
		'-- 新增分类广告代码
		HtmlContent = AdsReplace(HtmlContent,Rs("AdsCode"),Rs("stopad"))
		HtmlContent = Replace(HtmlContent, "{$InstallDir}", strInstallDir)
12345

softchannel.asp - 源码说明

本页面展示了「小游戏网站演示www.4399.io 拥有4万条游戏数据」中的 softchannel.asp 源码文件，采用 ASP 编程语言编写，共 1,455 行代码。您可以在线阅读完整代码内容，也可以返回资源详情页下载完整源码包进行本地学习和开发。

虫虫下载站收录了大量与4399相关的技术资源，包括源代码、技术文档、电路图等，是电子工程师和嵌入式开发者的专业学习平台。

⌨️ 快捷键说明

复制代码Ctrl + C
搜索代码Ctrl + F
全屏模式F11
增大字号Ctrl + =
减小字号Ctrl + -
显示快捷键?