12-1.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE, Comb Drive Example     ! 定义工作标题
/FILNAME,Comb,1                ! 定义工作文件名
/pmeth,on,1                    ! 指定P方法电场分析

/prep7
! 几何尺寸参数（微米）
wf=2                   ! 固定齿宽度
wm=2                   ! 运动齿宽度
gg=2                   ! 齿间气隙
tt=40                  ! 运动齿长度
t1=4                   ! 固定齿背宽
t2=tt                  ! 运动齿长度
hh=10                  ! 高度
dt=tt/2
V0=10
xx=(2*tt-dt)*2.75
y1=(wm/2)+gg
y2=(wm/2)+gg+wf
x1=tt+t1
dx=wm*1.1
dy=dx
! 创建几何模型
/PNUM,VOLU,1
cyl4,0,0,xx,0,,360,1
block,-tt,0,y1,y2,0,1
block,(-tt-t1),-tt,-y2,y2,0,1
block,-tt,0,-y1,-y2,0,1
block,-dt,(tt-dt),(-wm/2),(wm/2),0,1
block,(-dt-(gg/2)),(tt-dt+(gg/2)),((-wm/2)-(gg/2)),(wm/2)+(gg/2),0,1
block,-x1-dx,tt-dt+dx,-y2-dy,y2+dy,0,1
vovlap,all
! 二维网格划分
et,11,200,7              ! 定义高阶三角形网格单元
esize,gg/2
mshap,1                  ! 设定网格划分形状为三角形
amesh,52                 ! 运动齿外围空气层网格划分
esize,gg
amesh,54                 ! 整个装置外围空气层网格划分
esize,(y2+dy)*5
amesh,50                 ! 远场边界空气网格划分
! 三维网格划分
et,1,128
emunit,epzro,8.854e-6    ! 设定uMKSV单位制自由空间介电常数
mp,perx,1,1              ! 设定相对介电常数为1
mat,1
lsel,s,loc,z,0.5 
lesize,all,,,1           ! 设定Z方向个数尺寸为1
lsel,all
type,1
vsel,s,volu,,10,12,1
vsweep,all               ! 体扫掠网格划分，由三角形面网格创建楔形体单元
vsel,all
vsel,s,volu,,10          ! 绘出远场空气单元
eslv,s
eplot
allsel
asel,s,loc,z,1           ! 选择源面
aclear,all        
etdele,11                ! 删除网格单元 
asel,all
csys,1
nsel,s,loc,x,xx
d,all,VOLT,0             ! 给远场空气外边界施加0伏电压边界条件
nsel,all
csys,0
vsel,s,volu,,5
cm,MFINGER,volu
asel,s,ext
nsla,s,1
d,all,VOLT,0             ! 给运动齿施加0伏电压
sf,all,mxwf
vsel,s,volu,,2
vsel,a,volu,,8,9,1
cm,FFINGER,volu
asel,s,ext
nsla,s,1
d,all,VOLT,V0            ! 给固定齿施加10伏电压
allsel
! P方法收敛控制
pemopt,5.0,dual          ! 设定P方法求解误差范围和误差估计方法
pconv,2,efor,x           ! 设置P方法求解收敛值
/gst,on
save                     
finish

/solu
eqslv,iccg               ! 设定ICCG求解器 
solve                 
finish

/post1
set,last                 ! 读入最后一步求解结果
vsel,s,volu,,11,12
eslv,s
pplot                    ! 绘出运动齿和整个装置外围的空气体上的单元的特征P阶次
esel,all
plconv,all               ! 绘出收敛曲线
etable,fx,fmag,x
etable,fy,fmag,y
etable,fz,fmag,z
ssum
*get,fx,ssum,,item,fx    ! 获取单元表求和结果静电力
*get,fy,ssum,,item,fy
*get,fz,ssum,,item,fz
/com,Comb Drive Force
*stat,fx
finish