10-1.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE,MAGNETIC FIELD FROM A SQUARE CURRENT LOOP ! 定义工作标题
/FILNAME,CURRENT LOOP,1                       ! 定义工作文件名
KEYW,MAGELC,1                                 ! 指定磁场分析

/PREP7
ET,1,LINK68               ! 定义LINK68单元
R,1,1                      ! 给导线横截面积定义一个任意值
MP,RSVX,1,4.0E-8          ! 定义电阻率
N,1                       ! 为导线环定义节点
N,2,1.5
N,3,1.5,,1.5
N,4,,,1.5
N,5                       ! 与1号节点重合
N,6,,0.35                   ! 取出结果值的节点
/VIEW,1,1,1,1
E,1,2                      ! 创建单元
EGEN,4,1,-1
FINISH

/SOLU    
D,5,VOLT,0                 ! 导线上接地边界条件
F,1,AMPS,7.5                ! 施加电流激励载荷
OUTPR,ESOL,LAST          ! 设置输出控制，最后一步的单元结果保存
SOLVE                     ! 当前条件下求解
BIOT,NEW                  ! 通过比奥萨法儿积分计算HS场.
*GET,HX,NODE,6,HS,X       ! 获取HS(X)值并赋给参数HX 
*GET,HY,NODE,6,HS,Y       ! 获取HS(Y)值并赋给参数HY
*GET,HZ,NODE,6,HS,Z       ! 获取HS(Z)值并赋给参数HZ
MUZRO=12.5664E-7          ! 定义真空磁导率
BX=MUZRO*HX             ! 计算磁通密度
BY=MUZRO*HY
BZ=MUZRO*HZ
*status,parm                  ! 显示所有参数
*DIM,LABEL,CHAR,3,2        ! 定义参数并对较理论值和计算值比较
*DIM,VALUE,,3,3
LABEL(1,1) = 'BX ','BY ','BZ '
LABEL(1,2) = 'TESLA','TESLA','TESLA'
*VFILL,VALUE(1,1),DATA,2.010E-6,-.662E-6,2.01E-6
*VFILL,VALUE(1,2),DATA,BX,BY,BZ
*VFILL,VALUE(1,3),DATA,ABS(BX/(2.01E-6)),ABS(BY/.662E-6),ABS(BZ/(2.01E-6))
*CFOPEN, CURRENT LOOP,TXT,C:\  ! 在指定路径下打开CURRENT LOOP.TXT文本文件
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F12.9,'  ',F12.9,'   ',1F5.3)  ! 以指定的格式把上述参数写入打开的文件中
*CFCLOS                              ! 关闭打开的文本文件
FINISH