configure.in

飞鸽传书的linux源代码

dnl Process this file with autoconf to produce a configure script.

dnl from ac-archives
AC_DEFUN([AC_DEFINE_DIR], [
  test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  ac_define_dir=`eval echo $2`
  $1="$ac_define_dir"
  AC_SUBST($1)
  ifelse($3, ,
    AC_DEFINE_UNQUOTED($1, "$ac_define_dir"),
    AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3))
])

AC_INIT(configure.in)
AM_INIT_AUTOMAKE(g2ipmsg, 0.8.6)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AC_PROG_INTLTOOL([0.31])

AC_HEADER_STDC

dnl AC_ARG_ENABLE(applet,[  --enable-applet  build g2ipmsg applet(DANGEROUS) [default no]])
dnl AC_MSG_CHECKING(whether to enable applet)
dnl if test "x$enable_applet" = "xyes"; then
dnl	AC_MSG_RESULT(yes)
dnl	AC_DEFINE(G2IPMSG_APPLET,[],[Applet enable])
dnl fi

AC_ARG_ENABLE(schemas-install,
     [  --disable-schemas-install	Disable the schemas installation],
     [case ${enableval} in
       yes|no) ;;
       *) AC_MSG_ERROR(bad value ${enableval} for --enable-schemas-install) ;;
      esac])
AM_CONDITIONAL([GCONF_SCHEMAS_INSTALL], [test "$enable_schemas_install" != no])


pkg_modules="libgnomeui-2.0 libpanelapplet-2.0"
PKG_CHECK_MODULES(PACKAGE, [$pkg_modules])


GETTEXT_PACKAGE=g2ipmsg
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXTPACKAGE", [Gettext package.])

dnl ***************************************************************************
dnl *** Set install directories                                             ***
dnl ***************************************************************************
iconsdir="${datadir}/icons"
AC_SUBST(iconsdir)
pixmapsdir="${datadir}/pixmaps"
AC_SUBST(pixmapsdir)
pkgdatadir="${datadir}/gnome-applets"
AC_SUBST(pkgdatadir)
gladedir="${pkgdatadir}/glade"
AC_SUBST(gladedir)

AC_DEFINE_DIR(GNOME_ICONDIR, "${iconsdir}", [Gnome Icon Directory])
AC_DEFINE_DIR(GNOME_PIXMAPSDIR, "${pixmapsdir}", [Gnome Pixmaps Directory])
AC_DEFINE_DIR(GNOME_GLADEDIR, "${gladedir}", [Glade Resources Directory])
AC_DEFINE_DIR(DATADIR, "${datadir}", [datadir])
AC_DEFINE_DIR(SYSCONFDIR, "${sysconfdir}", [sysconfdir])
AC_DEFINE_DIR(LIBDIR, "${libdir}", [libdir])
AC_DEFINE_DIR(PREFIX, "$prefix", [install prefix])

dnl Add the languages which your application supports here.
ALL_LINGUAS="ja"
AM_GLIB_GNU_GETTEXT
AM_GCONF_SOURCE_2
GST_MAJORMINOR=0.10
PKG_CHECK_MODULES(GST,gstreamer-$GST_MAJORMINOR,HAVE_GST="yes",HAVE_GST="no")
if test "x$HAVE_GST" = "xyes"; then
	AC_DEFINE(HAVE_GST,1,[Gstreamer])
else
	AC_MSG_WARN(You need GStreamer-0.10 or later installed if you need sound relevant function.)
fi


AC_SUBST(GST_CFLAGS)
AC_SUBST(GST_LIBS)

PACKAGE_CFLAGS="$PACKAGE_CFLAGS $GST_CFLAGS"
PACKAGE_LIBS="$PACKAGE_LIBS $GST_LIBS"

AC_SUBST(PACKAGE_CFLAGS)
AC_SUBST(PACKAGE_LIBS)

AC_OUTPUT([
Makefile
src/Makefile
po/Makefile.in
])