4-1.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE,2D SOLENOID ACTUATOR STATIC ANALYSIS    ! 定义工作标题
/FILNAME,EMAGE_2D,1                       ! 定义工作文件名
KEYW,MAGNOD,1                            ! 指定磁场分析

/PREP7
ET,1,PLANE53,,,1            ! 指定单元类型并定义单元选项
ET,2,PLANE53,2,,1           ! 指定单元类型并定义单元选项
MP,MURX,1,1               ! 定义空气材料属性
MP,MURX,2,1000            ! 定义铁芯材料属性
MP,MURX,3,1               ! 定义线圈材料属性
MP,MURX,4,2000            ! 定义电枢材料属性
MP,RSVX,3,3E-8             ! 定义线圈电阻率
MP,RSVX,4,70E-8            ! 定义电枢电阻率

N=650                      ! 定义参数
TA=0.75
TB=0.75
TC=0.50
TD=0.75
WC=1
HC=2
GAP=0.25
SPACE=0.25
WS=WC+2*SPACE
HS=HC+0.75
W=TA+WS+TC
HB=TB+HS
H=HB+GAP+TD
ACOIL=WC*HC                 ! 线圈横截面积（CM2）

R,1,ACOIL*.01**2,N,,1,.95        ! 定义线圈实常数
/PNUM,AREA,1                 ! 打开面区域编号
/PNUM,AREA,1
RECTNG,0,W,0,TB               ! 生成几何模型
RECTNG,0,W,TB,HB
RECTNG,TA,TA+WS,0,H
RECTNG,TA+SPACE,TA+SPACE+WC,TB+SPACE,TB+SPACE+HC
AOVLAP,ALL
RECTNG,0,W,0,HB+GAP
RECTNG,0,W,0,H
AOVLAP,ALL
NUMCMP,AREA                 ! 压缩编号
APLOT
SAVE,Emage_2D_geom.db         ! 保存几何模型到文件
ASEL,S,AREA,,2                 ! 给线圈区域赋予材料特性
AATT,3,1,2,0
ASEL,S,AREA,,1                 ! 给电枢区域赋予材料特性
ASEL,A,AREA,,12,13
AATT,4,1,1
ASEL,S,AREA,,3,5               ! 给铁芯区域赋予材料特性
ASEL,A,AREA,,7,8
AATT,2,1,1,0
/PNUM,MAT,1                  ! 打开材料编号
ALLSEL,ALL
APLOT

SMRTSIZE,4                   ! 设置智能化划分网格等级L
AMESH,ALL                   ! 划分自由网格
SAVE,Emage_2D_Mesh.db        ! 保存网格单元数据到文件
ESEL,S,MAT,,4                 ! 选择电枢上的所有单元
CM,ARM,ELEM                ! 将电枢单元定义为一个组件
FMAGBC,'ARM'                ! 给电枢加力边界条件
ESEL,S,MAT,,3
NSLE,S
CP,1,CURR,ALL
CM,COIL,ELEM                ! 将线圈单元定义为一个组件
ALLSEL,ALL
ARSCAL,ALL,,,.01,.01,1,,0,1      ! 改变单位制为MSK单位（米）
FINISH

/SOLU
ANTYP,TRANS
NSEL,EXT                     ! 选择外层节点
D,ALL,AZ,0                    ! 施加磁力线平行边界条件
CMSEL,S,COIL
BFE,ALL,VLTG,,12
ALLSEL,ALL
TIME,.01                       ! 定义时间和子步选项
DELTIM,.002                    ! 定义时间和时间步长选项
OUTRES,ALL,ALL
SOLVE
TIME,.03
NSUBST,1
SOLVE
TIME,.03
DELTIM,.005
TIME,.06
NSUBST,1
SOLVE
SAVE,Emage_2D_resu.db             ! 保存计算结果
FINISH

/POST26
PMGTRAN,,,'ARM',,,,,'COIL','COIL'    ! 查看单元组件上的计算值
FINISH