4-2.txt

ANSYS电磁分析的命令流文件

/TITLE, TRANSIENT ANALYSIS OF A SLOT EMBEDDED CONDUCTOR
/FILNAME,TRANSIENT_2D,1 
KEYW,MAGNOD,1
 
/PREP7
ANTYPE,TRANS
ET,1,PLANE13
ET,2,PLANE13,6
EMUNIT,MUZRO,1
MP,MURX,1,1
MP,MURX,2,1
MP,RSVX,2,1
N,1
N,8,,7
FILL
NGEN,2,8,1,8,1,1
MAT,2
TYPE,2
E,1,2,10,9
EGEN,4,1,-1
MAT,1
TYPE,1
E,5,6,14,13
EGEN,3,1,-1
CP,1,AZ,1,9
*REPEAT,5,1,,1,1
ESEL,,MAT,,2
NSLE
CP,6,VOLT,ALL
ESEL,ALL
NSEL,S,LOC,Y,7
D,ALL,AZ,0
NSEL,ALL
FINISH
! 以上部分与本章实例2基本相同，不再注解。
! //////////////////////////////////////////////////////////////////////

/SOLU
EQSLV,JCG,1E-9                ! 选择雅克比求解器，误差为1×10-9
T=1E-8                         ! 设置开始求解时间
C=0                            ! 定义一个计数器
N=80                           ! 设置一个时间步长
PI=2*ASIN(1)                   ! 获得π的值
CON=2*PI/N                     ! 设置时间增量大小
NEQIT,1                        ! 设置时间步的迭代次数为1
*CREATE,LOAD                   ! 创建宏设置载荷步
TIME,T                         ! 设置载荷步终止时间
I=4*SIN(T)                     ! 计算激励电流
F,1,AMPS,I                     ! 把电流加到节点12上
T=T+CON                        ! 时间递增
C=C+1                          ! 计数器递增
OUTRES,ALL,1                   ! 设置输出控制
*IF,C,EQ,((N*.75)+1),THEN      ! 条件判断
OUTPR,,1                       ! 输出打印结果
*ELSEIF,C,EQ,(N+1),THEN        ! 条件转移
OUTPR,,1
*ELSE
OUTPR,,0
*ENDIF
SOLVE
*END
*DO,I,1,81                     ! 循环命令
*USE,LOAD                      ! 执行宏
*ENDDO
FINISH
/POST26
NUMVAR,12                      ! 设置存储变量文件的列数
ESOL,2,1,,NMISC,6,JE           ! 定义涡流变量
*REPEAT,4,1,1
ESOL,6,1,,VOLUME               ! 定义体积变量
*REPEAT,4,1,1
PROD,2,2,6                     ! 计算涡旋电流 IE=JE*VOLUME
*REPEAT,4,1,1,1
ADD,2,2,3,4,IE                 ! 对所有导体单元涡旋电流求和
ADD,10,2,5,,IE                 ! 总的涡旋电流（IE的变量编号为10）
ESOL,2,1,,SMISC,1,JS           ! 定义源电流变量
*REPEAT,4,1,1
PROD,2,2,6                     ! 计算IS=JS*VOLUME
*REPEAT,4,1,1,1
ADD,2,2,3,4,IS
ADD,11,2,5,,IS
ESOL,2,1,,NMISC,7,JT             ! 定义总的电流变量
*REPEAT,4,1,1
PROD,2,2,6
*REPEAT,4,1,1,1
ADD,2,2,3,4,IT
ADD,12,2,5,,IT
/AXLAB,Y,CURRENT                 ! 定义y轴标签为电流
/GROPT,AXNSC,2.0                 ! 坐标轴刻度比例因子，2.0表示主刻度间有一次刻度
PRVAR,10,11,12                   ! 打印涡旋电流、源电流和总电流
PLVAR,10,11,12                   ! 绘制涡旋电流、源电流和总电流
FINISH