runbuild.bat

I want to provide an example file system driver for Windows NT/2000/XP. For some time I have worked

@echo off

rem
rem This file makes it convenient to call the build program from Visual Studio
rem but it can also be used manually at the command line.
rem
rem syntax: runbuild nt4|w2k|xp|xp64 checked|free [-c]
rem         runbuild all
rem         runbuild distclean
rem

setlocal

set NT4_DDK_ROOT=C:\WINDDK\1381
set W2K_DDK_ROOT=C:\WINDDK\2195
set XP_DDK_ROOT=C:\WINDDK\2600

if "%1"=="all" goto all
if "%1"=="distclean" goto distclean

if "%2"=="checked" goto arg2ok
if "%2"=="free" goto arg2ok
goto usage

:arg2ok
if "%1"=="nt4" goto nt4
if "%1"=="w2k" goto w2k
if "%1"=="xp" goto xp
if "%1"=="xp64" goto xp64
goto usage

:nt4
if not exist %NT4_DDK_ROOT% goto noddk
pushd .
call %NT4_DDK_ROOT%\bin\setenv %NT4_DDK_ROOT% %2
popd
if "%DDKBUILDENV%"=="" goto noddk
mkdir ..\bin\nt4\i386\%DDKBUILDENV%
build %3
goto exit

:w2k
if not exist %W2K_DDK_ROOT% goto noddk
pushd .
call %W2K_DDK_ROOT%\bin\setenv %W2K_DDK_ROOT% %2
popd
if "%DDKBUILDENV%"=="" goto noddk
mkdir ..\bin\w2k\%DDKBUILDENV%\i386
build %3
goto exit

:xp
if not exist %XP_DDK_ROOT% goto noddk
pushd .
call %XP_DDK_ROOT%\bin\setenv %XP_DDK_ROOT% %2
popd
if "%DDKBUILDENV%"=="" goto noddk
mkdir ..\bin\xp\%DDKBUILDENV%\i386
build %3
goto exit

:xp64
if not exist %XP_DDK_ROOT% goto noddk
pushd .
call %XP_DDK_ROOT%\bin\setenv %XP_DDK_ROOT% %2 64
popd
if "%DDKBUILDENV%"=="" goto noddk
mkdir ..\bin\xp\%DDKBUILDENV%\ia64
build %3
goto exit

:all
call runbuild nt4 checked -c
call runbuild nt4 free -c
call runbuild w2k checked -c
call runbuild w2k free -c
call runbuild xp checked -c
call runbuild xp free -c
call runbuild xp64 checked -c
call runbuild xp64 free -c
goto exit

:distclean
del *.log *.ncb *.opt
del /S ..\bin\*.bsc ..\bin\*.nms
rmdir /S /Q obj
rmdir /S /Q objchk
rmdir /S /Q objfre
goto exit

:usage
echo syntax: runbuild nt4^|w2k^|xp^|xp64 checked^|free [-c] ^| runbuild all ^| runbuild distclean
goto exit

:noddk
echo Can't find the DDK, check the path in runbuild.bat
goto exit

:exit
endlocal