3-1.txt

ANSYS电磁分析的命令流文件

!/BATCH,LIST
/TITLE,VOLTAGE-FED THICK STRANDED COIL IN FREE SPACE  ! 定义工作标题
/FILNAM,VOL_COIL_2D,1                      ! 定义工作文件名
KEYW,MAGNOD,1                              ! 指定磁场分析

/PREP7
ET,1,53,,,1                                 ! 指定空气单元类型
ET,2,53,2,,1                                ! 指定载压线圈单元类型
ET,3,110,,,1                                ! 指定远场单元类型
EMUNIT,MKS                                  ! 指定单位制
MP,MURX,1,1                                 ! 定义空气区域材料特性
MP,MURX,2,1                                 ! 定义线圈区域材料特性
MP,RSVX,2,3.00E-8                           ! 定义线圈区域材料特性
S=0.02                                      ! 定义参数
N=500
R=3*S/2
/PNUM,AREA,1                               ! 打开面区域编号
RECTNG,S,2*S,0,S/2                         ! 生成几何模型
PCIRC,0,6*S,0,90
PCIRC,0,12*S,0,90
AOVLAP,ALL
SAVE,VOL_COIL_2D_geom.db                  ! 保存几何模型到文件
SAVE
ASEL,S,AREA,,1                            ! 指定线圈材料特性和单元类型
AATT,2,1,2
ASUM                                      ! 计算线圈面积
*GET,A,AREA,,AREA                         ! 取得的面积是线圈截面积的1/2
ASEL,S,AREA,,4                            ! 指定远场区域材料特性和单元类型
AATT,1,1,3
ASEL,ALL
CSYS,1                                    ! 把当前笛卡儿坐标系转变为柱坐标系
LSEL,S,LOC,X,9*S                          ! 选择坐标位置在9*s的线
LESIZE,ALL,,,1                            ! 设定所选线度上的单元个数为1
ESIZE,,8                                  ! 设定全局单元个数为8
MSHAPE,0,2D                               ! 采用二维四边形划分网格
MSHKEY,1                                  ! 采用映射网格划分
AMESH,1,4,3                               ! 对远场区域和线圈进行网格划分
SMRTSIZE,2                                ! 设定智能划分等级为2
ESIZE,S/4                                 ! 设定全局单元边长为s/4
MSHAPE,1,2D                               ! 采用二维三角形划分网格
MSHKEY,0                                  ! 采用自由网格划分
AMESH,5                           ! 对线圈和远场区域之间的空去域进行网格划分
SAVE,VOL_COIL_2D_Mesh.db                  ! 保存网格单元数据到文件
SAVE
R,1,2*A,500,,1,1                          ! 定义线圈实常数
N1=NODE(S,0,0)                            ! 获得线圈左下角节点编号
ESEL,S,MAT,,2                             ! 获得材料号为2的所有单元，即线圈单元
NSLE,S                                    ! 获所有节点得线圈上
CP,1,CURR,ALL                          ! 将线圈节点上的电流自由度进行耦合
ALLSEL,ALL                             ! 选中工作区中一切物体
CSYS,1                                 ! 把当前坐标系改为柱坐标系
NSEL,S,LOC,X,12*S                      ! 选择远场外边界上的所有节点
SF,ALL,INF                             ! 在所选节点上施加远场标志
CSYS,0                                 ! 把当前坐标改为笛卡儿坐标系
NSEL,S,LOC,X,0                         ! 选择Y轴上的所有节点
D,ALL,AZ,0                             ! 设定边界条件为磁通量与Y轴平行
ALLSEL,ALL
FINISH

/SOLU
ANTYPE,HARM                           ! 设定求解类型为谐性
ESEL,S,MAT,,2                         ! 选择材料号为2的所有单元
BFE,ALL,VLTG,,12                      ! 施加12V载荷（实数）
ESEL,ALL
HARFRQ,60                             ! 指定谐性频率为60 HZ.
SOLVE                                 ! 求解
SAVE,VOL_COIL_2D_resu.db              ! 保存计算结果
SAVE
FINISH 

/POST1
SET,1                                 ! 读入第一步结果数据
PLF2D                                 ! 绘制二维磁力线图
*GET,CURREAL,NODE,N1,CURR             ! 获得节点号为n1的电流实部
SET,1,1,,1                            ! 读入第一步求解结果的虚部值
PLF2D                                 ! 绘制二维虚部磁力线图
*GET,CURIMAG,NODE,N1,CURR             ! 获得节点n1电流的虚部
*STATUS                               ! 显示所有参数 
FINISH